[原创]：标注打断

haijiangl · 发表于 2003-2-25 20:48:19

马上注册，结交更多好友，享用更多功能，让你轻松玩转社区。

您需要登录才可以下载或查看，没有账号？立即注册

×

共有两个命令
bb1：点取多个点，打断标注，忽略不和标注线垂直相交的点。
bb2：选取多个直线，过直线起点，打断标注。

[FONT=courier new]
;按过滤列表选择物体
;fi_list格式: (0 "TYPE" 8 "LAYER" ...)
;图元类别请大写
(defun lhj_entsel (pro fi_list / n name res)
(if (setq name (car (entsel pro)))
(progn
(setq res 1
n (length fi_list)
)
(while (> n 0)
(setq n (- n 2))
(if (= (lhj_dxf name (nth n fi_list))
(nth (1+ n) fi_list)
)
(setq res (* res 1))
(setq res (* res 0))
)
)
(cond ((= res 1) (setq res name))
((= res 0) nil)
)
)
(setq res nil)
)
)
;获取实体dxf组码内容
; (lhj_dxf 实体名 dxf码编号)
;例：(lhj_dxf textname 10)，获取文字左下点标
(defun lhj_dxf (ename code / elist res)
(setq elist (entget ename))
(setq res (cdr (assoc code elist)))
)
;==========================================
;初始化，读取系统变量。结束时，恢复系统变量
; osmode 0
; cmdecho 1
; clayer 2
; textstyle 3
; cecolor 4
; dimstyle 5
; plinewid 6
(defun lhj_start ()
(setq lhj_s_lst
(list
(getvar "osmode")
(getvar "cmdecho")
(getvar "clayer")
(getvar "textstyle")
(getvar "cecolor")
(getvar "dimstyle")
(getvar "plinewid")
)
)
(setq old_error *error*)
(setvar "osmode" 0)
(setvar "cmdecho" 0)
(command "undo" "be")
(princ)
)
(defun lhj_end ()
(setvar "osmode" (nth 0 lhj_s_lst))
(setvar "clayer" (nth 2 lhj_s_lst))
(setvar "textstyle" (nth 3 lhj_s_lst))
(setvar "cecolor" (nth 4 lhj_s_lst))
(command "dimstyle" "r" (nth 5 lhj_s_lst))
(setvar "plinewid" (nth 6 lhj_s_lst))
(setq *error* old_error)
(command "undo" "e")
(setvar "cmdecho" (nth 1 lhj_s_lst))
(princ)
)
(setq lhj_pi2 (/ pi 2))
;求点到直线足
(defun p_to_l (pt0 pt1 pt2 mode / ang)
(setq ang (angle pt1 pt2))
(inters pt0
(polar pt0 (+ ang lhj_pi2) 1000)
pt1
pt2
mode
)
)
;去除表中指定元素，返回表
(defun a_ext_li (a alist / res temp)
(setq temp (member a alist))
(if (/= temp nil)
(setq res (append
(reverse (cdr (member a (reverse alist))))
(cdr temp)
)
)
(setq res alist)
)
)
;求一系列点中到基准点的距离最小点
(defun p_p0_dismin (p0 ptlist / ll pt1 pt2)
(setq ll (length ptlist))
(if (> ll 1)
(progn
(setq pt1 (nth 0 ptlist))
(while (> ll 1)
(setq ll (1- ll)
pt2 (nth ll ptlist)
)
(if (> (distance pt1 p0) (distance pt2 p0))
(setq pt1 pt2)
)
)
)
(setq pt1 (car ptlist))
)
(setq res pt1)
)
;将一系列点按到基准点的距离升序排列
(defun p_p0_disup (p0 ptlist / ll newlist pt1 res)
(setq newlist '()
ll (length ptlist)
)
(while (> ll 0)
(setq pt1 (p_p0_dismin p0 ptlist)
newlist (cons pt1 newlist)
ptlist (a_ext_li pt1 ptlist)
ll (1- ll)
)
(princ pt1)
)
(setq res (reverse newlist))
)
;求标注的另一控点
(defun dim_pt9 (dname / pt13 pt14 pt10 ang)
(setq pt13 (lhj_dxf dname 13)
pt14 (lhj_dxf dname 14)
pt10 (lhj_dxf dname 10)
ang (angle pt14 pt10)
pt9 (inters
pt13
(polar pt13 ang 1000)
pt10
(polar pt10 (+ ang lhj_pi2) 1000)
nil
)
)
)
;将标注打断为两部分，并返回新建标注的实体名
(defun dim_break (pt dname / pt13 pt14 pt10 ang dlist dlist1 dlist2
pt13_1)
(setq dlist (entget dname)
pt13 (lhj_dxf dname 13)
pt14 (lhj_dxf dname 14)
pt10 (lhj_dxf dname 10)
ang (angle pt14 pt10)
pt9 (inters
pt13
(polar pt13 ang 1000)
pt10
(polar pt10 (+ ang lhj_pi2) 1000)
nil
)
pt13_1 (polar pt14 (angle pt10 pt9) (distance pt10 pt))
)
(command "copy" dname "" "0,0" "@")
(setq dlist1 (subst (cons 14 pt13_1) (assoc 14 dlist) dlist)
dlist1 (subst (cons 10 pt) (assoc 10 dlist1) dlist1)
)
(setq dlist2 (entget (entlast))
dlist2 (subst (cons 13 pt13_1) (assoc 13 dlist2) dlist2)
)
(entmod dlist1)
(entmod dlist2)
(entlast)
)
;多点打断标注
(defun c:bb1 (/ dname pt9 ptlist loop ll pt10 pt ptlist_n dis)
(lhj_start)
(defun *error* (msg)
(princ "\n")
(princ "\n:::lhj_tools:::")
(princ msg)
(princ ",程序退出!")
(redraw dname 4)
(lhj_end)
)
(setq dname (lhj_entsel
"\n:::lhj_tools:::请选择要打断的标注:"
'(0 "DIMENSION")
)
loop T
ptlist '()
ptlist_n '()
)
(if dname
(progn
(redraw dname 3)
(setvar "osmode" 187)
(while loop
(if (setq pt (getpoint "\n:::lhj_tools:::请点取打断点:"))
(setq ptlist (cons pt ptlist))
(setq loop nil)
)
) ;end of while
(redraw dname 4)
(if ptlist
(progn
(setq pt9 (dim_pt9 dname)
pt10 (lhj_dxf dname 10)
ll (length ptlist)
dis (distance pt9 pt10)
)
(while (> ll 0)
(setq ll (1- ll)
pt (nth ll ptlist)
pt (p_to_l pt pt9 pt10 nil)
)
(if (<= (fix (+ (distance pt pt9) (distance pt pt10))) dis)
(setq ptlist_n (cons pt ptlist_n))
)
)
(setq ptlist_n (reverse (p_p0_disup pt9 ptlist_n)))
) ;end of progn
(princ "\n:::lhj_tools:::没有选择打断点!")
) ;end of if
(setq ll (length ptlist_n))
(while (and (> ll 0) dname)
(setq ll (1- ll)
pt (nth ll ptlist_n)
dname (dim_break pt dname)
)
)
(princ "\n:::lhj_tools:::打断成功!")
) ;end of progn
(princ "\n:::lhj_tools:::没有选择到标注!")
) ;end of if
(lhj_end)
(princ)
)
;多线打断标注
(defun c:bb2 (/ dname pt9 ptlist ll pt10 pt ptlist_n ss ssl lname dis)
(lhj_start)
(defun *error* (msg)
(princ "\n")
(princ "\n:::lhj_tools:::")
(princ msg)
(princ ",程序退出!")
(redraw dname 4)
(lhj_end)
)
(setq dname (lhj_entsel
"\n:::lhj_tools:::请选择要打断的标注:"
'(0 "DIMENSION")
)
ptlist '()
ptlist_n '()
)
(if dname
(progn
(redraw dname 3)
(princ "\n:::lhj_tools:::请选择要打断标注的直线:")
(if (setq ss (ssget '((0 . "line"))))
(progn
(setq ssl (sslength ss))
(while (> ssl 0)
(setq lname (ssname ss (setq ssl (1- ssl)))
pt (lhj_dxf lname 10)
ptlist (cons pt ptlist)
)
) ;end of while
)
)
(redraw dname 4)
(if ptlist
(progn
(setq pt9 (dim_pt9 dname)
pt10 (lhj_dxf dname 10)
ll (length ptlist)
dis (distance pt9 pt10)
)
(while (> ll 0)
(setq ll (1- ll)
pt (nth ll ptlist)
pt (p_to_l pt pt9 pt10 nil)
)
(if (<= (fix (+ (distance pt pt9) (distance pt pt10))) dis)
(setq ptlist_n (cons pt ptlist_n))
)
)
(setq ptlist_n (reverse (p_p0_disup pt9 ptlist_n)))
) ;end of progn
(princ "\n:::lhj_tools:::没有选择到直线!")
) ;end of if
(setq ll (length ptlist_n))
(while (and (> ll 0) dname)
(setq ll (1- ll)
pt (nth ll ptlist_n)
dname (dim_break pt dname)
)
)
(princ "\n:::lhj_tools:::打断成功!")
) ;end of progn
(princ "\n:::lhj_tools:::没有选择到标注!")
) ;end of if
(lhj_end)
(princ)
) [/FONT]

[FONT=courier new] 
 ;按过滤列表选择物体 
 ;fi_list格式: (0 "TYPE" 8 "LAYER" ...) 
 ;图元类别请大写 
(defun lhj_entsel (pro fi_list / n name res) 
 
  (if (setq name (car (entsel pro))) 
    (progn 
      (setq res        1 
            n        (length fi_list) 
      ) 
 
      (while (> n 0) 
        (setq n (- n 2)) 
        (if (= (lhj_dxf name (nth n fi_list)) 
               (nth (1+ n) fi_list) 
            ) 
          (setq res (* res 1)) 
          (setq res (* res 0)) 
        ) 
      ) 
      (cond ((= res 1) (setq res name)) 
            ((= res 0) nil) 
      ) 
    ) 
    (setq res nil) 
  ) 
) 
 
 
 
 ;获取实体dxf组码内容 
 ; (lhj_dxf 实体名 dxf码编号) 
 ;例：(lhj_dxf textname 10)，获取文字左下点标 
 
(defun lhj_dxf (ename code / elist res) 
  (setq elist (entget ename)) 
  (setq res (cdr (assoc code elist))) 
) 
 
 ;========================================== 
 ;初始化，读取系统变量。结束时，恢复系统变量 
 ;  osmode             0 
 ;  cmdecho         1 
 ;  clayer             2 
 ;  textstyle          3 
 ;  cecolor        4 
 ;  dimstyle        5 
 ;  plinewid    6 
 
 
(defun lhj_start () 
  (setq        lhj_s_lst 
         (list 
           (getvar "osmode") 
           (getvar "cmdecho") 
           (getvar "clayer") 
           (getvar "textstyle") 
           (getvar "cecolor") 
           (getvar "dimstyle") 
           (getvar "plinewid") 
         ) 
  ) 
  (setq old_error *error*) 
  (setvar "osmode" 0) 
  (setvar "cmdecho" 0) 
  (command "undo" "be") 
  (princ) 
) 
 
 
(defun lhj_end () 
  (setvar "osmode" (nth 0 lhj_s_lst)) 
  (setvar "clayer" (nth 2 lhj_s_lst)) 
  (setvar "textstyle" (nth 3 lhj_s_lst)) 
  (setvar "cecolor" (nth 4 lhj_s_lst)) 
  (command "dimstyle" "r" (nth 5 lhj_s_lst)) 
  (setvar "plinewid" (nth 6 lhj_s_lst)) 
  (setq *error* old_error) 
  (command "undo" "e") 
  (setvar "cmdecho" (nth 1 lhj_s_lst)) 
  (princ) 
) 
 
(setq lhj_pi2 (/ pi 2)) 
 
 ;求点到直线足 
 
(defun p_to_l (pt0 pt1 pt2 mode / ang) 
  (setq ang (angle pt1 pt2)) 
  (inters pt0 
          (polar pt0 (+ ang lhj_pi2) 1000) 
          pt1 
          pt2 
          mode 
  ) 
) 
 
 ;去除表中指定元素，返回表 
(defun a_ext_li        (a alist / res temp) 
  (setq temp (member a alist)) 
  (if (/= temp nil) 
    (setq res (append 
                (reverse (cdr (member a (reverse alist)))) 
                (cdr temp) 
              ) 
    ) 
    (setq res alist) 
  ) 
) 
 
 
 ;求一系列点中到基准点的距离最小点 
 
(defun p_p0_dismin (p0 ptlist / ll pt1 pt2) 
  (setq ll (length ptlist)) 
  (if (> ll 1) 
    (progn 
      (setq pt1 (nth 0 ptlist)) 
      (while (> ll 1) 
        (setq ll  (1- ll) 
              pt2 (nth ll ptlist) 
        ) 
        (if (> (distance pt1 p0) (distance pt2 p0)) 
          (setq pt1 pt2) 
        ) 
      ) 
    ) 
    (setq pt1 (car ptlist)) 
  ) 
  (setq res pt1) 
) 
 
 
 ;将一系列点按到基准点的距离升序排列 
 
(defun p_p0_disup (p0 ptlist / ll newlist pt1 res) 
  (setq        newlist        '() 
        ll        (length ptlist) 
  ) 
  (while (> ll 0) 
    (setq pt1          (p_p0_dismin p0 ptlist) 
          newlist (cons pt1 newlist) 
          ptlist  (a_ext_li pt1 ptlist) 
          ll          (1- ll) 
    ) 
    (princ pt1) 
  ) 
  (setq res (reverse newlist)) 
) 
 
 
 ;求标注的另一控点 
 
(defun dim_pt9 (dname / pt13 pt14 pt10 ang) 
  (setq        pt13 (lhj_dxf dname 13) 
        pt14 (lhj_dxf dname 14) 
        pt10 (lhj_dxf dname 10) 
        ang  (angle pt14 pt10) 
        pt9  (inters 
               pt13 
               (polar pt13 ang 1000) 
               pt10 
               (polar pt10 (+ ang lhj_pi2) 1000) 
               nil 
             ) 
  ) 
) 
 
 
 ;将标注打断为两部分，并返回新建标注的实体名 
(defun dim_break (pt dname / pt13 pt14 pt10 ang        dlist dlist1 dlist2 
                  pt13_1) 
 
  (setq        dlist  (entget dname) 
        pt13   (lhj_dxf dname 13) 
        pt14   (lhj_dxf dname 14) 
        pt10   (lhj_dxf dname 10) 
        ang    (angle pt14 pt10) 
        pt9    (inters 
                 pt13 
                 (polar pt13 ang 1000) 
                 pt10 
                 (polar pt10 (+ ang lhj_pi2) 1000) 
                 nil 
               ) 
        pt13_1 (polar pt14 (angle pt10 pt9) (distance pt10 pt)) 
  ) 
  (command "copy" dname "" "0,0" "@") 
  (setq        dlist1 (subst (cons 14 pt13_1) (assoc 14 dlist) dlist) 
        dlist1 (subst (cons 10 pt) (assoc 10 dlist1) dlist1) 
  ) 
  (setq        dlist2 (entget (entlast)) 
        dlist2 (subst (cons 13 pt13_1) (assoc 13 dlist2) dlist2) 
  ) 
  (entmod dlist1) 
  (entmod dlist2) 
 
  (entlast) 
) 
 
 
 ;多点打断标注 
(defun c:bb1 (/ dname pt9 ptlist loop ll pt10 pt ptlist_n dis) 
 
  (lhj_start) 
 
  (defun *error* (msg) 
    (princ "\n") 
    (princ "\n:::lhj_tools:::") 
    (princ msg) 
    (princ ",程序退出!") 
    (redraw dname 4) 
    (lhj_end) 
  ) 
 
  (setq        dname         (lhj_entsel 
                   "\n:::lhj_tools:::请选择要打断的标注:" 
                   '(0 "DIMENSION") 
                 ) 
        loop         T 
        ptlist         '() 
        ptlist_n '() 
  ) 
  (if dname 
    (progn 
      (redraw dname 3) 
      (setvar "osmode" 187) 
      (while loop 
        (if (setq pt (getpoint "\n:::lhj_tools:::请点取打断点:")) 
          (setq ptlist (cons pt ptlist)) 
          (setq loop nil) 
        ) 
      ) ;end of while 
      (redraw dname 4) 
      (if ptlist 
        (progn 
          (setq        pt9  (dim_pt9 dname) 
                pt10 (lhj_dxf dname 10) 
                ll   (length ptlist) 
                dis  (distance pt9 pt10) 
          ) 
          (while (> ll 0) 
            (setq ll (1- ll) 
                  pt (nth ll ptlist) 
                  pt (p_to_l pt pt9 pt10 nil) 
            ) 
            (if        (<= (fix (+ (distance pt pt9) (distance pt pt10))) dis) 
              (setq ptlist_n (cons pt ptlist_n)) 
            ) 
          ) 
          (setq ptlist_n (reverse (p_p0_disup pt9 ptlist_n))) 
        ) ;end of progn 
        (princ "\n:::lhj_tools:::没有选择打断点!") 
      ) ;end of if 
      (setq ll (length ptlist_n)) 
      (while (and (> ll 0) dname) 
        (setq ll    (1- ll) 
              pt    (nth ll ptlist_n) 
              dname (dim_break pt dname) 
        ) 
      ) 
      (princ "\n:::lhj_tools:::打断成功!") 
    ) ;end of progn 
    (princ "\n:::lhj_tools:::没有选择到标注!") 
  ) ;end of if 
  (lhj_end) 
  (princ) 
) 
 
 
 
 ;多线打断标注 
(defun c:bb2 (/ dname pt9 ptlist ll pt10 pt ptlist_n ss ssl lname dis) 
 
  (lhj_start) 
 
  (defun *error* (msg) 
    (princ "\n") 
    (princ "\n:::lhj_tools:::") 
    (princ msg) 
    (princ ",程序退出!") 
    (redraw dname 4) 
    (lhj_end) 
  ) 
 
  (setq        dname         (lhj_entsel 
                   "\n:::lhj_tools:::请选择要打断的标注:" 
                   '(0 "DIMENSION") 
                 ) 
        ptlist         '() 
        ptlist_n '() 
  ) 
  (if dname 
    (progn 
      (redraw dname 3) 
      (princ "\n:::lhj_tools:::请选择要打断标注的直线:") 
      (if (setq ss (ssget '((0 . "line")))) 
        (progn 
          (setq ssl (sslength ss)) 
          (while (> ssl 0) 
            (setq lname         (ssname ss (setq ssl (1- ssl))) 
                  pt         (lhj_dxf lname 10) 
                  ptlist (cons pt ptlist) 
            ) 
          ) ;end of while 
        ) 
      ) 
      (redraw dname 4) 
      (if ptlist 
        (progn 
          (setq        pt9  (dim_pt9 dname) 
                pt10 (lhj_dxf dname 10) 
                ll   (length ptlist) 
                dis  (distance pt9 pt10) 
          ) 
          (while (> ll 0) 
            (setq ll (1- ll) 
                  pt (nth ll ptlist) 
                  pt (p_to_l pt pt9 pt10 nil) 
            ) 
            (if        (<= (fix (+ (distance pt pt9) (distance pt pt10))) dis) 
              (setq ptlist_n (cons pt ptlist_n)) 
            ) 
          ) 
          (setq ptlist_n (reverse (p_p0_disup pt9 ptlist_n))) 
        ) ;end of progn 
        (princ "\n:::lhj_tools:::没有选择到直线!") 
      ) ;end of if 
      (setq ll (length ptlist_n)) 
      (while (and (> ll 0) dname) 
        (setq ll    (1- ll) 
              pt    (nth ll ptlist_n) 
              dname (dim_break pt dname) 
        ) 
      ) 
      (princ "\n:::lhj_tools:::打断成功!") 
    ) ;end of progn 
    (princ "\n:::lhj_tools:::没有选择到标注!") 
  ) ;end of if 
  (lhj_end) 
  (princ) 
)  [/FONT]

aeo · 发表于 2003-2-25 23:11:22

改了改 ;
求一系列点中到基准点的距离最小点
(defun p_p0_dismin (p0 ptlist / p1 p2)
(setq p1(car ptlist)ptlist(cdr ptlist))
(foreach p2 ptlist(if (<(distance p2 p0)(distance p1 p0))(setq p1 p2)))
p1)

;将一系列点按到基准点的距离升序排列
(defun p_p0_disup (p0 ptlist )
(vl-sort ptlist '(lambda(x y)(<(distance p0 x)(distance p0 y))))
)
求一系列点中到基准点的距离最小点
(defun p_p0_dismin (p0 ptlist )
(car (p_p0_disup p0 ptlist))
)

maxbug · 发表于 2003-2-26 21:39:57

正准备编一个,找到现成的了,谢谢提供.

账号		自动登录	找回密码
密码			立即注册

[原创]：标注打断

马上注册，结交更多好友，享用更多功能，让你轻松玩转社区。

相关帖子

浏览过的版块