[已解决]：如果获取属性块中的“标记”“提示”“默认”值？

Wildcat · 发表于 2007-9-7 16:41:27

马上注册，结交更多好友，享用更多功能，让你轻松玩转社区。

您需要登录才可以下载或查看，没有账号？立即注册

×

在Vlisp中，如果获取属性块中的“标记”“提示”“默认”的值？图块中可能存在多个属性文字（例如图框）。（块中带有ddattdef命令创建的文字，就叫属性块。对吗？）

A图框和B图框为同一个属性块，但属性文字的值不同。
我最终目的是想把A图框内的（设计、制图、审定）替换至B图框内的（设计、制图、审定）。

carrot1983 · 发表于 2007-9-7 17:57:49

[php]
;;获取属性块中的“标记”“默认”值
;;
(defun vlex-GetAttributes (ent / blkref lst)
  (vl-load-com)
  (if (= (vla-Get-ObjectName
   (setq blkref (vlax-Ename->vla-Object ent))
   )
   "AcDbBlockReference"
   )
(if (vla-Get-HasAttributes blkref)
   (mapcar
'(lambda (x)
   (setq
      lst (cons
   (list (vla-Get-TagString x) (vla-Get-TextString x))
   lst
   )
   )
   )
(vlax-safearray->list
   (vlax-variant-value (vla-GetAttributes blkref))
)
   )
)
  )
  (reverse lst)
)
[/php]
(setq ent (car (entsel)))
(vlex-GetAttributes ent)

取得属性的提示: (vla-get-PromptString Object ) 好像不行.

sony123 · 发表于 2007-9-8 07:20:19

还有个苯办法 eattext (属性提取)

我的错这个是lisp 版块

Wildcat · 发表于 2007-9-10 16:53:43

请问如何把一个新的表替换lst？
我只学了autolisp，现在边查vlisp函数边学习，可以基本看懂您的程序含义，想依葫芦画瓢，估计要调用vla-put-TagString和vla-put-TextString函数，但搞了几天也搞不定。再请教。

carrot1983 · 发表于 2007-9-10 17:58:54

如果只是想换掉图框中某些标记对应的默认值
(replattstr e2 tagstring textstring)
tagstring textstring可以做成表.然后遍历表....

[php]
(vl-load-com)
(defun c:tt ()
  (setq e1 (car (entsel "\n>>>选择 A 图框:")))
  (setq e2 (car (entsel "\n>>>选择 B 图框:")))
  (setq lst1 (vlex-GetAttributes e1))
  (foreach t1 lst1
(setq tagstring (car t1))
(setq textstring (cadr t1))
(replattstr e2 tagstring textstring)
  )
)

;;;修改块属性文字__mapcar+lamdba
(defun replattstr (ent tagstring textstring / blkref x)
  (if (= (vla-get-objectname
   (setq blkref (vlax-ename->vla-object ent))
   )
   "AcDbBlockReference"
   )
(progn
   (if (vla-get-hasattributes blkref)
(progn
   (mapcar '(lambda (x)
      (if (= tagstring (vla-get-tagstring x))
         (vla-put-textstring x textstring)
      ) ;if
   ) ;lambda
   (vlax-safearray->list
      (vlax-variant-value (vla-getattributes blkref))
   )
   ) ;mapcar
) ;progn
   ) ;if
) ;progn
  ) ;if
  (princ)
)

;;;取得块属性的列表
(defun vlex-GetAttributes (ent / blkref lst)
  (if (= (vla-Get-ObjectName
   (setq blkref (vlax-Ename->vla-Object ent))
   )
   "AcDbBlockReference"
   )
(if (vla-Get-HasAttributes blkref)
   (mapcar
'(lambda (x)
   (setq
      lst (cons
   (list (vla-Get-TagString x) (vla-Get-TextString x))
   lst
   )
   )
   )
(vlax-safearray->list
   (vlax-variant-value (vla-GetAttributes blkref))
)
   ) ; mapcar
) ; endif
  ) ; endif
  (reverse lst)
)

[/php]

注意:给个类似的通用函数:

;|获取块中所有属性
函数名：VxGetAtts
功能：获取块中所有属性
Copyright:2000 MENZI ENGINEERING GmbH, Switzerland
参数[类型]:
Obj = Object [VLA-OBJECT]
返回值 [类型]: 点表 '(("Tag1" . "Val1")...) [LIST]
|;
(defun VxGetAtts (Obj)
(mapcar
'(lambda (Att)
(cons (vla-get-TagString Att)
(vla-get-TextString Att)
)
)
(vlax-invoke Obj "GetAttributes")
)
)
;|VxSetAtts - Sets?attribute values to block
函数名: VxSetAtts
功能: 设置块中属性
Copyright: ?000 MENZI ENGINEERING GmbH, Switzerland
参数 [类型]:
Obj = Object [VLA-OBJECT]
Lst = 点表 '(("Tag1" . "Val1")...) [LIST]
返回值[类型]: nil
|;
(defun VxSetAtts (Obj Lst / AttVal)
(mapcar
'(lambda (Att)
(if (setq AttVal (cdr (assoc (vla-get-TagString Att) Lst)))
(vla-put-TextString Att AttVal)
)
)
(vlax-invoke Obj "GetAttributes")
)
(vla-update Obj)
(princ)
)

