（完成）[编程申请]：等距measure、等距divide,请xd编程.

ydf7332462 · 发表于 2002-10-31 22:15:14

马上注册，结交更多好友，享用更多功能，让你轻松玩转社区。

您需要登录才可以下载或查看，没有账号？立即注册

×

1 acad的measure divide是等path,且起终点只是端点.
2 可布井（栽电杆）是等distance,且起终点不一定是端点，而是pick point
3 distance是两点间（同acad的measure divide）
4 请xd编程等距measure、等距divide

XDSoft · 发表于 2002-10-31 22:19:42

最初由 ydf7332462 发布
[B]1 acad的measure divide是等path,且起终点只是端点.
2 可布井（栽电杆）是等distance,且起终点不一定是端点，而是pick point
3 distance是两点间（同acad的measure divide）
4 请xd编程等距measure、等距divide [/B]

把各种要求，贴图详细说明下。

LIFUPING · 发表于 2002-11-5 10:45:36

本人在使用divide、measure命令时，也有同感，补充说明见附件

xgwl · 发表于 2002-11-7 20:02:14

是个好想法，有时我也遇到这样的苦脑！

e2002 · 发表于 2002-11-8 15:48:47

我写的DistanceCopy和ArrangeCopy估计是你想要的...

你可以在下载中心找到 lkpt工具集

eachy · 发表于 2002-11-9 13:32:09

用什么作Measure、Divide？Block & Point?

ydf7332462 · 发表于 2002-11-9 20:50:31

1 Block可以
2 lkpt中,象不是.
是沿线上两点间距离distance,不是acad的等path
且起终点不一定是端点，而是pick point,default 起点是端点

cy956 · 发表于 2002-11-9 22:23:41

lisp只能用vlax－curve－xxx可以解决。

eachy · 发表于 2002-11-10 08:08:23

http://www.xdcad.net/forum/showthread.php?postid=86536#post86536

HSXLJWHT · 发表于 2002-11-12 14:21:14

可以在pick point 处将pline断开，然后在measure.

ydf7332462 · 发表于 2002-11-12 22:02:20

1 msdg说的问题是acad中的等curve，但起终点不是curve的end.与城市road、hiway、railroad河港中心线的桩号有相近之处，
我的做法也是苯办法同msdg，如果XD能给我们做好，就太感激了！
2 不过这里说的是等chord，我的做法是circle-找交点-再circle...Pline,布方块（well),太麻烦
修改更不必说

梦断江南 · 发表于 2002-11-13 02:10:37

最初由 eachy 发布
[B]http://www.xdcad.net/forum/showthread.php?postid=86536#post86536 [/B]

eachy, 你的程序等分 <1>, 好像有问题。
3个建议：
1。等距离输入距离时，最好用 getdist 而不是 getreal
2。完成后自动消除参考点的显示,但是显示消除得不完全(cadr2002)。查一下是什么原因。
3。我认为在选p1,p2点处也应该打点。

另外，ydf 你的要求eachy的程序基本能满足，你试一试。
ea有空做过flashcam教学上来吧

eachy · 发表于 2002-11-13 12:19:58

最初由梦断江南发布
[B]

eachy, 你的程序等分 <1>, 好像有问题。
3个建议：
1。等距离输入距离时，... [/B]

改好了。

