[求助]：06版的pline顶点增删程序，08用不了

celticblue

在网上找到一个pline的顶点增删程序，2006版以前都可以用，2008版就弹出：“错误: no function definition:
VLAX-CURVE-GETPARAMATPOINT”
不知怎么回事，请高手帮帮忙看看，感激万分！

源码：
(defun C:PLVE (/ OS KEY)
  (SETVAR "cmdecho" 0)
  (INITGET "A E")
  (setq OS (GETVAR "osmode"))
  (setq KEY (GETKWORD "\n A-Add/<E-Erase>:"))
  (if (= KEY nil)
    (setq KEY "E")
  )
  (cond ((= "A" (STRCASE KEY))
  (APLV)
)
((= "E" (STRCASE KEY))
  (EPLV)
)
  )
  (SETVAR "osmode" OS)
)
(defun EPLV ()
  (command "osnap")
  (command "end")
  (setq PTEND (GETPOINT "\nPick a vertex:"))
  (setq ENL (NENTSELP PTEND))
  (setq ENT (CAR ENL))
  (setq ENTL (ENTGET ENT))
  (setq PTL (CONS 10 (LIST (CAR PTEND) (CADR PTEND))))
  (setq L2 (CDDDDR (MEMBER PTL ENTL)))
  (setq L1 (REVERSE (CDR (MEMBER PTL (REVERSE ENTL)))))
  (setq ENTL (APPEND L1 L2))
  (PRINT ENT)
  (PRINT ENTL)
  (ENTMOD ENTL)
)
(defun APLV ()
  (command "_.osnap")
  (command "nea")
  (setq PTNEA (GETPOINT "\nSpecify the position to add new vertex:"))
  (setq ENL (NENTSELP PTNEA))
  (setq ENT (CAR ENL))
  (setq ENTL (ENTGET ENT))
  (setq PTEND (OSNAP PTNEA "_end"))
  (setq PTCEN (OSNAP PTNEA "_cen"))
  (setq PTL (CONS 10 (LIST (CAR PTEND) (CADR PTEND))))
  (setq N0 (LENGTH ENTL))
  (setq N (LENGTH (MEMBER PTL ENTL)))
  (setq N (- N0 N))
  (setq PTNEXTL (NTH (+ N 4) ENTL))
  (setq PTNEXT (CDR PTNEXTL))
  (IF (AND (<= (vlax-curve-getParamAtPoint ENT PTNEA)
        (vlax-curve-getParamAtPoint ENT PTEND)
    )
    (NOT (AND (< (DISTANCE PTNEA PTEND) 0.0001)
       (EQUAL (VLAX-CURVE-GETENDPARAM ENT)
       (vlax-curve-getParamAtPoint ENT PTEND)
       0.0001
       )
  )
    )
      )
    (setq N (- N 4))
  )

  (setq E40 (CONS 40 0.0))
  (setq E41 (CONS 41 0.0))
  (IF (OR (AND (< (DISTANCE PTNEA PTEND) 0.0001)
    (EQUAL (VLAX-CURVE-GETSTARTPARAM ENT)
    (vlax-curve-getParamAtPoint ENT PTEND)
    0.0001
    )
          )
   (AND (< (vlax-curve-getParamAtPoint ENT PTEND)
    (vlax-curve-getParamAtPoint ENT PTNEA))
        (OSNAP PTEND "_cen")
   )
      )
    (setq E42 (CONS 42 0.0))
    (setq E42 (NTH (1- N) ENTL))
  )
  (IF (= (setq
    NPT (GETPOINT PTNEA
    "\nNew vertex <Origin picked point>:"
        )
  )
  NIL
      )
    (setq NPT PTNEA)
  )
  (setq
    NPTL (APPEND (LIST (CONS 10 (LIST (CAR NPT) (CADR NPT)))
         E40
         E41
         E42
   )
  )
  )
  (setq L1 nil)
  (setq L2 nil)
  (setq I 0)
  (FOREACH X ENTL
    (IF (>= (+ N 3) I)
      (setq L1 (CONS X L1))
      (setq L2 (CONS X L2))
    )
    (setq I (1+ I))
  )
  (setq L1 (REVERSE L1))
  (setq L2 (REVERSE L2))
  (setq ENTL (APPLY 'APPEND (LIST L1 NPTL L2)))
  (ENTMOD ENTL)
)


我很喜欢这个lisp，虽然它不是很完善，但起码能看到源码，另外找到一个好一点的，但那是vlx程序，看不到源码。

狂刀

加 (vl-load-com)

celticblue

这么快就有了回复，喜出望外！！OK了，谢谢狂刀！！谢谢！！