[分享]：如何实现图纸中的文字输出的文本

shisj

(defun c:txtout (/ fln f a n index el e txt)
        (setq fln (getstring "\n输出文件名:"))
        (setq fln (strcat fln ".txt"))
        (setq f (open fln "w"))
        (setq a (ssget))
        (setq n (sslength a))
        (setq index 0)
        (repeat n
                (setq el (entget ( ssname a index)))
                (setq index ( + index 1))
                (setq e (assoc 0 el))
                (if (= "TEXT" (cdr e))
                        (progn
                                (setq txt (cdr (assoc 1 el)))
                                (write-line txt f)
                                )
                        )
                )
        (close f)
        )
意思实现了文字输出，但是只能按选择的顺序输出，无法做到按选择的文字位置顺序输出，还望高手指点一下。

aidraft

[php]
(defun c:txtout        (/ ss index lst fln f)
  (setq ss (ssget '((0 . "*TEXT"))))
  (setq        index -1
        lst '()
  )
  (while (< (setq index (1+ index)) (sslength ss))
    (setq lst (cons (ssname ss index) lst))
  )
  (setq        lst (vl-sort
              (vl-sort lst
                       '(lambda        (e1 e2)
                          (< (cadr (assoc 10 (entget e1)))
                             (cadr (assoc 10 (entget e2)))
                          )
                        )
              )
              '(lambda (e1 e2)
                 (> (caddr (assoc 10 (entget e1)))
                    (caddr (assoc 10 (entget e2)))
                 )
               )
            )
  )
  (setq fln (getstring "\nFilename:"))
  (setq fln (strcat fln ".txt"))
  (setq f (open fln "w"))
  (foreach en lst
    (write-line (cdr (assoc 1 (entget en))) f)
  )
  (close f)
  (startapp "notepad.exe" (findfile fln))
  (princ)
)
[/php]

shisj

老大看来是ActiveX的高手了，学这个有秘诀吗？
还要一个语句请教一下，我看不懂：(setq ss (ssget ":s" '((0 . "*LINE,ARC,CIRCLE,ELLIPSE"))))

我猜是过滤选择，可是在帮助找不到这个用法，能解释一下吗？

陌生人

帮助中有啊，v lisp部分

shisj

帮助中有ssget的函数解释，但是这样的用法，我没有看到过，因此求教

aidraft

":S" 是只允许单选，帮助文件里SSGET下有解释。至于Wild-Card match, 还提到参考wcmatch下的解释，有的人可能没有注意到，其实wcmatch的所有用法都可以在ssget的过滤中应用。

shisj

谢谢了，我明白了

ll_j

最初由 shisj 发布
[B](defun c:txtout (/ fln f a n index el e txt)
        (setq fln (getstring "\n输出文件名:"))
        ...
意思实现了文字输出，但是只能按选择的顺序输出，无法做到按选择的文字位置顺序输出，还望高手指点一下。[/B]

其实就是文字排序问题，是比较令人头痛的。我这里http://xdcad.net/forum/showthread.php?threadid=27605的wr.lsp就是实现此功能的，不过太长，有兴趣可以参考，另外Ju.lsp中也有类似的排序。

shisj

谢谢了，我参考研究一下，水平比较菜，到时可能还的求助

haibinpro

是个好帖子.

jianying17

去图书馆借点书看看，学习一下