[求助]：如何判断一个物体所在的group名称

urljit · 发表于 2003-12-23 17:22:50

马上注册，结交更多好友，享用更多功能，让你轻松玩转社区。

您需要登录才可以下载或查看，没有账号？立即注册

×

在编程期间遇到如何判断一个物体所在的group名称的问题，请各位各抒高见。

eachy · 发表于 2003-12-23 18:14:18

最初由 urljit 发布
[B]在编程期间遇到如何判断一个物体所在的group名称的问题，请各位各抒高见。 [/B]

自己画一个线，编组，用Vlisp的浏览数据，一层层查下去，另外建议你看看这个帖子
http://www.xdcad.net/forum/showthread.php?threadid=127718

lsjjm · 发表于 2003-12-23 18:39:47

请参考:
(defun GetEntGroupNames (ObjEnt / Ent_ID ListGroups)
  (setq Ent_ID (vla-get-objectid ObjEnt))
  (vlax-for eachGroup (vla-get-groups activedocument_gobj)
(vlax-for eachEnt eachGroup
   (if (equal (vla-get-objectid eachEnt) Ent_ID)
      (setq ListGroups (cons (vla-get-name eachGroup) ListGroups))
   )
)
  )
  (reverse ListGroups)
)

wkai · 发表于 2003-12-23 20:12:03