[FONT=courier new]
;|
命令：XDTB_Curve_2pDiv
功能：在曲线指定两点间Measure或Divide，可以用Point或Block
说明：1 用Point等分或等距时要先设置点样式，
2 插入块的名称不可为 1 或 2
3 拷贝至工具箱Lisp下运行
技术支持请访问“XDsoft CAD开发论坛” [url]http://www.xdcad.net/forum[/url]
at 2002.11.13 By Eachy Email: [email]eachy@21cn.com[/email]
|;
($xdrx_load "xdlsp.lsp")
(DEFUN c:XDTB_Curve_2pDiv (/ $2pt_getpointatdist e
p1 p2 $_dist tf
$ang $ea_scl p $prompt
_blk tf1 box
)
(defun $2pt_getpointatdist (e p0 p00 dist / ptl p3)
(setq p3 (xdrx_getpointatdist e p0 dist))
(while (> (xdrx_curve_getdistatpoint e p00)
(xdrx_curve_getdistatpoint e p3)
)
(if ptl
(setq ptl (append (list p3) ptl))
(setq ptl (list p3 p0))
)
(setq p3 (xdrx_getpointatdist e p3 dist))
)
(append (list p00) ptl)
)
(defun $prompt (str / kword $div $_dist)
(if (= (setq kword
(getstring (if str
"\n[1 等分/2 等距/3 输入块名]<1>: "
"\n[1 等分/2 等距/<1>: "
)
)
)
""
)
(setq kword "1")
)
(cond
((or (= kword "1") (= kword "2"))
(progn
(if (= kword "1")
(progn
(setq $div (getint "\n均分份数: "))
(setq $_dist (/ $dist $div)
)
)
(setq $_dist (getdist p1 "\n间隔距离: "))
)
)
)
)
(list kword $_dist)
)
(xdrx_begin)
(xdrx_sysvar_push "osmode")
(if (setq
e (car
(xdrx_entsel
"\n选择曲线(*Line,Arc,Ellipse): "
'((0 . "*line,arc,ellipse"))
)
)
)
(progn
(xdrx_ucson)
(redraw e 3)
(setq box (xdrx_entity_box e))
(if (setq tf1 (apply 'xdrx_isptoffscr box))
(progn
(xdrx_drawing_viewsave)
(xdrx_drawing_zoomw (car box) (nth 2 box))
)
)
(setq p1 (getpoint "\n第一点: "))
(if (not (xdrx_ison p1 e))
(setq p1 (cadr (xdrx_curve_ClosestPoint e p1)))
)
($xdlsp_grdraw p1)
(setq p2 (getpoint "\n第二点: "))
(if (not (xdrx_ison p2 e))
(setq p2 (cadr (xdrx_curve_ClosestPoint e p2)))
)
($xdlsp_grdraw p2)
(if (not (equal p1 p2))
(progn
(if (> (xdrx_curve_getdistatpoint e p1)
(xdrx_curve_getdistatpoint e p2)
)
(xdrx_curve_reverse e)
)
(princ
(strcat
"\n两点间距离 = "
(rtos (setq $dist (xdrx_curve_getDistAtPoint e p1 p2))
2
3
)
)
)
(setq tf t)
(while tf
(setq $_dist ($prompt t))
(cond
((or (= (car $_dist) "1") (= (car $_dist) "2"))
(foreach p ($2pt_getpointatdist e p1 p2 (last $_dist))
(command ".point" p)
)
(command)
(setq tf nil)
)
(T
(if (tblobjname "block" (setq _blk (car $_dist)))
(progn
(if (not (setq $ea_scl (getreal "\n图块比例<1>: ")))
(setq $ea_scl 1)
)
(setq $_dist (last ($prompt nil)))
(foreach p ($2pt_getpointatdist e p1 p2 $_dist)
(setq $ang (car (xdrx_getperpline e p)))
(command ".insert" _blk p $ea_scl $ea_scl $ang)
)
(setq tf nil)
)
(progn
(princ (strcat "\n未找到图块 " _blk " 。"))
(setq tf nil)
)
)
)
)
)
)
)
(redraw e 4)
($xdlsp_grdraw p1)
($xdlsp_grdraw p2)
(if tf1
(xdrx_drawing_viewres)
)
(xdrx_ucsoff)
)
)
(xdrx_sysvar_pop)
(xdrx_end)
(princ)
)
[/FONT]

[FONT=courier new] 
;| 
命令：XDTB_Curve_2pDiv 
 
功能：在曲线指定两点间Measure或Divide，可以用Point或Block 
 
说明：1 用Point等分或等距时要先设置点样式， 
 
      2 插入块的名称不可为 1 或 2 
 
      3 拷贝至工具箱Lisp下运行 
       
      技术支持请访问“XDsoft CAD开发论坛” [url]http://www.xdcad.net/forum[/url] 
 
      at 2002.11.13 By Eachy  Email: [email]eachy@21cn.com[/email] 
 
|; 
($xdrx_load "xdlsp.lsp") 
(DEFUN c:XDTB_Curve_2pDiv (/              $2pt_getpointatdist e 
                            p1              p2        $_dist          tf 
                            $ang      $ea_scl        p          $prompt 
                            _blk      tf1        box 
                           ) 
  (defun $2pt_getpointatdist (e p0 p00 dist / ptl p3) 
    (setq p3 (xdrx_getpointatdist e p0 dist)) 
    (while (> (xdrx_curve_getdistatpoint e p00) 
              (xdrx_curve_getdistatpoint e p3) 
           ) 
      (if ptl 
        (setq ptl (append (list p3) ptl)) 
        (setq ptl (list p3 p0)) 
      ) 
      (setq p3 (xdrx_getpointatdist e p3 dist)) 
    ) 
    (append (list p00) ptl) 
  ) 
  (defun $prompt (str / kword $div $_dist) 
    (if        (= (setq kword 
                  (getstring (if str 
                               "\n[1 等分/2 等距/3 输入块名]<1>: " 
                               "\n[1 等分/2 等距/<1>: " 
                             ) 
                  ) 
           ) 
           "" 
        ) 
      (setq kword "1") 
    ) 
    (cond 
      ((or (= kword "1") (= kword "2")) 
       (progn 
         (if (= kword "1") 
           (progn 
             (setq $div (getint "\n均分份数: ")) 
             (setq $_dist (/ $dist $div) 
             ) 
           ) 
           (setq $_dist (getdist p1 "\n间隔距离: ")) 
         ) 
       ) 
      ) 
    ) 
    (list kword $_dist) 
  ) 
  (xdrx_begin) 
  (xdrx_sysvar_push "osmode") 
  (if (setq 
        e (car 
            (xdrx_entsel 
              "\n选择曲线(*Line,Arc,Ellipse): " 
              '((0 . "*line,arc,ellipse")) 
            ) 
          ) 
      ) 
    (progn 
      (xdrx_ucson) 
      (redraw e 3) 
      (setq box (xdrx_entity_box e)) 
      (if (setq tf1 (apply 'xdrx_isptoffscr box)) 
        (progn 
          (xdrx_drawing_viewsave) 
          (xdrx_drawing_zoomw (car box) (nth 2 box)) 
        ) 
      ) 
      (setq p1 (getpoint "\n第一点: ")) 
      (if (not (xdrx_ison p1 e)) 
        (setq p1 (cadr (xdrx_curve_ClosestPoint e p1))) 
      ) 
      ($xdlsp_grdraw p1) 
      (setq p2 (getpoint "\n第二点: ")) 
      (if (not (xdrx_ison p2 e)) 
        (setq p2 (cadr (xdrx_curve_ClosestPoint e p2))) 
      ) 
      ($xdlsp_grdraw p2) 
      (if (not (equal p1 p2)) 
        (progn 
          (if (> (xdrx_curve_getdistatpoint e p1) 
                 (xdrx_curve_getdistatpoint e p2) 
              ) 
            (xdrx_curve_reverse e) 
          ) 
          (princ 
            (strcat 
              "\n两点间距离 = " 
              (rtos (setq $dist (xdrx_curve_getDistAtPoint e p1 p2)) 
                    2 
                    3 
              ) 
            ) 
          ) 
          (setq tf t) 
          (while tf 
            (setq $_dist ($prompt t)) 
            (cond 
              ((or (= (car $_dist) "1") (= (car $_dist) "2")) 
               (foreach        p ($2pt_getpointatdist e p1 p2 (last $_dist)) 
                 (command ".point" p) 
               ) 
               (command) 
               (setq tf nil) 
              ) 
              (T 
               (if (tblobjname "block" (setq _blk (car $_dist))) 
                 (progn 
                   (if (not (setq $ea_scl (getreal "\n图块比例<1>: "))) 
                     (setq $ea_scl 1) 
                   ) 
                   (setq $_dist (last ($prompt nil))) 
                   (foreach p ($2pt_getpointatdist e p1 p2 $_dist) 
                     (setq $ang (car (xdrx_getperpline e p))) 
                     (command ".insert" _blk p $ea_scl $ea_scl $ang) 
                   ) 
                   (setq tf nil) 
                 ) 
                 (progn 
                   (princ (strcat "\n未找到图块 " _blk " 。")) 
                   (setq tf nil) 
                 ) 
               ) 
              ) 
            ) 
          ) 
        ) 
      ) 
      (redraw e 4) 
      ($xdlsp_grdraw p1) 
      ($xdlsp_grdraw p2) 
      (if tf1 
        (xdrx_drawing_viewres) 
      ) 
      (xdrx_ucsoff) 
    ) 
  ) 
  (xdrx_sysvar_pop) 
  (xdrx_end) 
  (princ) 
) 
[/FONT]

ydf7332462 · 发表于 2002-11-17 20:41:51

1 plant tree可以,解决了msdgd的贴子，但绘筘筋、有方向的块（方井）等，还要measure中block的后两选项，沿实体(Yes/No)
2 以上并未解决我的最初贴子，我的难题是curve上两点间直线距离相等--即等距measure、div
3 我下载的上三个是curve上是两点间curve长--即等长measure、div

XDSoft · 发表于 2002-11-17 23:43:49

最初由 ydf7332462 发布
[B]1 plant tree可以,解决了msdgd的贴子，但绘筘筋、有方向的块（方井）等，还要measure中block的后两选项，沿实体(Yes/No)
2 以上并未解决我的最初贴子，我的难题是curve上两点间直线距离相等--即等距measure、div
3... [/B]

文字不如图来的详细，你截个图吧，图上用文字符号标出各种可能的情况。看看，我们给你写。

账号		自动登录	找回密码
密码			立即注册

（完成）[编程申请]：等距measure、等距divide,请xd编程.

马上注册，结交更多好友，享用更多功能，让你轻松玩转社区。

相关帖子

Re: [编程申请]：等距measure、等距divide,请xd编程.