[分享]：用xdapi写了一个"扩展修剪程序",自动判断内外。

aeo

例子见snsj的贴.
支持的东西要多一些,要xd_api ,但不要ET工具.
自动判断内外,>=R14可用.
[php]
(defun c:ext( / apix trim: area box e el in l name p1 p2 pt pts
                pts-no pts-yes ss tf yes e-del high pts-new)

(defun apix()(/ (getvar "VIEWSIZE")(cadr(getvar "screensize"))))

(defun trim:(l / el p1 p2 yes)
   ;;;(my-princ (sslength ss))
   (setq l(mapcar '(lambda(x)(trans x 0 1)) l)
         p1(car l)
         l(cdr l)
   )
   (command "trim" ss "" )
   (while(setq yes t el (entlast) p2(car l))
     (while yes
       (command "f" p1 p2 "")
       (if(equal(entlast)el)(setq yes nil)(setq el(entlast)))
     )
     (setq l(cdr l) p1 p2)
   )
   (command "")  
)

;;;-------------
(xdrx_begin '(("osmode" . 0)("cmdecho" . 0)("plinewid" . 0)))
(if(and
   (princ "\n没考虑\"层锁定\",自己处理.  trim框和框不要相交")
   (princ "\n支持\"*line,arc,circle,ellipse,*text,region\", 选择: ")
   (setq ss(ssget '((0 . "*line,arc,circle,ellipse,*text,region"))))
   (setq box (xdrx_entity_box ss))
   (setq pt(getpoint "\nTrim点: "))
   )
  (progn
;;;zoom...
    (setq  p1(car box)
           p2(caddr box)
     )
    (if (setq tf (xdrx_isptoffscr p1 p2))
               (xdrx_drawing_zoomw p1 p2);;;一定要zoom的，不然会出错的，不光剪不了.
    )
   (command "zoom" "0.95x")            ;;;在 trim框外面时...
;;;分类...
(xdrx_SetSsToDb ss 0)  
(while(setq e (xdrx_GetEntData 0))
       (setq name (xdrx_GetEntDxf 0))
      (cond((wcmatch  name "LINE,ARC")(setq area 0))
           ((wcmatch  name "*TEXT")
             (setq high(xdrx_GetEntDxf 40)
                   pts (xdrx_textbox e) ;;.ttf -->xdrx_textbox出错 bug??
                   area (progn(apply 'command (cons "PLINE" pts))(command "c"))
                   ;;;text:Trim的框不是textbox,那要扩大多少?
                   pts (xdrx_curve_offset (entlast)(* 0.2 high))
                   high   (entdel(entlast))
                   pts-yes(cons pts pts-yes)
                   e-del(cons(entdel e)e-del)   
             )
           )
           ((eq name "REGION")
             (setq  area nil
                    pts-yes(cons (xdrx_region_vertex e) pts-yes)
             )
           )
           (t
             (command"area""_ob" e)
             (setq area(getvar "area"))
       )  )
       (cond((= area 0)
              (command "offset"(apix) e pt "")
              (setq pts(xdrx_getsamplept (entlast)))
              (entdel (entlast))
              (setq pts-no(cons pts pts-no)) ;没面积
            )
           ((null area))
           (t
              (setq pts(xdrx_getsamplept e)
                    pts-yes(cons pts pts-yes)  ;有面积
                    e-del(cons(entdel e)e-del) ;pl有宽度，会trim到自己.
              )
           )
       )
)
;;; 点 在不在 里面?-->in
   (setq pts pts-yes)
   (while(and (not in)(setq l(car pts)))
      (if (apply 'xdrx_isinside(cons pt l))(setq in t))  ;xdrx_isinside有Bug ??
      (setq pts(cdr pts))
   )
;;;处理"有面积"的  没用 xdrx_curve_offset-->对text等不行
  (foreach l pts-yes
    (apply 'command (cons "PLINE" l))(command "")
    (setq el(entlast)
          e-del(cons el e-del)  ;几个trim框自相交会出问题，会删不干净
          ss(ssadd el ss)
           l(if in (xdrx_curve_offset el (- (apix)))
                   (xdrx_curve_offset el (apix)))
          pts-new(cons l pts-new)
    ))
    (foreach l pts-new(trim: l)  )
;;;处理"没面积"的
  (foreach l pts-no
    (trim: l)
  )
;;;end
(foreach x e-del(entdel x))
  (command "zoom" "p")
  (if tf (command "zoom" "p") )
))
  
  (xdrx_end)(princ)
)[/php]
大家试一下，可能有没考虑的东西
写的有点绕.

xgwl

不能在cad2004 和2005 , 工具箱3.0下用吗? 怎么能启动命令确不能运算到最后结果呢?

yjtdkj

请问xd_api 是什么？我是CAD2004能不能用？

xxxyzxx

倒，工具很实用啊，但有个问题要说，我比较喜欢使用快捷命令，用晓东开发的程序是否也能使用快捷命令呢？

yjtdkj

错误: no function definition: MY-PRINC
是不是要装什么工具？

aeo

最初由 yjtdkj 发布
[B]错误: no function definition: MY-PRINC
是不是要装什么工具？ [/B]

难怪，改了，调试的时候用的,去掉那一行就行了.

挺好用的，特别是弧线为边trim的时候.

lhj743

菜鸟提问：加载后是输入什么命令来运行啊？
trim“ss”－－把我弄晕了！

dicck

顶

j1187

加载后运行ext,晕,刚才都忘了

wangwei_66

最初由 xxxyzxx 发布
[B]倒，工具很实用啊，但有个问题要说，我比较喜欢使用快捷命令，用晓东开发的程序是否也能使用快捷命令呢？ [/B]

快捷健可以自己做一个。

qiankuncq

剪简单的图形还比较管用。在剪裁地形图时就出问题了。提示非法操作！

陌生人

哦？能说说么？或把测试图传上来

Free-Lancer

地形图中多数会有 z 不为 0 的情况。另外

2. 
   
3. (if (setq tf (xdrx_isptoffscr p1 p2))
   
4.                (xdrx_drawing_zoomw p1 p2);;;一定要zoom的，不然会出错的，不光剪不了.
   
5.     )
   

<br /> (if (setq tf (xdrx_isptoffscr p1 p2)) <br />                (xdrx_drawing_zoomw p1 p2);;;一定要zoom的，不然会出错的，不光剪不了. <br />     ) <br />

在 cad2005 中就简单了，看看 zoom 中多了一个选项
命令: z ZOOM
指定窗口的角点，输入比例因子 (nX 或 nXP)，或者
[全部(A)/中心(C)/动态(D)/范围(E)/上一个(P)/比例(S)/窗口(W)/对象(O)] <实时>:

shisj

谢谢了，我先看看。

tpezzh

我喜欢这样的工具，准备试用一下