[求助]：帮忙看一下这段画折断线的lisp代码

guanhuaming

帮忙看一下以下画折断线的代码：
[program]
(defun c:test ()
   (setq p0 (getpoint "\nInput point"))
   (setq pe (getpoint p0 "\nInput Second Point:"))
   (setq dist (distance p0 pe))
   (if (> dist 200.0)
      (setq h (/ dist 50.0)) (setq h (/ dist 40.0))   
   )
   (if (< dist 100.00) (setq h (/ dist 30.0)))
   (if (< dist 50.00) (setq h (/ dist 20.0)))
   (if (< dist 20.00) (setq h (/ dist 12.0)))
   (setq a (angle p0 pe)
         p1 (polar p0 a (- (/ dist 2) h))
         p2 (polar p1 (+ a (/ pi 2)) h)
         p4 (polar p0 a (+ (/ dist 2) h))
         p3 (polar p4 (- a (/ pi 2)) h)
   )
   (princ p0)
   (princ p1)
   (princ p2)
   (princ p3)
   (princ p4)
   (princ pe)
   (vl-cmdf "pline" p0 p1 p2 p3 p4 pe "")
) [/program]

为什么p0,p1,p2,p3,p4,pe都显示正确，可最后一行画出来的折断线不对?

lsjjm

你这是改的别人的程序吧?  没有问题呀? "最后一行画出来的折断线" 有什么不对?

naster

经过测试，程序改为如下，没有出现任何问题，原因是没有把捕捉取消，导致画线时捕捉点[program]
(defun c:test (/ oldosmode p0 pe p1 p2 p3 p4 a dist)
  (setq oldosmode (getvar "osmode"))
  (setvar "osmode" 0)
  (setq p0 (getpoint "\nInput point"))
  (setq pe (getpoint p0 "\nInput Second Point:"))
  (setq dist (distance p0 pe))
  (cond                                        ;cond
    ((> dist 200.0) (setq h (/ dist 50.0)))
    ((and (> dist 200.0) (< dist 100.00))
     (setq h (/ dist 40.0))
    )
    ((and (< dist 100.00) (> dist 50.00))
     (setq h (/ dist 30.0))
    )
    ((and (< dist 50.00) (> dist 20.00)) (setq h (/ dist 20.0)))
    ((< dist 20.00) (setq h (/ dist 12.0)))
  )                                        ;endcond
  (setq        a  (angle p0 pe)
        p1 (polar p0 a (- (/ dist 2) h))
        p2 (polar p1 (+ a (/ pi 2)) h)
        p4 (polar p0 a (+ (/ dist 2) h))
        p3 (polar p4 (- a (/ pi 2)) h)
  )
  (princ p0)
  (princ p1)
  (princ p2)
  (princ p3)
  (princ p4)
  (princ pe)
  (vl-cmdf "pline" p0 p1 p2 p3 p4 pe "")
  (setvar "osmode" oldosmode)
)[/program]

guanhuaming

最初由 lsjjm 发布
[B]你这是改的别人的程序吧?  没有问题呀? "最后一行画出来的折断线" 有什么不对? [/B]

是的，是看了你写的程序后改了一点点。忘了先谢谢你了。

wyj_007

没把捕捉osmode设为0即取消，导致画时的东西不是想要的，这个对初学者来说是经常犯的错误。以前我也吃过这种苦，后来不犯了。

guanhuaming

非常感谢大家的帮助，终于完成了一个画折断线的代码，弄出来与需要的人分享，代码如下：

(defun c:zdx(/ oldosmode oldecho oldplinewid p0 pe pm p1 p2 p3 p4 a dist h)
   (vl-load-com)
   (setq oldosmode (getvar "OSMODE"))
   (setq oldecho (getvar "CMDECHO"))
   (setq oldplinewid (getvar "PLINEWID"))
   (setvar "osmode" 0)
   (setvar "CMDECHO" 0)
   (setvar "PLINEWID" 0)
   (setq p0 (getpoint "\nInput first point:"))
   (setq pe (getpoint p0 "\nInput Second Point:"))
   (setq dist (distance p0 pe))
   (if (> dist 200.0)
      (setq h (/ dist 50.0)) (setq h (/ dist 40.0))   
   )
   (if (< dist 100.00) (setq h (/ dist 30.0)))
   (if (< dist 50.00) (setq h (/ dist 20.0)))
   (if (< dist 20.00) (setq h (/ dist 12.0)))
   (setq a (angle p0 pe)
         pm (polar p0 a (/ dist 2))
         p1 (polar p0 a (- (/ dist 2) (/ h 2)))
         p2 (polar pm (+ a (/ pi 2)) h)
         p3 (polar pm (- a (/ pi 2)) h)
         p4 (polar p0 a (+ (/ dist 2) (/ h 2)))
   )
   (vl-cmdf "pline" p0 p1 p2 p3 p4 pe "")
   (setvar "PLINEWID" oldplinewid)
   (setvar "CMDECHO" oldecho)
   (setvar "OSMODE" oldosmode)
   (princ)
)