[求助]：删除表中重复的元素用什么函数

animal212

删除表中重复的元素用什么函数？

carrot1983

美女。。。一定没有搜过论坛里的贴子吧。
[php]
;;;删除列表中的相同元素(保留一个)并返回新表
(defun LstDelSame (lst / x nl)
  (foreach x lst
    (if        (not (member x nl))
      (setq nl (cons x nl))
    )
  )
  (reverse nl)
)


;;;N位開始,M 長度的子表
(defun LI_SubList ( Lst Start len / _len n m _Lst)
(if (minusp len)
    (setq len (1+(length lst)))
)

(setq
    _len (length Lst)
    n (min (- Start 1) _len)    ; Starting Index
    m (min (+ n len) _len)        ; Ending Index
    _Lst '()
)

(while (< n m)
    (setq
        _Lst (cons (nth n Lst) _Lst)
        n (1+ n)
    )
)
(reverse _Lst)
)

;;;统计表中相同元素的个数
(defun lstsameitmnum (lst / a len x return)
(while lst
  (setq a (car lst))
  (setq len (length lst))
  (setq lst(vl-remove-if  '(lambda(x)(= a x)) lst))
  ;;第一个是(- len(length lst))个
  (setq return (cons (list a (- len(length lst))) return))
)
return
)

;;;两表的并集
(defun LSTUNION        (Lst1 Lst2 / Lst tmp)
  (append Lst1 lst2)
)

;;;两表的交集
(defun LSTINTER        (Lst1 Lst2 / Lst tmp lst11 lst22)
  (foreach tmp Lst2
    (if        (member tmp Lst1)
      (setq Lst22 (cons tmp Lst22))
    )
  )
  (foreach tmp Lst1
    (if        (member tmp Lst2)
      (setq Lst11 (cons tmp Lst11))
    )
  )
  (setq        Lst (append (reverse Lst11) (reverse Lst22))
        lst (LstDelSame lst)
  )
  Lst
)

;;;两表的差集
(defun LSTDIFF (Lst1 Lst2 / Lst tmp lst11 lst22)
  (foreach tmp Lst2
    (if        (not (member tmp Lst1))
      (setq Lst22 (cons tmp Lst22))
    )
  )
  (foreach tmp Lst1
    (if        (not (member tmp Lst2))
      (setq Lst11 (cons tmp Lst11))
    )
  )
  (setq        Lst (append (reverse Lst11) (reverse Lst22))
        lst (LstDelSame lst)
  )
  Lst
)


;;;listremoveatom去除表delatom中指定的元素lstin
(defun listremoveatom (delatom lstin)
  (apply
    'append
    (subst
      nil
      (list delatom)
      (mapcar
    'list
    lstin
      )
    )
  )
)

(defun LI_RemLst( itm lst / nlst elem len )
(setq nlst '())
(foreach elem lst
    (if (not (equal elem itm))
        (setq nlst (append nlst (list elem)))
    )
)
nlst
)

;;;將表的第N項移去
(defun LI_DelLst( Idx Lst / nlst cnt elem )
(setq
    nlst '()
    cnt 1
)
(foreach elem lst
    (if (/= cnt Idx)
        (setq nlst (cons elem nlst))
    )
    (setq cnt (1+ cnt))
)
(reverse nlst)
)

;;;及在表的第n項位置增加一元素

(defun LI_AddList (Lst Pos Val / Lst1 Lst2 cnt nverts )
(setq
    cnt 0
    Lst1 '()
    nverts (length Lst)
)

(repeat Pos
    (setq
        Lst1 (cons (nth cnt Lst) Lst1)
        cnt (1+ cnt)
    )
)

(setq
    Lst1 (cons Val Lst1)
    Lst1 (reverse Lst1)
    cnt Pos
)

(if (> nverts Pos)
(progn
    (setq Lst2 '())
    (repeat (- nverts Pos)
        (setq
            Lst2 (cons (nth cnt Lst) Lst2)
            cnt (1+ cnt)
        )
    )
    (setq
        Lst2 (reverse Lst2)
        Lst1 (append Lst1 Lst2)
    )
))
Lst1
)


;;;;表排序
;;;;(55 11 33 44 22 66) 变成(11 22 33 44 55 66)

;;;將表的第N項移去
(defun LI_DelLst (Idx Lst / nlst cnt elem)
  (setq
    nlst '()
    cnt         1
  )
  (foreach elem        lst
    (if        (/= cnt Idx)
      (setq nlst (cons elem nlst))
    )
    (setq cnt (1+ cnt))
  )
  (reverse nlst)
)

(defun sortlist (lis / len k abc nn len_nn plis)
  (setq len (length lis))
  (setq k 1)
  (while (<= k len)
    (setq abc (eval (append '(max) lis)))
    (setq nn 1)
    (setq len_nn (length lis))
    (while (<= nn len_nn)
      (if (= (nth (1- nn) lis) abc)
        (progn
          (setq lis (LI_DelLst nn lis))
          (setq plis (cons abc plis))
        )
      )
      (setq nn (1+ nn))
    )
    (setq k (1+ k))
  )
  (reverse plis)
)
[/php]

kohi

试试这个: (acet-list-remove-duplicates plist tol)
其中: plist 表,tol 精度

fsxm

一般来说用的都是有序表~
再用这个方法来删相同元素就太慢了~

基本算法是：
如果表是有必要排序的
就先排序再用foreach来消重~

就算是不必要排序的表
如果有很多的要消重也要先排序再用foreach来消重