最初由 lsjjm 发布
[B]请参考:
(defun GetEntGroupNames (ObjEnt / Ent_ID ListGroups)
(setq Ent_ID (vla-get-objectid ObjEnt))
(vlax-for eachGroup (vla-get-groups activedocument_gobj[/COLOR] )
(vlax-for eachEnt eachGroup
... [/B]

activedocument_gobj 是什么？

lsjjm · 发表于 2003-12-24 05:11:39

不好意思, 上面的是个子程序,
(setq ActiveDocument_gobj (vla-get-activedocument (vlax-get-acad-object)))

urljit · 发表于 2003-12-24 15:47:57

不好意思，我还没有研究过vl，各位高手，有autolisp吗？

LUCAS · 发表于 2003-12-26 08:01:50

马上注册，结交更多好友，享用更多功能，让你轻松玩转社区。

您需要登录才可以下载或查看，没有账号？立即注册

×

;;EACHY
;;(test (get_object_reactor (car (entsel))));
;;测试实体所属组名
(defun test (lst / g)
(foreach item (mapcar 'vlax-ename->vla-object lst)
(if (= (vla-get-objectname item) "AcDbGroup")
(setq g (cons (vla-get-name item) g)
)
)
)
g
)
;;获取实体的永久反应器
(defun get_object_reactor (e / elst lst etlst)
(setq elst (entget e))
(if (and (assoc 102 elst)
(= (cdr (assoc 102 elst)) "{ACAD_REACTORS")
)
(progn
(setq lst (cdr (member '(102 . "{ACAD_REACTORS") elst)))
(while (= (caar lst) 330)
(setq etlst (cons (cdar lst) etlst))
(setq lst (cdr lst))
)
)
)
etlst
)
;;/////////////////////////////////////////////////////////////////////////
;;
;; GroupNames ( Ename )
;;
;; Copyright c 2001 Michael Puckett - All Rights Reserved
;;
;;/////////////////////////////////////////////////////////////////////////
;;
;; Return a list of the group names the entity is a child of,
;; innermost first.
;;
;;/////////////////////////////////////////////////////////////////////////
;;(GROUPNAMES (car(entsel)))
(defun GROUPNAMES (ENAME / KEY DICT RESULT)
(setq KEY (cons 340 ENAME)
DICT (dictsearch (namedobjdict) "acad_group")
)
(while (setq DICT (member (assoc 3 DICT) DICT))
(if (member KEY (entget (cdadr DICT)))
(setq RESULT (cons (cdar DICT) RESULT))
)
(setq DICT (cddr DICT))
)
(reverse RESULT)
)

;;EACHY 
;;(test (get_object_reactor (car (entsel)))); 
;;测试实体所属组名 
(defun test (lst / g) 
  (foreach item        (mapcar 'vlax-ename->vla-object lst) 
    (if        (= (vla-get-objectname item) "AcDbGroup") 
      (setq g (cons (vla-get-name item) g) 
      ) 
    ) 
  ) 
  g 
) 
 
;;获取实体的永久反应器 
(defun get_object_reactor (e / elst lst etlst) 
  (setq elst (entget e)) 
  (if (and (assoc 102 elst) 
           (= (cdr (assoc 102 elst)) "{ACAD_REACTORS") 
      ) 
    (progn 
      (setq lst (cdr (member '(102 . "{ACAD_REACTORS") elst))) 
      (while (= (caar lst) 330) 
        (setq etlst (cons (cdar lst) etlst)) 
        (setq lst (cdr lst)) 
      ) 
    ) 
  ) 
  etlst 
) 
 
;;///////////////////////////////////////////////////////////////////////// 
;; 
;;  GroupNames ( Ename ) 
;; 
;; Copyright c 2001 Michael Puckett - All Rights Reserved 
;; 
;;///////////////////////////////////////////////////////////////////////// 
;; 
;;  Return a list of the group names the entity is a child of, 
;;  innermost first. 
;; 
;;///////////////////////////////////////////////////////////////////////// 
;;(GROUPNAMES (car(entsel))) 
(defun GROUPNAMES (ENAME / KEY DICT RESULT) 
  (setq        KEY  (cons 340 ENAME) 
        DICT (dictsearch (namedobjdict) "acad_group") 
  ) 
  (while (setq DICT (member (assoc 3 DICT) DICT)) 
    (if        (member KEY (entget (cdadr DICT))) 
      (setq RESULT (cons (cdar DICT) RESULT)) 
    ) 
    (setq DICT (cddr DICT)) 
  ) 
  (reverse RESULT) 
)

eachy · 发表于 2003-12-26 13:34:51

http://www.vbdesign.net/expresso/archive/topic/2237.html
一个 NamedObjDict 资料，不错

<table border="1" cellpadding="0" cellspacing="0" style="border-collapse: collapse" bordercolor="#111111" width="700" id="AutoNumber1" height="498">
<tr>
<td width="100%" height="489">
<iframe name="I1" width="100%" height="100%" src="http://www.vbdesign.net/expresso/archive/topic/2237.html">
浏览器不支持嵌入式框架或配置为不显示嵌入式框架
</iframe>
</td>
</tr>
</table>

复制代码

urljit · 发表于 2003-12-28 19:05:32

感谢大家的热情,不过,还是vl啊!?

LUCAS · 发表于 2003-12-29 08:01:12

看清楚我的是autolisp

panzhongw · 发表于 2003-12-29 10:25:01

不错！很有用
有谁能顺带讲一下对组的添加和删除

urljit · 发表于 2003-12-29 18:15:24

(vla-get-name item) 是autolisp吗?

LUCAS · 发表于 2003-12-30 08:04:08

拜託注意一下

;;/////////////////////////////////////////////////////////////////////////
;;
;;  GroupNames ( Ename )
;;
;; Copyright c 2001 Michael Puckett - All Rights Reserved
;;
;;/////////////////////////////////////////////////////////////////////////
;;
;;  Return a list of the group names the entity is a child of,
;;  innermost first.
;;
;;/////////////////////////////////////////////////////////////////////////
;;(GROUPNAMES (car(entsel)))

qiankuncq · 发表于 2003-12-30 08:16:55

斑竹的calender很漂亮。能否提供下载？

urljit · 发表于 2004-1-1 22:59:19

13楼：没看仔细，不好意思，谢谢！

最初由 qiankuncq 发布
[B]斑竹的calender很漂亮。能否提供下载？ [/B]

好像有个软件叫flashsaver，安装后自主下载你看到的flash吧！

账号		自动登录	找回密码
密码			立即注册

[求助] [求助]：如何判断一个物体所在的group名称

马上注册，结交更多好友，享用更多功能，让你轻松玩转社区。

相关帖子

Re: [求助]：如何判断一个物体所在的group名称

马上注册，结交更多好友，享用更多功能，让你轻松玩转社区。

相关帖子

浏览过的版块