[测试]：一键快速打印的lsp，请ll_j、它山之石、xyp1964还有斑竹来看看

贱人

画图的时候，把图框都作成块，块名要一样，用这个就可以快速打印，打印时（窗选）自动搜索图框的左下角与右上角为界限,无论一张图上有多少图框，一次搞定


;command部分需要自己修改，选择自己的打印机，打印方式，纸张大小等等

(defun Getpts(BlkName / ss i ent pts)
  (defun GetBox(ent / pt1 pt2)
    (vla-getboundingbox (vlax-ename->vla-object ent) 'pt1 'pt2)
    (mapcar 'vlax-safearray->list (list pt1 pt2))
  )
  (if (= (type BlkName) 'STR)
    (setq ss (ssget "x" (list '(0 . "INSERT") (cons 2 BlkName))))
    (progn
      (setq ss (ssadd))
      (ssadd BlkName ss)
    )
  )
  (setq i 0)
  (if ss
    (repeat (sslength ss)
      (setq ent (ssname ss i))
      (setq pts (append pts (list (GetBox ent))))
      (setq i (1+ i))
    )
  )
  pts
)

(defun c:Wplot( / BlkName plt pts i pt pt1 scale)
  (vl-load-com)
  (setq BlkName (getstring "输入块名<Base>:"))
  (if (= BlkName "") (setq BlkName "base"))
  (setq plt (car (entsel "选择图框<全部>...")))
  (if plt (setq BlkName plt))
  (setq pts (GetPts BlkName))
  (setq i 0)
  (setvar "cmdecho" 0)
  (repeat (length pts)
    (setq pt (nth i pts))
    (setq pt1 (cadr pt))
    (command "_.plot" "y" "Model" "RICOH_A4_Hor.pc3" "A4 (210 x 297 mm)"
      "m" "l" "n" "w" pt1 pt "" "c" "n" "." "y" "a" "n" "y" "y")
    (setq i (1+ i))
  )
  (princ)
)


我试了出错，我是cad2004，图框块名是aa

WPLOT 输入块名<Base>:aa
选择图框<全部>...未知命令“WPLOT”。按 F1 查看帮助。
未知命令“C”。按 F1 查看帮助。
未知命令“N”。按 F1 查看帮助。
未知命令“WPLOT”。按 F1 查看帮助。
未知命令“Y”。按 F1 查看帮助。
未知命令“A”。按 F1 查看帮助。
未知命令“Y”。按 F1 查看帮助。
未知命令“Y”。按 F1 查看帮助。
未知命令“Y”。按 F1 查看帮助。

还有个问题
我按照lsp在cad用-plot模拟了一遍，可是：
输入打印偏移 (x,y) 或 [居中打印(C)] <0.00,0.00>: c这一步做不下去，不知道为何？

ll_j

我觉得现在的打印已经比较方便了，关键的是养成好的绘图习惯。
就楼上程序出错的问题，出现“未知命令”，一般是在什么地方多了个回车“""”，根据后面的内容多数可以看出回车的位置，本例可以将“"c" "n"”前的一个回车去掉试试。

ljpnb

输入打印偏移 (x,y) 或 [居中打印(C)] <0.00,0.00>: c这一步做不下去，原因很简单，因为如果用打印对话框按了[居中打印(C)] ，那它的X、Y偏移量会自动求得，但如果你是直接用程序输入"c"，它不会自动计算偏移量，当然会出错，所以这一步只能输入一个X、Y的偏移值。

它山之石

以下为修正过的程序（COMMAND部分略过）：
另外有以下建议：
1、当程序出错时自己最好学着调试。
2、程序还可再精简些。
3、应增加图中无输入的图块名时提示并退出的功能。因为没有时会出错。
4、输入图块名毕竟麻烦，程序最好是点取得到图块名后再提示是全部还是再次选择。

[php]
(defun Getpts (BlkName / ss i ent)
  (defun GetBox        (ent / pt1 pt2)
    (vla-getboundingbox (vlax-ename->vla-object ent) 'pt1 'pt2)
    (mapcar 'vlax-safearray->list (list pt1 pt2))
  ) ;_ 结束defun
  (if (= (type BlkName) 'STR)
    (setq ss (ssget "x" (list '(0 . "INSERT") (cons 2 BlkName))))
    (progn
      (setq ss (ssadd))
      (ssadd BlkName ss)
    ) ;_ 结束progn
  ) ;_ 结束if
  (setq i 0)
  (if ss
    (repeat (sslength ss)
      (setq ent (ssname ss i))
      (setq pts (append pts (list (GetBox ent))))
      (setq i (1+ i))
    ) ;_ 结束repeat
  ) ;_ 结束if
;;;;;;  pts
) ;_ 结束defun

(defun c:Wplot (/ BlkName plt pts ptss i pt pt1 scale)
  (vl-load-com)
  (setq BlkName (getstring "输入块名:"))
  (if (= BlkName "")
    (setq BlkName "base")
  ) ;_ 结束if
  (setq plt (car (entsel "选择图框<全部>...")))
  (if plt
    (setq BlkName plt)
  ) ;_ 结束if
  (setq ptss (GetPts BlkName))
  (setq i 0)
  (setvar "cmdecho" 0)
  (repeat ptss
;;;;;;    (length ptss)
    (setq pt (nth i pts))
    (setq pt1 (cadr pt))
;;;    (command "_.plot"        "y"           "Model"    "RICOH_A4_Hor.pc3"
;;;             "A4 (210 x 297 mm)"   "m"              "l"         "n"
;;;             "w"        pt1           pt              ""         "c"
;;;             "n"        "."           "y"              "a"         "n"
;;;             "y"        "y"
;;;            ) ;_ 结束command
    (alert "Are You Ready?")
    (setq i (1+ i))
  ) ;_ 结束repeat
  (princ)
) ;_ 结束defun

[/php]

贱人

最初由 ljpnb 发布
[B]输入打印偏移 (x,y) 或 [居中打印(C)] <0.00,0.00>: c这一步做不下去，原因很简单，因为如果用打印对话框按了[居中打印(C)] ，那它的X、Y偏移量会自动求得，但如果你是直接用程序输入"c"，它不会自动计算偏移量，当?.. [/B]

晕，看2天了，不明白，直说吧，在什么情况下这个“c”参数是可以输入的？我试了好多方法不行啊



它山之石，command部分我已经自己修改了，我的机器 “输入打印偏移 (x,y) 或 [居中打印(C)] <0.00,0.00>: c” 这一步实在不行，就直接回车了，选了打印到文件，可是还不行，一选图框就出错了，还说：未知命令“WPLOT”。按 F1 查看帮助。，怎么选完图框又去调主函数
    (command "_.plot"    "y"       "Model"    "Epson"
         "A4"   "m"          "p"     "n"
         "w"    pt1       pt          ""     ""
         "y"    "acad.ctb"       "y"          "a"     "y"
         "y"    "y"
        ) ;_ 结束command

它山之石

打印偏移值，必须输入全称“居中打印(c)”或“圆心”或“0，0”等，如只输入“C”会出错。
COMMAND部分定义如下即可：

[php]
(defun A0 ()
  (command
    "-plot"                                ;命令行执行打印
    "y"                                        ;是否需要详细打印配置？[是(Y)/否(N)] <否>: y
    "model"                                ;输入布局名或 [?] <模型>:
;;;下面为用户已定义的打印机配置名称
    "tds300_hy.pc3"                        ;输入输出设备的名称或 [?] <\\printer3\HP LaserJet 5000 Series PCL 6>:
;;;以下为图纸尺寸，必须与配置文件中相同，如只输入“A0”会出错
    "A0 (860.00 x 1250.00 毫米)"        ;输入图纸尺寸或 [?] <A3>:
    "M"                                        ;输入图纸单位 [英寸(I)/毫米(M] <毫米>:
    "p"                        ;输入图形方向 [纵向(P)/横向(L)] <横向>:
      "N"                                        ;是否反向打印？[是(Y)/否(N)] <否>:
    "w"                                        ;输入打印区域 [显示(D)/范围(E)/图形界限(L)/视图(V)/窗口(W)] <窗口>:
    pt1                                        ;输入窗口的左下角 <-1375541.640277,50438.400149>:
    pt2                                        ;输入窗口的右上角 <-1184391.640277,139538.400149>:
    "fit"                                ;输入打印比例 (打印的 毫米=图形单位) 或 [布满(F)] <Fit>:
;;;以下为打印偏移值，必须输入全称“居中打印(c)”或“圆心”或“0，0”等，如只输入“C”会出错。
    "居中打印(c)"                        ;输入打印偏移 (x,y) 或 [居中打印(C)] <圆心>:
    "y"                                        ;是否按样式打印？[是(Y)/否(N)] <是>:
;;;以下为用户已定义的打印样式表
    "tds300_hy.ctb"                        ;输入打印样式表名称或 [?] (输入 . 表示无) <HP5000_HY.CTB>:
    "y"                                        ;是否打印线宽？[是(Y)/否(N)] <是>:
    "As displayed"                        ;输入着色打印设置 [按显示(A)/线框(W)/消隐(H)/渲染(R)] <按显示>:
    "y"                                        ;是否打印到文件 [是(Y)/否(N)] <N>:
;;;以下当打印到文件时确定文件名，调试程序用。
    ""
    "y"                                        ;是否保存对页面设置的更改 [是(Y)/否(N)]? <N>
    "y"                                        ;是否继续打印？[是(Y)/否(N)] <Y>: Y
  ) ;_ 结束command
) ;_ 结束defun

[/php]

啵浪鼓

楼主的块我想多半是在创建时未将块的坐标点设置到归0状态

xiaochongcn

非常有创意。
好好完善，真得不错。
佩服得五体投地。

madeinchina

充满期待

贱人

还是选图框这步，试不出来，有成功的没？

选择图框<全部>...
未知命令“wplot”。按 F1 查看帮助。

它山之石

最初由 贱人 发布
[B]还是选图框这步，试不出来，有成功的没？

选择图框<全部>...
未知命令“wplot”。按 F1 查看帮助。 [/B]

晕，怎么还不行，俺用着可以的。
不知你的问题是出现在COMMAND部分还是选图框部分。
这两部分俺不都给你说明过问题出在哪了吗？
你用俺改过的程序了没有？是否出现ARE　YOU　READY的提示了？

贱人

最初由 它山之石 发布
[B]

晕，怎么还不行，俺用着可以的。
不知你的问题是出现在... [/B]

你的可以用？那太好了，把你的lsp传上来，让我试试
我的选图框时出现：(are you ready 没出来)

选择图框<全部>...
; 错误: 参数类型错误: fixnump: (((940.579 192.533 0.0) (2007.83 746.659 0.0)))
命令:

li809

好,完善后请发给我
baoshun01@163.com

它山之石

参考了XYP1964的部分函数。

运行后如下：

*** 模型空间批量打印软件V050222 ***
        [晓东论坛作品]
选择图框<回车点选打印范围>
图形文件中共有名为 [ TKA2 ] 的图框 1 个
请选择要打印的图纸张数：全部(Q)/选择(X) <单张(D)>

*** 模型空间批量打印软件V050222 ***
        [晓东论坛作品]


[php]
;|英文版PLOT参数
Command: -plot
Detailed plot configuration? [Yes/No] <No>: y

Enter a layout name or [?] <Model>:
Enter an output device name or [?] <\\欧阳益敏\EPSON Stylus Photo 1270>:
Enter paper size or [?] <A3 297 x 420 mm>:
Enter paper units [Inches/Millimeters] <Inches>:
Enter drawing orientation [Portrait/Landscape] <Landscape>:
Plot upside down? [Yes/No] <No>:
Enter plot area [Display/Extents/Limits/View/Window] <Window>:
Enter lower left corner of window <700477.336097,-57730.988273>:
Enter upper right corner of window <862153.882007,47664.339827>:
Enter plot scale (Plotted Inches=Drawing Units) or [Fit] <Fit>:
Enter plot offset (x,y) or [Center] <0.00,0.00>: c
Plot with plot styles? [Yes/No] <Yes>:
Enter plot style table name or [?] (enter . for none) <acad.ctb>:
Plot with lineweights? [Yes/No] <Yes>:
Enter shade plot setting [As displayed/Wireframe/Hidden/Rendered] <As
displayed>:
Write the plot to a file [Yes/No] <N>: y
Save changes to page setup [Yes/No]? <N>
Proceed with plot [Yes/No] <Y>: n
|;

(vl-load-com)

;;;以下定义打印A4纸张
(defun A4 ()
  (command
    "-plot"                                ;命令行执行打印
    "y"                                        ;是否需要详细打印配置？[是(Y)/否(N)] <否>: y
    "model"                                ;输入布局名或 [?] <模型>:
;;;以下为用户已定义的打印机配置名称
    "\\\\printer3\\HP LaserJet 5000 Series PCL 6"
                                        ;输入输出设备的名称或 [?] <\\printer3\HP LaserJet 5000 Series PCL 6>:
    "A4"                                ;输入图纸尺寸或 [?] <A3>:
    "M"                                        ;输入图纸单位 [英寸(I)/毫米(M] <毫米>:
    (if        (= ro "Y")                        ;输入图形方向 [纵向(P)/横向(L)] <横向>:
      "p"
      "L"
    ) ;_ 结束if
    "N"                                        ;是否反向打印？[是(Y)/否(N)] <否>:
    "w"                                        ;输入打印区域 [显示(D)/范围(E)/图形界限(L)/视图(V)/窗口(W)] <窗口>:
    pt1                                        ;输入窗口的左下角 <-1375541.640277,50438.400149>:
    pt2                                        ;输入窗口的右上角 <-1184391.640277,139538.400149>:
    "fit"                                ;输入打印比例 (打印的 毫米=图形单位) 或 [布满(F)] <Fit>:
    "居中打印(c)"                        ;输入打印偏移 (x,y) 或 [居中打印(C)] <圆心>:
    "y"                                        ;是否按样式打印？[是(Y)/否(N)] <是>:
;;;以下为用户已定义的打印样式表
    "hp5000_hy.ctb"                        ;输入打印样式表名称或 [?] (输入 . 表示无) <HP5000_HY.CTB>:
    "y"                                        ;是否打印线宽？[是(Y)/否(N)] <是>:
    "As displayed"                        ;输入着色打印设置 [按显示(A)/线框(W)/消隐(H)/渲染(R)] <按显示>:
    "n"                                        ;是否打印到文件 [是(Y)/否(N)] <N>:
;;;以下当打印到文件时确定文件名，调试程序用。
;;;    ""
    "y"                                        ;是否保存对页面设置的更改 [是(Y)/否(N)]? <N>
    "n"                                        ;是否继续打印？[是(Y)/否(N)] <Y>: Y
  ) ;_ 结束command
) ;_ 结束defun

(defun pt-zw ()
  (setvar "ORTHOMODE" 0)
  (if (setq pt1 (getpoint "\n请点取打印范围的左下角 <退出> : "))
    (if        (setq pt2 (getcorner pt1 "\n请点取打印范围的右上角 <退出> : "))
      (progn
        (setq ptss 1)
;;;        (command "zoom" "w" pt1 pt2)
      ) ;_ 结束progn
      (setq ptss nil)
    ) ;_ 结束if
    (setq ptss nil)
  ) ;_ 结束setq
  (princ "\n")
) ;_ 结束defun


(defun GetBox (ent / pt1 pt2)
  (vla-getboundingbox (vlax-ename->vla-object ent) 'pt1 'pt2)
  (mapcar 'vlax-safearray->list (list pt1 pt2))
) ;_ 结束defun

(defun Getpts (BlkName / ss i ent xztzhzhsh Blk_Name)
  (setq Blk_Name (cdr (assoc 2 (entget BlkName))))
  (setq        tzhzsh (sslength
                 (ssget "x" (list '(0 . "INSERT") (cons 2 Blk_Name)))
               ) ;_ 结束sslength
  ) ;_ 结束setq
  (princ (strcat "\n图形文件中共有名为 [ "
                 　Blk_Name
                 " ] 的图框 "
                 (rtos tzhzsh 2 0)
                 " 个"
         ) ;_ 结束strcat
  ) ;_ 结束princ
  (initget "D X Q")
  (setq
    xztzhzhsh (getkword
                "\n请选择要打印的图纸张数：全部(Q)/选择(X) <单张(D)>"
              ) ;_ 结束getkword
  ) ;_ 结束setq
  (cond
    ((or (= xztzhzhsh "q") (= xztzhzhsh "Q"))
     (setq ss (ssget "x" (list '(0 . "INSERT") (cons 2 Blk_Name))))
    )
    ((or (= xztzhzhsh "x") (= xztzhzhsh "X"))
     (princ
       (strcat
         "\n请选择其它要打印的图框！
          \n要求与点选图框块名相同！"
       ) ;_ 结束strcat
     ) ;_ 结束princ
     (setq ss (ssget (list '(0 . "INSERT") (cons 2 Blk_Name))))
     (setq ss (ssadd BlkName ss))
    )
    ((= xztzhzhsh nil)
     (setq ss (ssadd))
     (setq ss (ssadd BlkName ss))
    )
  ) ;_ 结束cond

  (setq i 0)
  (if ss
    (repeat (sslength ss)
;;;    (while
      (setq ent (ssname ss i))
      (setq pts (append pts (list (GetBox ent))))
      (setq i (1+ i))
    ) ;_ 结束repeat
  ) ;_ 结束if
) ;_ 结束defun

(defun c:Wplot (/ ort BlkName pts ptss i pt pt1 pt2 scale ro)
  (princ (strcat "\n*** 模型空间批量打印软件V050222 ***"))
  (princ (strcat "\n        [晓东论坛作品]"))
  (princ)
  (setq ort (getvar "ORTHOMODE"))
  (setq        BlkName        (car (xdrx_entsel
                       "\n选择图框<回车点选打印范围>"
                       '((0 . "INSERT") (8 . "TK"))
                     ) ;_ 结束xdrx_entsel
                ) ;_ 结束car
  ) ;_ 结束setq

;;;(setq plt (car (entsel "\n选择图框<回车点选打印范围>\n")))
  (if BlkName
    (setq ptss (GetPts BlkName))
    (pt-zw)
  ) ;_ 结束if

  (setq i 0)
  (setvar "cmdecho" 0)
  (if ptss
    (repeat ptss
      (if BlkName
        (progn
          (setq pt (nth i pts))
          (setq        pt1 (car pt)
                pt2 (cadr pt)
          ) ;_ 结束setq
        ) ;_ 结束progn
      ) ;_ 结束if
      (if (< (abs (- (car pt1) (car pt2)))
             (abs (- (cadr pt1) (cadr pt2)))
          ) ;_ 结束<
        (setq ro "Y")
        (setq ro "N")
      ) ;_ 结束if
      (if (= ptss 1)
        (command "zoom" "w" pt1 pt2)
      ) ;_ 结束if
      (alert "Are You Ready?")
;;;以下为打印程序
;;;    (A4)
;;;以下为预览
;;;    (command "preview")
      (if (= ptss 1)
        (command "zoom" "p")
      ) ;_ 结束if
      (setq i (1+ i))
    ) ;_ 结束repeat
  ) ;_ 结束if
  (setvar "ORTHOMODE" ort)

  (princ (strcat "\n*** 模型空间批量打印软件V050222 ***"))
  (princ (strcat "\n        [晓东论坛作品]"))
  (princ)
) ;_ 结束defun


;;;下一个版本将增加对话框。
;;;下一个版本将增加预览选项。

[/php]

贱人

开始怀疑我的机器不正常
命令: wplot
*** 模型空间批量打印软件V050222 ***
        [晓东论坛作品]; 错误: no function definition: XDRX_ENTSEL