[求助]：求关于填充的LSP！

xxxyzxx

也许我的要求对高手来说不难，但我确实不会LSP，无法自己编，哪位兄弟有心帮我编一下，也可以教我怎么编，我自己去编，谢谢～～～
条件：图中有多条BO线
目标：对每条BO线作填充，使每个填充独立
操作：一次性选中图中所有BO线，一次性填充后，得到的结果不是一个填充整体，而是N个填充个体（注：希望系统生成的填充在当前层，而不是原BO线层－－－或者能添加个选项－－－）

eachy

[php]
;|
HPNAME 初始值：“ANSI31” 设置默认填充图案，其名称最多可包含 34 个字符，其中不能有空格。
HPSCALE 初始值： 1.0000 指定填充图案的比例因子，其值不能为零。
HPANG 初始值： 0 指定填充图案的角度
|;
(defun c:test (/ ss sl e)
  (if (setq ss (ssget '((-4 . "<or")
                        (0 . "circle")
                        (-4 . "<and")
                        (0 . "*Polyline,spline")
                        (-4 . "&=")
                        (70 . 1)
                        (-4 . "and>")
                        (-4 . "or>")
                       )
               )
      )
    (progn
      (setq sl (sslength ss))
      (while (> sl 0)
        (setq e (ssname ss (setq sl (1- sl))))
        (vl-cmdf ".hatch" "" "" "" e "")
      )
    )
  )
  (princ)
)[/php]

xxxyzxx

谢谢老大，经过测试，非常满意，但有一个小小的疑问
我将它改成实体的了(vl-cmdf ".hatch" "solid" e "") 好使，但是多余的""不删(vl-cmdf ".hatch" "solid" "" "" e "") 却出错？
此外，我想是否可以弹出对话框，让用户在对话框中选择呢？那样更方便些，请eachy兄弟指点！

li809

好用，对以后修改有很大帮助

xyp1964

除了eachy  斑竹的方法，如何将圆（CIRCLE）包含进去？
[php]
(defun c:test ()
  (setq        htname (ustr 1 "\n图案名称 : " htname nil)
        n      -1
  )
  (if (setq
        SS (ssget
             '((0 . "CIRCLE,ELLIPSE,REGION,*POLYLINE,SPLINE,") (70 . 1))
           )
      )
    (progn
      (if (= (strcase htname) "SOLID")
        (progn
          (while (setq e (ssname ss (setq n (1+ n))))
            (vl-cmdf "hatch" "solid" e "")
          )
        )
        (progn
          (while (setq e (ssname ss (setq n (1+ n))))
            (vl-cmdf "hatch" htname "" "" e "")
          )
        )
      )
    )
  )
  (princ)
)
(defun ustr (bit msg def spflag / inp nval)
   (if (and def (/= def ""))
       (setq msg (strcat "\n" msg "<" def ">:")
             inp (getstring msg spflag)
             inp (if (= inp "") def inp)
       )
       (progn
         (setq msg (strcat "\n" msg ": "))
         (if (= bit 1)
             (while (= "" (setq inp (getstring msg spflag))))
             (setq inp (getstring msg spflag))
         )))
   (if inp inp def)
)
[/php]

li809

上楼的也不错，谢谢