[求助]：文本替换问题

hmh888888

CAD2004，长文本换为短文本测试
单行文本，对齐方式为中间
修改后，不会回到中间夹点了
而是左对齐到原文本的——>左夹点了
移动一下才中间对正
？？？？？？





源程序：整个文件夹CAD图批量文本替换（多、单行）
;;文字的批量修改
(arxload "acetutil.arx" NIL)
;;需要相应版本的ET工具(acetutil.arx,acetutil.dll)支持
(vl-load-com)

(defun c:changt (/ NEWTXT OLDTXT)

  (setq oldtxt (getstring "\n查找文字:"))
  (setq newtxt (getstring "\n替换文字:"))
  (setq OLDECHO (getvar "cmdecho"))
  ;;保存系统变量值
  (setvar "cmdecho" 0)
  (setq        path
         (strcat
           (vl-string-right-trim
             "\\"
             (strcase (acet-ui-pickdir
                        "选择目录"
                        "D:\\"           ;(vl-string-right-trim "\\" (getvar "dwgprefix"))
                        "批量修改"
                      )
             )
           )
           "\\"
         )
  )
  (setq OLDLSP (getvar "ACADLSPASDOC"))
  ;;保存系统变量值
  (setvar "acadlspasdoc" 0)
  (setq dwgname (vl-directory-files path "*.DWG"))
  (setq num 0)
  (if (/= dwgname NIL)
    (progn
      (setq APP (vlax-get-acad-object))        ;获得Acad 对象
      (repeat (length dwgname)
        (setq DWGNAME2 (strcase (strcat path (nth num dwgname))))  ;======把路径字母全部转为大写，并赋与DWGNAME2
        (setq doc (vla-open (vla-get-documents APP) DWGNAME2))
                                        ;打开图形并获得其对象
        (setq msp (vla-get-ModelSpace doc))
        (vlax-for ENT msp
          (if (and (vlax-property-available-p ENT 'TEXTSTRING)
                   (wcmatch (setq STR (vla-get-textstring ENT))
                            (strcat "*" OLDTXT "*")
                   )
              )
            (progn
              (setq STR (vl-string-subst NEWTXT OLDTXT STR));
              (vla-put-textstring ENT STR)
            )
          )
        )
        (vla-save DOC)
        (prompt (strcat "\n" DWGNAME2 " <修改Text完成>!!!"))
        (vla-close doc :vlax-false)        ;关闭图形(不检查是否保存)
        (setq num (1+ num))
      )
      (vlax-release-object doc)
      (vlax-release-object APP)
    )
    (prompt "\n所选目录中未有任何图形!!")
  )
  (setvar "acadlspasdoc" OLDLSP)
  ;;恢复系统变量值
  (setvar "cmdecho" OLDECHO)
  ;;恢复系统变量值
  (princ)
)