[求助]：如何得到pl线的各个顶点的坐标数据，并将其分别写入变量中

zhynt · 发表于 2003-4-7 03:48:46

马上注册，结交更多好友，享用更多功能，让你轻松玩转社区。

您需要登录才可以下载或查看，没有账号？立即注册

×

有一个由多条线段（圆弧）组成的多段线，怎样才能获得各个顶点的坐标值？且将其分别写入变量如：pt1、pt2、pt3……ptn中。
我已经找到一个解决的方法：
选择一个多段线将返回一个类似于
((-1 . <图元名: 7ef5deb8>) (0 . "LWPOLYLINE") (330 . <图元名:
7ef5dcf8>) (5 . "8F") (100 . "AcDbEntity") (67 . 0) (410 . "Model") (8 . "0")
(100 . "AcDbPolyline") (90 . 8) (70 . 1) (43 . 0.0) (38 . 0.0) (39 . 0.0) (10
985.481 837.732) (40 . 0.0) (41 . 0.0) (42 . -0.414214) (10 1059.9 763.312) (40
. 0.0) (41 . 0.0) (42 . 0.0) (10 1059.9 361.039) (40 . 0.0) (41 . 0.0) (42 .
-0.414214) (10 985.481 286.619) (40 . 0.0) (41 . 0.0) (42 . 0.0) (10 635.071
286.619) (40 . 0.0) (41 . 0.0) (42 . -0.414214) (10 560.65 361.039) (40 . 0.0)
(41 . 0.0) (42 . 0.0) (10 560.65 763.312) (40 . 0.0) (41 . 0.0) (42 .
-0.414214) (10 635.071 837.732) (40 . 0.0) (41 . 0.0) (42 . 0.0) (210 0.0 0.0
1.0))
的表，多段线的顶点信息从第15表项开始以后每隔4个表项为一顶点，还可以根据表的长度算出多段线的线段数。
代码：

(defun aaa ()
(setq z_a (entsel))
(setq z_b (entget (car z_a)))
(setq n (length z_b))
(setq na (- (/ (- n 15) 4) 1))
(setq m 0)
(setq nb 14)
(while (<= m na)
(setq pt (cdr (nth nb z_b)))
(set (read (strcat "pt" (itoa (1+ m)))) pt)
(setq nb (+ nb 4))
(setq m (1+ m))
)
)

ll_j · 发表于 2003-4-7 18:50:38

这个问题好像不应该是雷锋同志应该问的。
你看看这样如何：

(setq e0 (entget (car (entsel "\n拾取 LWP多义线：")))
l1 nil
)
(mapcar
'(lambda(x)
(if (or (= (car x) 10) ;顶点
(= (car x) 42) ;凸度
)
(setq l1 (cons x l1))
)
)
e0
)
(reverse l1)

这样构成的表比使用很多的变量灵活的多。

eachy · 发表于 2003-4-7 18:55:03

看看CAD中的Vlisp例程。
用vla-get-Coordinates 得到顶点坐标，用下面的函数处理。

;;;--------------------------------------------------------------------;
;;; Function: list->variantArray ;
;;;--------------------------------------------------------------------;
;;; Description: This function takes one parameter representing a ;
;;; list of double values, e.g. a list of 2D points: ;
;;; '(p1.X p1.Y p2.X p2.Y p3.X p3.Y p4.X p4.Y). ;
;;; The list is converted into an ActiveX ;
;;; variant based on a safearray. ;
;;; No error checking is performed on the parameter -- ;
;;; it is assumed to consist of a list of doubles. ;
;;;------------------------------------------------------------------- ;
(defun gp:list->variantArray (ptsList / arraySpace sArray)
; allocate space for an array of 2d points stored as doubles
(setq arraySpace
(vlax-make-safearray
vlax-vbdouble ; element type
(cons 0
(- (length ptsList) 1)
) ; array dimension
)
)
(setq sArray (vlax-safearray-fill arraySpace ptsList))
; return array variant
(vlax-make-variant sArray)
)
;;;--------------------------------------------------------------------;
;;; Function: xyzList->ListOfPoints ;
;;;--------------------------------------------------------------------;
;;; Description: This function extracts and formats 3D point lists ;
;;; from one big list of reals, in the form: ;
;;; (x y z x y z x y z ...) ;
;;; This is the format of the data returned by the ;
;;; vla-get-coordinates function when applied to a ;
;;; standard polyline object. ;
;;;--------------------------------------------------------------------;
;;; The return value will be a list in the format: ;
;;; ((x y z) (x y z) (x y z) ... ) ;
;;;--------------------------------------------------------------------;
(defun xyzList->ListOfPoints (coordList / ptlist)
(while coordList
(setq ptlist (append ptlist
(list (list (car coordList) (cadr coordList) (caddr coordList)))
) ;_ end of append
coordList (cdddr coordList)
) ;_ end of setq
) ;_ end of while
ptlist
;;; (setq ptlist ptlist)
) ;_ end of defun
;;;--------------------------------------------------------------------;
;;; Function: xyList->ListOfPoints ;
;;;--------------------------------------------------------------------;
;;; Description: This function extracts and formats 2D point lists ;
;;; from one big list of reals, in the form: ;
;;; (x y x y x y ...) ;
;;; This is the format of the data returned by the ;
;;; vla-get-coordinates function when applied to a ;
;;; lightweight polyline object. ;
;;;--------------------------------------------------------------------;
;;; The return value will be a list in the format: ;
;;; ((x y) (x y) (x y) ... ) ;
;;;--------------------------------------------------------------------;
(defun xyList->ListOfPoints (coordList / ptlist)
(while coordList
(setq ptlist (append ptlist
(list (list (car coordList) (cadr coordList)))
) ;_ end of append
coordList (cddr coordList)
) ;_ end of setq
) ;_ end of while
ptlist
;;; (setq ptlist ptlist)
) ;_ end of defun

