[LISP函数]：做结构的请注意了

qiaqiadeng · 发表于 2006-7-20 20:27:34

马上注册，结交更多好友，享用更多功能，让你轻松玩转社区。

您需要登录才可以下载或查看，没有账号？立即注册

×

做结构的注意了，现有一显示梁配筋面积的程序，本人是借鉴XD里的一网友的帖子稍加修改，自认为很有用。我在XD里见过类似的，但不是原码，现我把我的源码拿出来给大家共享，希望能对大家有帮助：

(defun C:bb (/ myerr dxf toang fx add_solid
add_text dis olderr oldos oldfill ss
pd gr pt ent entold
)
(defun myerr (msg)
(setq *error* olderr)
(command "_.undo" "_b")
(princ)
)
(defun dxf (ent i)
(if (= (type ent) 'ename)
(setq ent (entget ent))
)
(cdr (assoc i ent))
)
(defun toang (ang i)
(if (= i 1)
(* ang (/ 180 pi))
(* ang (/ pi 180))
)
)
(defun fx (ang)
(cond
((>= (/ pi 2) ang 0) (list pi (+ pi (/ pi 2)) 1))
((>= pi ang (/ pi 2)) (list 0 (+ pi (/ pi 2)) 1))
((>= (+ pi (/ pi 2)) ang pi) (list 0 (/ pi 2) 0))
((>= (* 2 pi) ang (+ pi (/ pi 2))) (list pi (/ pi 2) 0))
)
)
(defun add_solid (p1 p2 p3 p4)
(entmakex (list (cons 0 "SOLID")
(cons 100 "AcDbEntity")
(cons 62 7)
(cons 100 "AcDbTrace")
(cons 10 p1)
(cons 11 p2)
(cons 12 p3)
(cons 13 p4)
)
)
)
(defun add_text (pt h ang txt style jus)
(entmakex (list (cons 0 "TEXT")
(cons 100 "AcDbEntity")
(cons 62 1)
(cons 100 "AcDbText")
(if (= jus 0)
(cons 10 pt)
(list 10 0.0 0.0 0.0)
)
(cons 40 h)
(cons 1 txt)
(cons 50 ang)
(cons 7 style)
(cons 72
(cond ((= jus 0) 0)
((= jus 1) 1)
((= jus 2) 1)
((= jus 3) 2)
)
)
(if (= jus 0)
(list 11 0.0 0.0 0.0)
(cons 11 pt)
)
(cons 100 "AcDbText")
(cons 73
(cond ((= jus 0) 0)
((= jus 1) 2)
((= jus 2) 3)
((= jus 3) 2)
)
)
)
)
)
(defun mj (txt1 / k1 n1 d as) ;计算诸如4%%13225所代表的面积:1963mm2
(setq k1 (vl-string-search "%%13" txt1)) ;k1=2 12%%13125 6/5
(setq n1 (atoi (substr txt1 1 k1)))
(setq d (atoi (substr txt1 (+ k1 6))))
(setq as (* pi d d 0.25 n1))
)
(defun mjj (txt / kong plus ww s1 s2) ;只要有txt就可以求出面积
(if (vl-string-search " " txt) ;去除两空格字符
(setq txt (vl-string-subst " " " " txt))
)
(setq kong (vl-string-search " " txt)) ;获得空格所在位置
(if (/= kong nil) ;如果有空格，则将txt从空格处去掉尾巴
(setq txt (substr txt 1 kong))
)
;到目前为止，txt只剩下有+号和无+号两种情况了
(setq plus (vl-string-search "+" txt)) ;获得+所在位置
(if (= plus nil) ;如果没有+，则直接进行计算
(setq ww (mj txt))
(progn
(setq s1 (mj (substr txt 1 plus)))
(setq s2 (mj (substr txt (+ plus 2))))
(setq ww (+ s1 s2))
)
)
(setq ww ww)
)
(defun dis (ent / obj laynm name st1 st2 st3 lst
h ang n text fenhao ww1 ww2 ss1
ss2 i d s i1 i2 i3 s1 s2
n as1 as2 fyjisuan fy
)
(setq obj (vlax-ename->vla-object ent))
(setq laynm (strcat "图层:" (dxf ent 8))
name (dxf ent 0)
)
(if (or (= name "TEXT") (= name "MTEXT"))
(progn
(setq text (vla-get-textstring obj)) ;获得文字内容
(if (vl-string-search "%%13" text)
(progn
;(setq text "2%%13114;3%%13114")
(setq fenhao (vl-string-search ";" text)) ;获得;所在位置
;集中标注情况
(if (>= fenhao 0) ;有分号则输出面积
(progn
(setq ww1 (substr text 1 fenhao)) ;分号前面的文字
(setq ww2 (substr text (+ fenhao 2))) ;分号后面的文字
(setq ss1 (/ (mjj ww1) 100))
(setq ss2 (/ (mjj ww2) 100))
(setq ss1 (rtos ss1 2 2))
(setq ss2 (rtos ss2 2 2))
(setq lst (list (strcat ss1 ";" ss2)))
)
(setq lst (list (rtos (/ (mjj text) 100) 2 2)))
;如果没有;则将进行计算
)
(if ;%%1308@100板钢筋情况
(wcmatch text "%%13#*[@-@]###,%%13#*[@-@]##,%%13#*[@-@]#")
(progn
;(setq text "%%13110@200")
(setq i (vl-string-search "@" text))
(setq d (atof (substr text 6 (- i 6 -1))))
(setq s (atof (substr text (+ i 2))))
(setq stellas (/ (* pi d d 0.25 1000) s))
(setq fy (fylisp (substr text 1 5)))
(setq fyjisuan 210) ;计算时用一级钢则采用210，可根据情况修改**********************************
(if (= fy 210) ;如果是一级钢则只输出自身面积，否则输出自身及转换成一级钢后的面积
(setq lst (list (strcat "板筋:" (rtos stellas 2 1))))
(setq lst
(list (strcat "板筋:"
(rtos stellas 2 1)
"/"
(rtos (/ (* stellas fy) fyjisuan) 2 1)
)
)
)
)
)
)
(if ;%%1308@100/150(2)箍筋情况
(wcmatch text "%%13#*[@-@]*/*(#)")
(progn
(setq i1 (vl-string-search "@" text))
(setq i2 (vl-string-search "/" text))
(setq i3 (vl-string-search "(" text))
(setq d (atof (substr text 6 (- i1 6 -1))))
(setq s1 (atof (substr text (+ i1 2) (- i2 i1))))
(setq s2 (atof (substr text (+ i2 2) (- i3 i1))))
(setq n
(atof (substr text (+ i3 2) (- (strlen text) i3 2)))
)
(setq as1 (/ (* pi d d 0.25 100 n) s1 100))
;换成100间距时的箍筋面积
(setq as2 (/ (* pi d d 0.25 100 n) s2 100))
;换成100间距时的箍筋面积
(setq fy (fylisp (substr text 1 5)))
(setq fyjisuan 210) ;计算时用一级钢则采用210，可根据情况修改**********************************
(if (= fy 210)
(setq lst
(list (strcat "G" (rtos as1 2 2) "-" (rtos as2 2 2))
)
)
(setq lst
(list (strcat "G" (rtos as1 2 2) "-" (rtos as2 2 2))
(strcat "G"
(rtos (/ (* as1 fy) fyjisuan) 2 2)
"-"
(rtos (/ (* as2 fy) fyjisuan) 2 2)
)
)
)
)
)
)
(if ;%%1308@100(2)箍筋情况
(wcmatch
text
"%%13#*[@-@]###(#),%%13#*[@-@]##(#),%%13#*[@-@]#(#)"
)
(progn
(setq i1 (vl-string-search "@" text))
(setq i2 (vl-string-search "(" text))
(setq d (atof (substr text 6 (- i1 6 -1))))
(setq s1 (atof (substr text (+ i1 2) (- i2 i1))))
(setq n
(atof (substr text (+ i2 2) (- (strlen text) i2 2)))
)
(setq as1 (/ (* pi d d 0.25 100 n) s1 100))
;换成100间距时的箍筋面积
(setq fy (fylisp (substr text 1 5)))
(setq fyjisuan 210) ;计算时用一级钢则采用210，可根据情况修改**********************************
(if (= fy 210)
(setq lst
(list (strcat "G" (rtos as1 2 2))
)
)
(setq lst
(list (strcat "G" (rtos as1 2 2))
(strcat "G"
(rtos (/ (* as1 fy) fyjisuan) 2 2)
)
)
)
)
)
)
(if ;G6%%13112情况
(wcmatch
text
"G*%%13#*,N*%%13#*"
)
(progn
;(setq text "G12%%1318")
(setq i (vl-string-search "%%13" text))
(setq n (atof (substr text 2 i)))
(setq d (atof (substr text (+ i 6))))
(setq as1 (* pi d d 0.25 n 0.5 0.01))
(setq lst
(list (strcat "单边面积:" (rtos as1 2 2))
)
)
)
)
)
)
)
(setq lst (list "非文字对象!"))
)
(setq ss (ssadd)
h (/ (getvar "viewsize") 10)
)
(setq ang (fx (angle (getvar "viewctr") pt)))
(setq n (* 1.4 (1+ (/ (apply 'max (mapcar 'strlen lst)) 2.0))))
(ssadd (add_solid
pt
(polar pt (car ang) (* n h))
(setq pt (polar pt (cadr ang) (+ h (* 1.8 h (length lst)))))
(polar pt (car ang) (* n h))
)
ss
)
(setq pt (polar pt (car ang) (/ (* n h) 2)))
(if (= (caddr ang) 0)
(setq pt (polar pt (/ pi 2) (* 0.4 h)))
(setq pt (polar pt (/ pi 2) (+ (* 1.4 h) (* 1.8 h (length lst)))))
)
(setq n -1)
(repeat (length lst)
(ssadd (add_text (setq pt (polar pt (+ pi (/ pi 2)) (* 1.8 h)))
h
0
(nth (setq n (1+ n)) lst)
"STANDARD"
1
)
ss
)
)
)
(vl-load-com)
(command "_.undo" "_m")
(princ "动态显示梁、板主、箍筋面积\n")
(setq olderr *error*
*error* myerr
)
(setq oldos (getvar "osmode"))
(setq oldfill (getvar "fillmode"))
(setvar "osmode" 0)
(setvar "fillmode" 1)
(setvar "cmdecho" 0)
(command "_.style" "STANDARD" "tssdeng2.shx,tssdchn.shx"
"" 0.7 "" ""
"" ""
)
(setq ss (ssadd))
(while (not pd)
(while (not (progn
(setq gr (grread T 2))
(if (= (car gr) 5)
(setq pt (cadr gr)
ent (nentselp pt)
ent (if (and ent (= (type (last (last ent))) 'ename))
(last (last ent))
(car ent)
)
)
(setq pd T)
)
)
)
)
(if (and (not pd)
(not (equal ent entold))
(not (ssmemb ent ss))
)
(progn
(if entold
(redraw entold 4)
)
(if ss
(command "_.erase" ss "")
)
(redraw ent 3)
(dis ent)
(setq entold ent)
)
)
)
(if entold
(redraw entold 4)
)
(if ss
(command "_.erase" ss "")
)
(setvar "osmode" oldos)
(setvar "fillmode" oldfill)
(setq *error* olderr)
(princ)
) ;bb定义完成
(defun fylisp (ttt / fy)
(cond
((= ttt "%%130") (setq fy 210))
((= ttt "%%131") (setq fy 300))
((= ttt "%%132") (setq fy 360))
((= ttt "%%133") (setq fy 360))
)
(setq fy fy)
)

(defun C:bb (/             myerr   dxf     toang   fx             add_solid 
             add_text             dis     olderr  oldos   oldfill ss 
             pd             gr             pt             ent     entold 
            ) 
  (defun myerr (msg) 
    (setq *error* olderr) 
    (command "_.undo" "_b") 
    (princ) 
  ) 
  (defun dxf (ent i) 
    (if        (= (type ent) 'ename) 
      (setq ent (entget ent)) 
    ) 
    (cdr (assoc i ent)) 
  ) 
 
  (defun toang (ang i) 
    (if        (= i 1) 
      (* ang (/ 180 pi)) 
      (* ang (/ pi 180)) 
    ) 
  ) 
 
  (defun fx (ang) 
    (cond 
      ((>= (/ pi 2) ang 0) (list pi (+ pi (/ pi 2)) 1)) 
      ((>= pi ang (/ pi 2)) (list 0 (+ pi (/ pi 2)) 1)) 
      ((>= (+ pi (/ pi 2)) ang pi) (list 0 (/ pi 2) 0)) 
      ((>= (* 2 pi) ang (+ pi (/ pi 2))) (list pi (/ pi 2) 0)) 
    ) 
  ) 
 
  (defun add_solid (p1 p2 p3 p4) 
    (entmakex (list (cons 0 "SOLID") 
                    (cons 100 "AcDbEntity") 
                    (cons 62 7) 
                    (cons 100 "AcDbTrace") 
                    (cons 10 p1) 
                    (cons 11 p2) 
                    (cons 12 p3) 
                    (cons 13 p4) 
              ) 
    ) 
  ) 
 
  (defun add_text (pt h ang txt style jus) 
    (entmakex (list (cons 0 "TEXT") 
                    (cons 100 "AcDbEntity") 
                    (cons 62 1) 
                    (cons 100 "AcDbText") 
                    (if        (= jus 0) 
                      (cons 10 pt) 
                      (list 10 0.0 0.0 0.0) 
                    ) 
                    (cons 40 h) 
                    (cons 1 txt) 
                    (cons 50 ang) 
                    (cons 7 style) 
                    (cons 72 
                          (cond        ((= jus 0) 0) 
                                ((= jus 1) 1) 
                                ((= jus 2) 1) 
                                ((= jus 3) 2) 
                          ) 
                    ) 
                    (if        (= jus 0) 
                      (list 11 0.0 0.0 0.0) 
                      (cons 11 pt) 
                    ) 
                    (cons 100 "AcDbText") 
                    (cons 73 
                          (cond        ((= jus 0) 0) 
                                ((= jus 1) 2) 
                                ((= jus 2) 3) 
                                ((= jus 3) 2) 
                          ) 
                    ) 
              ) 
    ) 
  ) 
 
  (defun mj (txt1 / k1 n1 d as)                ;计算诸如4%%13225所代表的面积:1963mm2 
    (setq k1 (vl-string-search "%%13" txt1)) ;k1=2   12%%13125 6/5 
    (setq n1 (atoi (substr txt1 1 k1))) 
    (setq d (atoi (substr txt1 (+ k1 6)))) 
    (setq as (* pi d d 0.25 n1)) 
  ) 
 
  (defun mjj (txt / kong plus ww s1 s2)        ;只要有txt就可以求出面积 
    (if        (vl-string-search "  " txt)        ;去除两空格字符 
      (setq txt (vl-string-subst " " "  " txt)) 
    ) 
    (setq kong (vl-string-search " " txt)) ;获得空格所在位置 
    (if        (/= kong nil)                        ;如果有空格，则将txt从空格处去掉尾巴 
      (setq txt (substr txt 1 kong)) 
    ) 
                                        ;到目前为止，txt只剩下有+号和无+号两种情况了 
    (setq plus (vl-string-search "+" txt)) ;获得+所在位置 
    (if        (= plus nil)                        ;如果没有+，则直接进行计算 
      (setq ww (mj txt)) 
      (progn 
        (setq s1 (mj (substr txt 1 plus))) 
        (setq s2 (mj (substr txt (+ plus 2)))) 
        (setq ww (+ s1 s2)) 
      ) 
    ) 
    (setq ww ww) 
  ) 
 
 
  (defun dis (ent   /          obj        laynm name  st1          st2        st3   lst 
              h            ang          n        text  fenhao          ww1        ww2   ss1 
              ss2   i          d        s     i1    i2          i3        s1    s2 
              n            as1          as2        fyjisuan    fy 
             ) 
    (setq obj (vlax-ename->vla-object ent)) 
    (setq laynm        (strcat "图层:" (dxf ent 8)) 
          name        (dxf ent 0) 
    ) 
 
    (if        (or (= name "TEXT") (= name "MTEXT")) 
      (progn 
        (setq text (vla-get-textstring obj)) ;获得文字内容 
        (if (vl-string-search "%%13" text) 
          (progn 
                                        ;(setq text "2%%13114;3%%13114") 
            (setq fenhao (vl-string-search ";" text)) ;获得;所在位置 
                                        ;集中标注情况 
            (if        (>= fenhao 0)                ;有分号则输出面积 
              (progn 
                (setq ww1 (substr text 1 fenhao)) ;分号前面的文字 
                (setq ww2 (substr text (+ fenhao 2))) ;分号后面的文字 
                (setq ss1 (/ (mjj ww1) 100)) 
                (setq ss2 (/ (mjj ww2) 100)) 
                (setq ss1 (rtos ss1 2 2)) 
                (setq ss2 (rtos ss2 2 2)) 
                (setq lst (list (strcat ss1 ";" ss2))) 
              ) 
              (setq lst (list (rtos (/ (mjj text) 100) 2 2))) 
                                        ;如果没有;则将进行计算 
            ) 
 
            (if                                ;%%1308@100板钢筋情况 
              (wcmatch text "%%13#*[@-@]###,%%13#*[@-@]##,%%13#*[@-@]#") 
               (progn 
                                        ;(setq text "%%13110@200") 
                 (setq i (vl-string-search "@" text)) 
                 (setq d (atof (substr text 6 (- i 6 -1)))) 
                 (setq s (atof (substr text (+ i 2)))) 
                 (setq stellas (/ (* pi d d 0.25 1000) s)) 
                 (setq fy (fylisp (substr text 1 5))) 
 
                 (setq fyjisuan 210)        ;计算时用一级钢则采用210，可根据情况修改********************************** 
                 (if (= fy 210)                ;如果是一级钢则只输出自身面积，否则输出自身及转换成一级钢后的面积 
                   (setq lst (list (strcat "板筋:" (rtos stellas 2 1)))) 
                   (setq lst 
                          (list        (strcat        "板筋:" 
                                        (rtos stellas 2 1) 
                                        "/" 
                                        (rtos (/ (* stellas fy) fyjisuan) 2 1) 
                                ) 
                          ) 
                   ) 
                 ) 
               ) 
            ) 
 
            (if                                ;%%1308@100/150(2)箍筋情况 
              (wcmatch text "%%13#*[@-@]*/*(#)") 
               (progn 
                 (setq i1 (vl-string-search "@" text)) 
                 (setq i2 (vl-string-search "/" text)) 
                 (setq i3 (vl-string-search "(" text)) 
                 (setq d (atof (substr text 6 (- i1 6 -1)))) 
                 (setq s1 (atof (substr text (+ i1 2) (- i2 i1)))) 
                 (setq s2 (atof (substr text (+ i2 2) (- i3 i1)))) 
                 (setq n 
                        (atof (substr text (+ i3 2) (- (strlen text) i3 2))) 
                 ) 
                 (setq as1 (/ (* pi d d 0.25 100 n) s1 100)) 
                                        ;换成100间距时的箍筋面积 
                 (setq as2 (/ (* pi d d 0.25 100 n) s2 100)) 
                                        ;换成100间距时的箍筋面积 
                 (setq fy (fylisp (substr text 1 5))) 
                 (setq fyjisuan 210)        ;计算时用一级钢则采用210，可根据情况修改********************************** 
 
                 (if (= fy 210) 
                   (setq lst 
                          (list        (strcat "G" (rtos as1 2 2) "-" (rtos as2 2 2)) 
                          ) 
                   ) 
                   (setq lst 
                          (list        (strcat "G" (rtos as1 2 2) "-" (rtos as2 2 2)) 
                                (strcat        "G" 
                                        (rtos (/ (* as1 fy) fyjisuan) 2 2) 
                                        "-" 
                                        (rtos (/ (* as2 fy) fyjisuan) 2 2) 
                                ) 
                          ) 
                   ) 
                 ) 
               ) 
            ) 
 
 
            (if                                ;%%1308@100(2)箍筋情况 
              (wcmatch 
                text 
                "%%13#*[@-@]###(#),%%13#*[@-@]##(#),%%13#*[@-@]#(#)" 
              ) 
               (progn 
                 (setq i1 (vl-string-search "@" text)) 
                 (setq i2 (vl-string-search "(" text)) 
                 (setq d (atof (substr text 6 (- i1 6 -1)))) 
                 (setq s1 (atof (substr text (+ i1 2) (- i2 i1)))) 
                 (setq n 
                        (atof (substr text (+ i2 2) (- (strlen text) i2 2))) 
                 ) 
                 (setq as1 (/ (* pi d d 0.25 100 n) s1 100)) 
                                        ;换成100间距时的箍筋面积 
                 (setq fy (fylisp (substr text 1 5))) 
                 (setq fyjisuan 210)        ;计算时用一级钢则采用210，可根据情况修改********************************** 
 
                 (if (= fy 210) 
                   (setq lst 
                          (list        (strcat "G" (rtos as1 2 2)) 
                          ) 
                   ) 
                   (setq lst 
                          (list        (strcat "G" (rtos as1 2 2)) 
                                (strcat        "G" 
                                        (rtos (/ (* as1 fy) fyjisuan) 2 2) 
                                ) 
                          ) 
                   ) 
                 ) 
               ) 
            ) 
 
            (if                                ;G6%%13112情况 
              (wcmatch 
                text 
                "G*%%13#*,N*%%13#*" 
              ) 
               (progn 
                                        ;(setq text "G12%%1318") 
                 (setq i (vl-string-search "%%13" text)) 
                 (setq n (atof (substr text 2 i))) 
                 (setq d (atof (substr text (+ i 6)))) 
 
                 (setq as1 (* pi d d 0.25 n 0.5 0.01)) 
                 (setq lst 
                        (list (strcat "单边面积:" (rtos as1 2 2)) 
                        ) 
                 ) 
               ) 
            ) 
 
 
          ) 
        ) 
 
      ) 
 
      (setq lst (list "非文字对象!")) 
    ) 
 
    (setq ss (ssadd) 
          h  (/ (getvar "viewsize") 10) 
    ) 
    (setq ang (fx (angle (getvar "viewctr") pt))) 
    (setq n (* 1.4 (1+ (/ (apply 'max (mapcar 'strlen lst)) 2.0)))) 
    (ssadd (add_solid 
             pt 
             (polar pt (car ang) (* n h)) 
             (setq pt (polar pt (cadr ang) (+ h (* 1.8 h (length lst))))) 
             (polar pt (car ang) (* n h)) 
           ) 
           ss 
    ) 
    (setq pt (polar pt (car ang) (/ (* n h) 2))) 
    (if        (= (caddr ang) 0) 
      (setq pt (polar pt (/ pi 2) (* 0.4 h))) 
      (setq pt (polar pt (/ pi 2) (+ (* 1.4 h) (* 1.8 h (length lst))))) 
    ) 
    (setq n -1) 
    (repeat (length lst) 
      (ssadd (add_text (setq pt (polar pt (+ pi (/ pi 2)) (* 1.8 h))) 
                       h 
                       0 
                       (nth (setq n (1+ n)) lst) 
                       "STANDARD" 
                       1 
             ) 
             ss 
      ) 
    ) 
  ) 
 
 
  (vl-load-com) 
  (command "_.undo" "_m") 
  (princ "动态显示梁、板主、箍筋面积\n") 
  (setq        olderr        *error* 
        *error*        myerr 
  ) 
  (setq oldos (getvar "osmode")) 
  (setq oldfill (getvar "fillmode")) 
  (setvar "osmode" 0) 
  (setvar "fillmode" 1) 
  (setvar "cmdecho" 0) 
  (command "_.style"          "STANDARD"         "tssdeng2.shx,tssdchn.shx" 
           ""                  0.7                 ""                "" 
           ""                  "" 
          ) 
  (setq ss (ssadd)) 
 
  (while (not pd) 
    (while (not        (progn 
                  (setq gr (grread T 2)) 
                  (if (= (car gr) 5) 
                    (setq pt  (cadr gr) 
                          ent (nentselp pt) 
                          ent (if (and ent (= (type (last (last ent))) 'ename)) 
                                (last (last ent)) 
                                (car ent) 
                              ) 
                    ) 
                    (setq pd T) 
                  ) 
                ) 
           ) 
    ) 
    (if        (and (not pd) 
             (not (equal ent entold)) 
             (not (ssmemb ent ss)) 
        ) 
      (progn 
        (if entold 
          (redraw entold 4) 
        ) 
        (if ss 
          (command "_.erase" ss "") 
        ) 
        (redraw ent 3) 
        (dis ent) 
        (setq entold ent) 
      ) 
    ) 
  ) 
  (if entold 
    (redraw entold 4) 
  ) 
  (if ss 
    (command "_.erase" ss "") 
  ) 
  (setvar "osmode" oldos) 
  (setvar "fillmode" oldfill) 
  (setq *error* olderr) 
  (princ) 
)                                        ;bb定义完成 
 
 
(defun fylisp (ttt / fy) 
  (cond 
    ((= ttt "%%130") (setq fy 210)) 
    ((= ttt "%%131") (setq fy 300)) 
    ((= ttt "%%132") (setq fy 360)) 
    ((= ttt "%%133") (setq fy 360)) 
  ) 
  (setq fy fy) 
)

ALU · 发表于 2006-7-20 20:45:34

qiaqiadeng 楼主，是那个版本的，在R14可用否?

oyxx_1023 · 发表于 2006-7-20 21:30:52

不能在R14下用.vl-string-search不能运行在R14下.

它山之石 · 发表于 2006-7-22 14:21:40

好啊，俺先下来看看，与XD里的那个类似的有什么不同。

qiaqiadeng · 发表于 2006-8-5 11:16:49

我用的是2004版的,对R14,我是在2000年毕业设计时使用过,实在没时间去研究这些问题,其实我本人认为R14实在没什么好用的,画图太累了,建议各位用2004,用2006或2008都可以,刻舟求剑没什么好的,我之所以还没用2006,那是因为TSSD我只有2004版的,否则我用2006肯定很爽,对了,上面的程序我最近又有修改,只是今天没带到网吧来,抱歉,关于vl-string-search,可以对上面的代码捎加修改就行了,用substr,一个个找,不难的.

xjlmlxbq · 发表于 2006-8-5 12:07:56

与它山之石的东东有什么不同?

hungbeetle · 发表于 2006-8-14 15:07:51

HAO !下了线看看再叫好最好具体怎么使用再所说

账号		自动登录	找回密码
密码			立即注册

[LISP函数]：做结构的请注意了

马上注册，结交更多好友，享用更多功能，让你轻松玩转社区。

相关帖子