[讨论]：如何做带提示和过滤表的entsel ?

陌生人 · 发表于 2003-12-19 21:33:11

马上注册，结交更多好友，享用更多功能，让你轻松玩转社区。

您需要登录才可以下载或查看，没有账号？立即注册

×

如何做带提示和过滤表的entsel ?

先转贴一个龙龙仔的程序作为参考,还有别的写法,思路么?

;;BY 龙龙仔(LUCAS)
;;USAGE:(ENTSEL_LAI "\n选择直线或圆..." '((0 . "*LINE,CIRCLE")))
(defun ENTSEL_LAI (MSG FILTER / SS SSS)
;;(while (not SS)
(setq SS (entsel MSG))
(if (/= SS NIL)
(progn
(command "_.SELECT" (car SS) "")
(if (not (setq SSS (ssget "P" FILTER)))
(setq SS NIL)
(list (ssname SSS 0) (cadr SS))
)
)
)
;;)
)
;;USAGE:(ENTSEL_MSG_FILTER "\n选取POLYINE对象: " '((0 . "LWPolyline")))
(defun ENTSEL_MSG_FILTER (MSG FILTER / SSPICK PICKOBJ PT1)
(prompt MSG)
(setq SSPICK (ssget ":S" FILTER))
(if SSPICK
(progn
(setq PICKOBJ (car (ssnamex SSPICK 0)))
(setq PT1 (cadr (nth 3 PICKOBJ)))
(list (nth 1 PICKOBJ) PT1)
)
)
)

陌生人 · 发表于 2004-1-1 00:23:23

更新一下

(defun xentsel (msg filter keys / );(/ keyini pt ss lst)
(while (= nil (setq keyini (initget keys)
el (entsel (strcat msg "/<退出选择>:"))
ss (cond ((= 'STR (type el)) el)
((= 'LIST (type el))(setq pt (osnap (cadr el) "nea")
pkbox (xpkboxlst pt)
ss (ssget "c" (car pkbox) (cadr pkbox) filter))
(if ss (cons (ssname ss 0) (list pt)) nil))
((and (= nil el)(= 52 (getvar "errno"))) T)
)
) )
(princ "\n未选中过滤实体!")
)
(if (= 'T ss) nil ss)
)
;(xpkboxlst 点位) 取得取点所在处拾取框pickbox的（左上角点右下角点）点表
;(xpkboxlst (getpoint))
(defun xpkboxlst (pt / pkhigh pkrad)
(setq pkhigh (* (getvar "viewsize") (/ (getvar "pickbox") (cadr (getvar "screensize"))))
pkrad (* 1.4144 pkhigh))
(list (polar pt (* 0.75 PI) pkrad) (polar pt (* 1.75 PI) pkrad))
)

(defun xentsel (msg filter keys / );(/ keyini pt ss lst) 
  (while (= nil (setq keyini (initget keys) 
                       el (entsel (strcat msg "/<退出选择>:")) 
                       ss (cond ((= 'STR (type el)) el) 
                                ((= 'LIST (type el))(setq pt  (osnap (cadr el) "nea") 
                                                          pkbox (xpkboxlst pt) 
                                                          ss (ssget "c" (car pkbox) (cadr pkbox) filter)) 
                                                    (if ss (cons (ssname ss 0) (list pt)) nil))        
                                ((and (= nil el)(= 52 (getvar "errno"))) T) 
                          ) 
         )    )          
         (princ "\n未选中过滤实体!") 
  ) 
  (if (= 'T ss) nil ss) 
) 
;(xpkboxlst 点位) 取得取点所在处拾取框pickbox的（左上角点 右下角点）点表 
;(xpkboxlst (getpoint)) 
(defun xpkboxlst (pt / pkhigh pkrad) 
  (setq pkhigh (* (getvar "viewsize") (/ (getvar "pickbox") (cadr (getvar "screensize")))) 
        pkrad  (* 1.4144 pkhigh)) 
  (list (polar pt (* 0.75 PI) pkrad) (polar pt (* 1.75 PI) pkrad)) 
)

前面帖子已经说过，不用grread是无法在点选前亮显的，我说grread亮显的优势并不是可否亮显，而是可以在点选前就亮显。这个只是用entsel+ssget是做不到的，因此就算把我亮显的那段放到ea程序里面，也不能达到预先亮显的效果。我个人认为，如果不在点选前亮显，亮显就没有太大意义，如果认为这个不需要，那就干脆不用grread了，也就是我这贴的效果。还是一句话，个人喜好问题。
至于在程序外面写，那我认为没有必有，选已经选了，亮不亮显有什么必要？又不是求选择集。
另外，我的程序是（ssget “c”pt pt ‘((...))) ,不是(ssget pt) （见最近两贴），请不要继续就（ssget pt）的缺点展开论述（这个我早已很清楚, 我怎么老觉得说这个跑题了？这个关于（ssget pt）的问题根本就是无中生有－－你是在和我说还是和ll长老说？我是不是表错情了？）在pt点求nea后，再加上过滤后是可以选到合要求的物体的（有多个实体重合/交点处）。对于这样的交点处有多个符合过滤的实体，一样具有选择的不确定性，哪怕“c”的范围再大。只有当这一堆东西里面只有一个符合过滤的实体，返回的结果才真正“准确”。
不过，我承认模拟pickbox选择的成功率是更有保障。

zhang8755 · 发表于 2003-12-20 00:10:22

我的方法

[FONT=courier new]
(setq con1 t)
(while con1
(prompt "请选择需查看平面图的杆塔:")
(while (not (setq ssgt (car (entsel)))))
(if (= (strcase (cdr (assoc 8 (entget sgt)))) "GANTA")
(setq con1 nil)
)
)
[/FONT]

在循环中作过滤处理

陌生人 · 发表于 2003-12-20 00:21:50

不错不错.写的挺紧凑
不过可惜虽然有过滤功能,
但是没支持过滤表.过滤的能力有限.能否改一下?

eachy · 发表于 2003-12-20 00:29:49

用 Vla 方法加错误判断也可

on/off · 发表于 2003-12-20 20:17:49

以前见过这样的：
(defun hh_entsel(filt prom / E EN IN IN-TY K N);;;用entsel方式选择过滤物体
 (setq e(entsel prom))
 (if e(progn
(setq en(entget (car e))
 n(length filt)
 in 0 k t)
(while(and k (< in n))
 (setq in-ty(car (nth in filt))
 k(WCMATCH (strcase(dxf in-ty en)) (strcase(cdr(nth in filt))))
 in(1+ in))
) )
(setq k nil)
 )
 (if k e)
)

陌生人 · 发表于 2003-12-20 20:31:19

加点难度.大家一起玩玩?
功能如下,谁也来写一个?我明天贴程序

;| 带提示和过滤表的xentsel ------------------------------陌生人.2003.12
函数: (xentsel 提示信息过滤表)
返回值: nil 或者 (实体名 . 点位)点对表.
功能: 1.带提示和过滤表的entsel;
2.循环直到选中有效实体或选择退出为止;
3.返回的点对表中的点位为实体上的点;
实例: (xentsel "\n选择直线或圆..." '((0 . "*LINE,CIRCLE")))
实战:
(xentsel "\n选择直线或圆..." '((0 . "*LINE,CIRCLE")))
选择直线或圆.../<退出选择>: (此时乱点)
未选中有效实体
选择直线或圆.../<退出选择>: (此时按空格或回车)
nil
(xentsel "\n选择直线或圆..." '((0 . "*LINE,CIRCLE")))
选择直线或圆.../<退出选择>: (此时选有效物体)
(<图元名: 40093f08> (4771.53 -7575.42 0.0))
|;

复制代码

ll_j · 发表于 2003-12-21 09:07:24

这是我在编程心得中的例一：

(defun ett_ct()
(initget "C ") ;关键字“C”及空格
(setq s0 (entsel "\n设置颜色C / 选取文本:"))
(cond
( (= s0 "C") (ett_col)) ;转设置颜色子函数
( (= s0 "") nil) ;空格退出
( (and (= (type s0) 'LIST) ;选择实体
(= (cdr (assoc 0 (entget (car s0)))) "TEXT") ;判别文本
)
... ;操作内容
(ett_ct) ;编辑后返回选择
)
(t (ett_ct)) ;空选返回选择
)
)

例子主要说空选与右键退出，在“判别文本”段适当修改可以使之满足过虑表条件，将最后的“空选返回”与“判别文本”次序颠倒一下，应可以满足返回值要求。

lijiao · 发表于 2003-12-21 11:47:48

我曾经上传过一个函数，叫CS_ENTSEL，不仅有过滤功能，而且还有预先提示功能。

eachy · 发表于 2003-12-21 13:00:44

我收藏并一直在使用的函数

(defun EntSelF (Msg Filter / EntN pbDist PtPick ssPick)
(setvar "ErrNo" 0) ; clear ErrNo for loop
(while (and (not (setq EntN (if Msg ; if selection prompt
(entsel Msg) ; then (entsel) w/prompt
(entsel)
)
)
) ; while no selection (or no exit)
(/= 52 (getvar "ErrNo"))
)
) ; if null response
(cond
((= (type EntN) 'LIST) ; if not exit
(setq pbDist (abs ; return absolute number, get pixel ratio
(/ (* (/ (getvar "PickBox") (cadr (getvar "ScreenSize")))
(getvar "ViewSize")
) ; apply to viewsize (in units)
(sin (* 0.25 pi))
)
) ; at 45°
PtPick (cadr EntN)
) ; get point of pick
(if (setq ssPick (ssget "_C" ; if entities in crossing
(polar PtPick (* 1.25 pi) pbDist)
; lower left
(polar PtPick (* 0.25 pi) pbDist)
; upper right
Filter
)
) ; match filter, if any
(cons (ssname ssPick 0) (list PtPick))
)
)
((= (type EntN) 'STR) EntN);;支持 Initget 关键字
)
)

(defun EntSelF (Msg Filter / EntN pbDist PtPick ssPick) 
  (setvar "ErrNo" 0)                        ; clear ErrNo for loop 
  (while (and (not (setq EntN (if Msg        ; if selection prompt 
                                (entsel Msg) ; then (entsel) w/prompt 
                                (entsel) 
                              ) 
                   ) 
              )                                ; while no selection (or no exit) 
              (/= 52 (getvar "ErrNo")) 
         ) 
  )                                        ; if null response 
  (cond 
    ((= (type EntN) 'LIST)                ; if not exit 
     (setq pbDist (abs                        ; return absolute number, get pixel ratio 
                    (/ (* (/ (getvar "PickBox") (cadr (getvar "ScreenSize"))) 
                          (getvar "ViewSize") 
                       )                ; apply to viewsize (in units) 
                       (sin (* 0.25 pi)) 
                    ) 
                  )                        ; at 45° 
           PtPick (cadr EntN) 
     )                                        ; get point of pick 
     (if (setq ssPick (ssget "_C"        ; if entities in crossing 
                             (polar PtPick (* 1.25 pi) pbDist) 
                                        ; lower left 
                             (polar PtPick (* 0.25 pi) pbDist) 
                                        ; upper right 
                             Filter 
                      ) 
         )                                ; match filter, if any 
       (cons (ssname ssPick 0) (list PtPick)) 
     ) 
    ) 
    ((= (type EntN) 'STR) EntN);;支持 Initget 关键字 
  ) 
)

陌生人 · 发表于 2003-12-21 13:17:39

最初由 lijiao 发布
[B]我曾经上传过一个函数，叫CS_ENTSEL，不仅有过滤功能，而且还有预先提示功能。 [/B]

预先提示什么内容?

测试下我的:

;| 带提示和过滤表的xentsel ------------------------------陌生人 2003.12
v1.0 2003.12完成.
函数: (xentsel 提示信息过滤表)
返回值: nil 或者 (实体名 . 点位)点对表.
功能: 1.带提示和过滤表的entsel;
2.循环直到选中有效实体或选择退出为止;
3.返回的点对表中的点位为实体上的点;
实例: (xentsel "\n选择直线或圆..." '((0 . "*LINE,CIRCLE")))
|;
(defun xentsel (msg filter / pt ss)
(while (not(or (setq el (entsel (strcat msg "/<退出选择>:"))
ss (if el (ssget (cadr el) filter)))
(= 52 (getvar "errno"))))
(princ "\n未选中有效实体")
)
(if ss (cons (ssname ss 0) (list(osnap (cadr el) "nea")))
nil)
)

eachy · 发表于 2003-12-21 13:28:46

最初由陌生人发布
[B]

预先提示什么内容?

测试下我的:
[CODE]
;| 带提示和过滤表的xentsel ----... [/B]

有时候还需要关键字的

陌生人 · 发表于 2003-12-21 15:14:22

什么时候用关键字,举个例子?

;v1.1 2003.12.20.改写:加入带亮显提示功能;
;实例:(xentsel "\n选择直线或圆..." '((0 . "*LINE,CIRCLE")))
;:使用(grread T 4 2),放弃使用entsel;
(defun xentsel (msg filter / roop el ss e entl draw)
(setq roop T entl nil)
(while roop
(setq el (grread t 4 2))
(cond
((member el '((2 13)(2 32))) (princ "\n你选择了退出,未选中实体!")(setq roop nil))
((setq ss (ssget (cadr el) filter))
(setq e (ssname ss 0))
(if e0
(if(not(equal e e0))(redraw e0 4)(redraw e 3))
(setq e0 e draw (redraw e 3))
)
(if (= 3 (car el))
(setq roop nil
entl (cons e (list (osnap (cadr el) "nea")))
draw (redraw e 4))
)
)
(T (if e0 (redraw e0 4))(setq e0 nil))
)
)
(if entl entl nil)
)

哈哈,还没有其他回复.我又来啦

;v1.1 2003.12.20.改写:加入带亮显提示功能;
;v1.2 支持关键字返回;
;实例:(xentsel "\n选择直线或圆/O-调整参数:" '((0 . "*LINE,CIRCLE")) "O")
;技巧:使用(grread T 4 2),放弃使用entsel;
;|
实例:
Command: (xentsel "\n选择直线或圆/O-调整参数:" '((0 . "*LINE,CIRCLE")) "O")
选中符合要求的实体,返回(实体名 . 点)双元表;
经过符合要求的实体;
未选中符合要求的实体;
空格退出;
输入非关键字,继续提问;
输入关键字"O",返回"O";
|;

复制代码

继续: 看另外一篇帖子,发现一个问题比较有意思:
用entsel 可以透明使用zoom命令,但是不能预先亮显符合要求的实体.
用grread则正好相反.有没有什么办法可以鱼和熊掌兼得呢?

eachy · 发表于 2003-12-21 22:42:35

你这个可以在提示的时候返回字符串吗? 就是 entsel 前加 initget 字段。

陌生人 · 发表于 2003-12-22 00:26:09

;v1.2 支持关键字返回;
;实例:(xentsel "\n选择直线或圆/O-调整参数:" '((0 . "*LINE,CIRCLE")) "O")
上面的 "o"就是关键字, 可看看演示.
函数:(xentsel 提示过滤表关键字)

eachy · 发表于 2003-12-22 00:54:41

最初由陌生人发布
[B];v1.2 支持关键字返回;
;实例:(xentsel "\n选择直线或圆/O-调整参数:" '((0 . "*LINE,CIRCLE")) "O")
上面的 "o"就是关键字, 可看看演示.
函数:(xentsel 提示过滤表关键字) [/B]

一个字符的关键字太简单了，这样的效果

(initget 128 "A F C M R TL TC TR ML")
(setq e (entsel "\n[对齐(A)/调整(F)/中心(C)/中间(M)/右(R)/左上(TL)/中上(TC)/右上(TR)/左中(ML)]: ")
(cond
......

用 entsel 加上 redraw 也没什么不好，还可以用 zoom

账号		自动登录	找回密码
密码			立即注册

[讨论]：如何做带提示和过滤表的entsel ?

马上注册，结交更多好友，享用更多功能，让你轻松玩转社区。

相关帖子

浏览过的版块