;;;--------------------------------------------------------------------; 
;;;     Function: list->variantArray                                   ; 
;;;--------------------------------------------------------------------; 
;;;  Description: This function takes one parameter representing a     ; 
;;;               list of double values, e.g. a list of 2D points:     ; 
;;;               '(p1.X p1.Y p2.X p2.Y p3.X p3.Y p4.X p4.Y).          ; 
;;;                  The list is converted into an ActiveX                ; 
;;;                  variant based on a safearray.                        ; 
;;;               No error checking is performed on the parameter --   ; 
;;;               it is assumed to consist of a list of doubles.       ; 
;;;------------------------------------------------------------------- ; 
(defun gp:list->variantArray (ptsList / arraySpace sArray) 
                                        ; allocate space for an array of 2d points stored as doubles 
  (setq        arraySpace 
         (vlax-make-safearray 
           vlax-vbdouble                ; element type 
           (cons 0 
                 (- (length ptsList) 1) 
           )                                ; array dimension 
         ) 
 
  ) 
  (setq sArray (vlax-safearray-fill arraySpace ptsList)) 
                                        ; return array variant 
  (vlax-make-variant sArray) 
) 
 
 
;;;--------------------------------------------------------------------; 
;;;     Function: xyzList->ListOfPoints                                ; 
;;;--------------------------------------------------------------------; 
;;;  Description: This function extracts and formats 3D point lists    ; 
;;;               from one big list of reals, in the form:             ; 
;;;                   (x y z x y z x y z ...)                          ; 
;;;               This is the format of the data returned by the       ; 
;;;               vla-get-coordinates function when applied to a       ; 
;;;               standard polyline object.                            ; 
;;;--------------------------------------------------------------------; 
;;;               The return value will be a list in the format:       ; 
;;;                    ((x y z) (x y z) (x y z) ... )                  ; 
;;;--------------------------------------------------------------------; 
(defun xyzList->ListOfPoints (coordList / ptlist) 
  (while coordList 
    (setq ptlist (append ptlist 
                         (list (list (car coordList) (cadr coordList) (caddr coordList))) 
                 ) ;_ end of append 
          coordList         (cdddr coordList) 
    ) ;_ end of setq 
  ) ;_ end of while 
  ptlist 
  ;;; (setq ptlist ptlist) 
) ;_ end of defun 
 
 
;;;--------------------------------------------------------------------; 
;;;     Function: xyList->ListOfPoints                                 ; 
;;;--------------------------------------------------------------------; 
;;;  Description: This function extracts and formats 2D point lists    ; 
;;;               from one big list of reals, in the form:             ; 
;;;                   (x y x y x y ...)                                ; 
;;;               This is the format of the data returned by the       ; 
;;;               vla-get-coordinates function when applied to a       ; 
;;;               lightweight polyline object.                         ; 
;;;--------------------------------------------------------------------; 
;;;               The return value will be a list in the format:       ; 
;;;                    ((x y) (x y) (x y) ... )                        ; 
;;;--------------------------------------------------------------------; 
(defun xyList->ListOfPoints (coordList / ptlist) 
  (while coordList 
    (setq ptlist (append ptlist 
                         (list (list (car coordList) (cadr coordList))) 
                 ) ;_ end of append 
          coordList         (cddr coordList) 
    ) ;_ end of setq 
  ) ;_ end of while 
    ptlist 
  ;;; (setq ptlist ptlist) 
) ;_ end of defun

zhynt · 发表于 2003-4-8 08:26:46

最初由 ll_j 发布
[B]这个问题好像不应该是雷锋同志应该问的。
你看看这样如何：
[code]
  (setq e0  (entget (car (entsel "\n拾取 LWP多义线：")))
l1  nil
  )
  (mapcar
'(lambda(x)
   (if (or (= (car x) 10) ... [/B]

怎么这么说呢，其实我有很多东西还不是太懂。

心梦相随 · 发表于 2003-4-14 19:30:10

仿ll-j,共同学习
⒈(setq e0  (entget (car (entsel "\n拾取 LWP多义线：")))  l1  nil  )
  (foreach x e0
   (if (or (= (car x) 10)       (= (car x) 42)  )
      (setq l1 (cons x l1))
   )
)
  (reverse l1)
⒉(setq e0  (entget (car (entsel "\n拾取 LWP多义线：")))  l1  nil i 0 )
  (while (setq x (nth i eo))
   (if (or (= (car x) 10)       (= (car x) 42)  )
      (setq l1 (cons x l1))
   )
(setq i (1+  i))
)
  (reverse l1)

账号		自动登录	找回密码
密码			立即注册

[求助] [求助]：如何得到pl线的各个顶点的坐标数据，并将其分别写入变量中

马上注册，结交更多好友，享用更多功能，让你轻松玩转社区。

相关帖子