[求助]：一个LISP程序，怎么才能让它画的结果指定到某层？

degucn · 发表于 2005-7-15 08:49:34

马上注册，结交更多好友，享用更多功能，让你轻松玩转社区。

您需要登录才可以下载或查看，没有账号？立即注册

×

这是一个计算面积的命令，我怎么才能实现让它的结果指定到我指定的层上(比如“面积”)

(defun myerr (s)
  (if (/= s "Function cancelled")
   (if (/= s "quit/exit abord")
      (princ (strcat "\nERROR:" s))
   )
  )
  (setq *error* olderr)
  (setvar "osmode" oldos)
  (setq olderr nil PT nil STA nil QAREA nil OLDOS nil PT1 nil)
  (setq set nil dataarea nil len nil count nil e1 nil dat nil sumarea nil allarea nil)
)

;; write area value to drawing
(DEFUN C:QAA(/ OLDOS PT STA QAREA)
  (setq olderr *error*)
  (setq *error* myerr)
  (SETVAR "CMDECHO" 0)
  (SETQ OLDOS (GETVAR "OSMODE"))
  (SETVAR "OSMODE" 0)
  (SETQ PT (GETPOINT"\nPick the point:"))
  (SETQ STA (BPOLY PT))
  (IF (= STA NIL) (EXIT))
  (COMMAND "AREA" "E" "L")
  (SETQ QAREA (RTOS (GETVAR "AREA") 2 2))
  (COMMAND "TEXT" PT "" "" QAREA)
  (SETVAR "OSMODE" OLDOS)
  (SETVAR "CMDECHO" 1)
  (setq *error* olderr)
  (PRINC)
)

紫云飞 · 发表于 2005-7-15 10:08:51

在命令text后执行:
(setq mm (entget (entlast)))
(setq old (assoc 8 mm))
(setq mm (subst (cons 8 "面积") old mm))
(entmod mm)

xiaomihu · 发表于 2005-7-15 10:10:13

将“面积”这曾在(COMMAND "TEXT" PT "" "" QAREA)
前积活不就可以了吗
(command "-layer" n "面积" s "面积"）

liangcheng_xia · 发表于 2005-7-15 19:41:10

可以直接创建这个层!并在这个层上操作!!!

yjrun · 发表于 2005-7-16 15:33:32

使用layer命令进行图层操作即可

xyp1964 · 发表于 2005-7-16 17:25:12

偶一般在标注前设层，利用自定义函数MKLA：
MKLA 图层颜色格式化输入 : (MKLA "层名" 颜色号)
实例：
(mkla"面积"4)

源码：
[php];;; ----------------------- MKLA ---------------------------
;;;                图层颜色格式化输入
;;;方式 : (mkla "层名" 颜色号)
(defun mkla (name color)
  (If (= (Tblsearch "layer" name) nil)
(Command "layer" "m" name "c" color name "")
(Command "layer" "t" name "s" name "c" color name "")
  )
)[/php]

ab99001 · 发表于 2005-7-17 08:26:15

好，感谢楼上各位，又学到不少招

yshf · 发表于 2005-7-17 21:47:32

也可以进行操作：
(COMMAND "TEXT" PT "" "" QAREA
"_chprop" (entlast) "" "layer" "面积" ""
)

aeo · 发表于 2005-7-18 00:59:27

最初由紫云飞发布
[B]在命令text后执行:
(setq mm (entget (entlast)))
(setq old (assoc 8 mm))
(setq mm (subst (cons 8 "面积") old mm))
(entmod mm) [/B]

yes

无声 · 发表于 2005-7-19 15:44:48

我是初学者，在各位交流中学到不少

tc405003 · 发表于 2005-7-19 22:19:08

真是受益不少，我现在是初学，以后得向大家多多学习

leochen · 发表于 2005-7-20 19:04:03

(defun mlayer (lname colour)
  (if (= (tblobjname "LAYER" lname) nil)
(entmake (list
         '(0 . "LAYER")
         '(100 . "AcDbSymbolTableRecord")
         '(100 . "AcDbLayerTableRecord")
         '(6 . "CONTINUOUS")
         (cons 62 colour)
         '(70 . 0)
         (cons 2 lname)
      )
)
  )
  (princ)
)

userzhluserzhl · 发表于 2005-8-5 21:12:50

我在CAD2005上试了一下,输出的结果它会自动成TXT层!

账号		自动登录	找回密码
密码			立即注册

[求助] [求助]：一个LISP程序，怎么才能让它画的结果指定到某层？

马上注册，结交更多好友，享用更多功能，让你轻松玩转社区。

相关帖子