;|获取块中所有属性 
函数名：VxGetAtts 
功  能：获取块中所有属性 
Copyright:2000 MENZI ENGINEERING GmbH, Switzerland 
参  数[类型]: 
         Obj = Object [VLA-OBJECT] 
返回值 [类型]: 点表 '(("Tag1" . "Val1")...) [LIST] 
|; 
(defun VxGetAtts (Obj) 
  (mapcar 
    '(lambda (Att) 
       (cons (vla-get-TagString Att) 
             (vla-get-TextString Att) 
       ) 
     ) 
    (vlax-invoke Obj "GetAttributes") 
  ) 
) 
 ;|VxSetAtts - Sets?attribute values to block 
函数名: VxSetAtts 
功  能: 设置块中属性 
Copyright: ?000 MENZI ENGINEERING GmbH, Switzerland 
参数 [类型]: 
    Obj = Object [VLA-OBJECT] 
    Lst = 点表 '(("Tag1" . "Val1")...) [LIST] 
返回值[类型]: nil 
|; 
(defun VxSetAtts (Obj Lst / AttVal) 
  (mapcar 
    '(lambda (Att) 
       (if (setq AttVal (cdr (assoc (vla-get-TagString Att) Lst))) 
         (vla-put-TextString Att AttVal) 
       ) 
     ) 
    (vlax-invoke Obj "GetAttributes") 
  ) 
  (vla-update Obj) 
  (princ) 
)

雨箭风刀 · 发表于 2007-9-10 18:09:18

(if (and (setq e (car(entsel)))
   (setq o (vlax-Ename->vla-Object e))
   (= "AcDbBlockReference" (vla-get-objectname o)))
  (mapcar '(lambda(x)(mapcar '(lambda(y)(vlax-get x y))'(TagString TextString )))(vlax-invoke o 'getattributes))
)

zhoufupeng · 发表于 2007-9-10 20:47:31

lisp的话我一般是这样用的，有点麻烦。
(setq a (car (entsel ))) ;;;选择块
(setq b (entnext a))
(steq b_data (entget b));;;就可以提取图元列表.
如果要下个属性
(setq c (entnext b))
(steq c_data (entget c)
一直下去就可以取得所有的属性
值.

carrot1983 · 发表于 2007-9-11 08:39:05

(vlax-get x y))'(TagString TextString )))
我也刚学VLisp,更多的都是用别人写好的.
这个太帅了..强
7楼的兄弟,你没搞清楚,这里所谓的属性块是,ATTDEF+(W)BLOCK
你说的那个是图元数据.

Wildcat · 发表于 2007-9-11 15:28:25

最初由雨箭风刀发布
[B](if (and (setq e (car(entsel)))
   (setq o (vlax-Ename->vla-Object e))
   (= "AcDbBlockReference" (vla-get-objectname o)))
  (mapcar '(lambda(x)(mapcar '(lambda(y)(vlax-get x y))'(TagString TextStrin... [/B]

每次雨箭风刀帮我解答疑难的程序都是那么短小精悍哦。谢谢您。
请问(vlax-invoke o 'getattributes)的意义是通过 ActiveX 的方法调出物体o的块属性并返出一个表吗？

Wildcat · 发表于 2007-9-11 15:40:42

最初由 carrot1983 发布
[B][php]
;;获取属性块中的“标记”“默认”值
;;
(defun vlex-GetAttributes (ent / blkref lst)
  (vl-load-com)
  (if (= (vla-Get-ObjectName
   (setq blkref (vlax-Ename->vla-Object ent))
   )
   "AcDb... [/B]

还有一个地方想请教，vla-GetAttributes这个函数具体是什么含义呀？查VLISP的帮助文件好像查不到这个的定义。

另外，总觉得学习vlisp要比autolisp难得多，初步的原因是因为很多vlisp的函数在控制台里返回的值总是些很不直观的东西，例如上面的(vla-GetAttributes blkref)，在控制台返回#variant 8201 ... ，不像autolisp那样返回一些“实数，整数，字串，表……），我手上也没有什么VLISP的教程，只有一本帮助手册，学起来格外费力。市面上又就不着相关的教程，如果方便的话可以提供一些相关的书籍名称给我吗？

雨箭风刀 · 发表于 2007-9-11 20:54:49

GetAttributes 要看vba里面的帮助部分，属于“方法”

Wildcat · 发表于 2007-9-11 23:53:04

最初由雨箭风刀发布
[B]GetAttributes 要看vba里面的帮助部分，属于“方法” [/B]

谢谢您，我查查VBA的帮助，再理解一下。

Free-Lancer · 发表于 2007-9-12 06:07:51

[iframe h=600 w=100%]http://www.mjtd.com/object/acad2004/idh_getattributes.htm[/iframe]

czcxxx_01 · 发表于 2015-8-4 15:54:40

hao ji le hao ji le

账号		自动登录	找回密码
密码			立即注册

[已解决] [已解决]：如果获取属性块中的“标记”“提示”“默认”值？

马上注册，结交更多好友，享用更多功能，让你轻松玩转社区。

相关帖子