[LISP程序]：编程的问题求教~

bytlw

我想写一个lisp ,统计某图层上图元的数量,在写的时候遇到一个问题:看我的lisp:
(defun C:lw()
  (setq name (entsel "请选择要统计的对像:")) ;取得图元
   (setq new (car name)) ;获得图元名
  (setq namen (entget new)) ;获得图元详细信息
   (setq db (assoc 8 namen)) ;获得图层信息
  ;;(setq aa (cdr db)) ;取得图层名(无用)
  (setq p1 (getpoint "\n请输入窗口的对角点:"))
  (setq p2 (getpoint p1 ))
  (setq goc (ssget "w" p1 p2 db)) ;这句怎么写才对?db是点对格式的:(8 . "dim2")
    ;(setq goc (ssget "w" p1 p2 '((8 . "dim2")))) ;如果这样写是可以执行的,但是只能取得dim2上的图元数量
  (setq n (sslength goc))
  (print "您选择的层上的图元数量是:")
  (print n)
  (princ)
   )
在那个取ssget 里,db ,也就是读出的点对不知道用什么格式代入?总是提示参数错误.下面的那句是可以执行的,没什么问题,最后的结果也是正确的.但如果用下面那句,就只能改lisp ,指定相应层.这不是我的目的.请各位高手指点.

cy956

(setq db(list  (assoc 8 namen)))

bytlw

非常感谢非常感谢,这次成功了.另外,我想把P1P2那两个点用线框输入,要怎么写呢?

sjy2005

线框输入什么意思？

zml84

[php]

(defun C:LW (/ SS DB P1 P2 I)
    (if        (and
            ;; 1.获取图层名称
            (setq SS (entsel "\n请点取对象，以获取图层名称: "))
            (setq DB (assoc 8 (entget (car SS))))
            (princ (cdr DB))
            ;; 2.获取两个点
            (princ "\n选择对象...")
            (setq P1 (getpoint "指定第一个角点: "))
            (setq P2 (getcorner P1 "指定对角点: "))
        )
        (progn
            ;; 3.判断是否选择到指定图层上的对象
            (if        (setq SS (ssget "w" P1 P2 (list DB)))
                (setq I (sslength SS))
                (setq I 0)
            )
            ;; 4.打印显示
            (princ (strcat "**您选择的"
                           (cdr DB)
                           "图层上的图元数量是: "
                           (itoa I)
                           " 个"
                   )
            )
        )
    )
    (princ)
)
[/php]

Free-Lancer

ssget 还需要先定两点？

luowy

最初由 Free-Lancer 发布
[B]ssget 还需要先定两点？ [/B]

注意，那是ssget用了 w 开关， 为框选，因此必须指定两个点！