[求助]：菜鸟请教程序错误处理：未知命令“”

eobser

以下是一个列乘的小程序，运算可以执行，但总提示未知命令：“test”，大家帮忙看下，谢谢！
(defun c:test ()
   (setvar "cmdecho" 0)
   (setq odim (getvar "dimzin"))
   (setvar "dimzin" 1)
   (prompt "\n请选择第一列乘数:")
   (setq ss1 (ssget (list (cons 0 "TEXT"))))
   (prompt "\n请选择第二列乘数:")
   (setq ss2 (ssget (list (cons 0 "TEXT"))))
   (if (null (setq ent_f (getreal "\n输入小数点位数[2]:")))
       (setq ent_f 2)
   )
   (setq pt1 (getpoint "\n选择基点:")
         pt2 (getpoint pt1 "\n指定置放点:")
   )
   
   (setq ent1 (entlast))   
   (command "copy" ss2 "" pt1 pt2 "")
   (setq ss3 (ssadd))
   (while (setq ent1 (entnext ent1))
          (ssadd ent1 ss3)
   )
   (setq ss1n (sslength ss1)
         ss2n (sslength ss2)
   )
   (setq i 0)
   (if (= ss1n ss2n)
       (repeat ss1n
           (setq ent3 (entget (ssname ss3 i)))
           (setq y3 (caddr (assoc 10 ent3)))
           (setq ii 0)
           (repeat ss1n
                   (if (= y3 (caddr (assoc 10 (entget (ssname ss1 ii)))))
                       (setq text1 (atof (cdr (assoc 1 (entget (ssname ss1 ii))))))
                   )
                   (if (= y3 (caddr (assoc 10 (entget (ssname ss2 ii)))))
                       (setq text2 (atof (cdr (assoc 1 (entget (ssname ss2 ii))))))
                   )
                   (setq ii (1+ ii))
           )
           (setq text3 (rtos (/ (* text1 text2) 1000) 2 (fix ent_f)))
           (setq ent3 (subst (cons 1 text3) (assoc 1 ent3) ent3))
           (entmod ent3)
           (setq i (1+ i))           
       )
   )           
   (setvar "dimzin" odim)
   (princ)
)

Underway

(command "copy" ss2 "" pt1 pt2 "")

Try this==>
(command "copy" ss2 "" pt1 pt2)

jinsong-liao

多了双引号，相当于多按了空格键，故提示未知命令。

eobser

可以了。
谢谢两位！