匹配同名图块的XYZ方向的比例 LISP程序：BlockScaleMatch by quelea

YueFeng

;; 匹配同名图块的XYZ方向的比例

(defun C:BlockScaleMatch (/        xscale    yscale      zscale
              blockname  sourceblkobj      targetblkobj
              blklist    ss        i      n
             )
  (setq sourceblkobj (entsel "\nSelect reference block:"))
  (if (null sourceblkobj) (exit))
  (setq sourceblkobj (vlax-ename->vla-object (car sourceblkobj)))
  (if (/= "AcDbBlockReference" (vla-get-objectname sourceblkobj))
    (progn
      (princ
    "\nThe object you selected was not block reference. Application terminated."
      )
      (exit)
    )
  )
  (setq    blockname (vla-get-name sourceblkobj)
    xscale      (vla-get-xscalefactor sourceblkobj)
    yscale      (vla-get-yscalefactor sourceblkobj)
    zscale      (vla-get-zscalefactor sourceblkobj)
  )
  (setq ss (ssget (list '(0 . "INSERT") (cons 2 blockname))))
  (if (null ss)
    (exit)
  )
  (setq    i 0
    n (sslength ss)
  )
  (setvar "cmdecho" 0)
  (vl-cmdf "_.UNDO" "_Begin")
  (while (< i n)
    (setq targetblkobj (ssname ss i))
    (setq targetblkobj (vlax-ename->vla-object targetblkobj))
    (vla-put-xscalefactor targetblkobj xscale)
    (vla-put-yscalefactor targetblkobj yscale)
    (vla-put-zscalefactor targetblkobj zscale)
    (setq i (1+ i))
  )
  (vl-cmdf "_.UNDO" "_END")
  (setvar "cmdecho" 1)
  (princ)
)