确定边后拉伸绘制矩形

newer

拖动矩形时候，可以输入垂边距离确定矩形大小。



[sell=5]

(defun c:XDTB_BottomRec ( / i kword p1 p2 pts w)
  (defun _kword (kword)
    (cond
      ((= kword "W")
        (if (setq w (getreal (xdrx_prompt "\n输入线宽度<" #pline_wid ">:" t)))
          (setq #pline_wid w)
        )
      )
      ((= kword "C")
        (if (setq w (getint (xdrx_prompt "\n输入颜色号<" #pline_color ">:" t)))
          (setq #pline_color w)
        )
      )
      (t
        (if (> i 0)
          (progn
            (xd::doc:command (list ".undo" 2))
            (setq i (1- i))
            (if (= i 0)
              (xdrx_prompt "\n所有回退已经完成.")
            )
          )
          (xdrx_prompt "\n所有回退已经完成.")
        )
      )
    )
  )
  (defun _prompt ()
    (xdrx_prompt "\n当前设置：线宽(" #pline_wid ") 颜色(" #pline_color ")")
    t
  )
  (xdrx_begin)
  (xdrx_sysvar_push '("osmode" 33))
  (if (not #pline_wid)
    (setq #pline_wid 1.0)
  )
  (if (not #pline_color)
    (setq #pline_color 7)
  )
  (setq i 0)
  (while (and
           (xdrx_initget (strcat "W C" (if (> i 0)
                                         " U"
                                         ""
                                       )
                         )
           )
           (_prompt)
           (setq p1 (getpoint (strcat "\n矩形第一点[线宽(W)/颜色(C)"
                                      (if (> i 0)
                                        "/回退(U)"
                                        ""
                                      ) "]<退出>:"
                              )
                    )
           )
         )
    (cond
      ((= (type p1) 'STR)
        (_kword p1)
      )
      ((= (type p1) 'LIST)
        (if (and
              (setq p2 (getpoint p1 "\n矩形底边第二点<退出>:"))
              (setq pts (XD::DRAG:RECTANG "\n矩形顶边右上点<退出>"
                                          (list p1 p2 "" 0)
                        )
              )
            )
          (progn
            (vla-startundomark **XD::Doc**)
            (setq i (1+ i))
            (xdrx_setpropertyvalue (entlast) "constantwidth" #pline_wid
                                   "color" #pline_color
            )
            (vla-endundomark **XD::Doc**)
          )
        )
      )
    )
  )
  (xdrx_sysvar_pop)
  (xdrx_end)
  (princ)
)

[/sell]

alliuyx

非常方便的使用。

liuyj

没试出这种效果，XD::DRAG:RECTANG的参数也有点问题(list p1 p2 "" 0)的右侧括号应该在p2后面

376394482

非常好的东西

longer1000

啥也不说了，感谢楼主分享哇！

newer

liuyj 发表于 2016-11-10 11:46

你用的是最新的通用LISP函数库吗？

用下这个替换

(defun XD::Drag:Rectang (info pts / an dynpt en flag index
                              ins ll newpoint  per pl pnt v v0
                              
                        )
  (defun RecCallback1 (dynpt /)
    (setq ins (car (xd::pnts:orthoproject (list dynpt) p1 p2)))
    (setq vec (mapcar
                '-
                dynpt
                ins
              )
    )
    (if (not lastPnts)
      (setq lastPnts (cons dynpt lastPnts))
      (setq lastPnts (list dynpt (car lastPnts)))
    )
    (xdrx_polyline_setpointat en 2 (setq ret (mapcar
                                     '+
                                     p2
                                     vec
                                   ))
    )
    (xdrx_polyline_setpointat en 3 (mapcar
                                     '+
                                     p1
                                     vec
                                   )
    )
    (setq ret (trans ret 0 1))
    ret
  )
  (defun RecCallback2 (dynpt /)
    (setq p3 dynpt
          p2 (mapcar '+ p1 xdir)
          p2 (car (xd::pnts:orthoproject (list p3) p1 p2))
          p4 (car (xd::pnts:orthoproject (list p3) p1 (mapcar '+ p1 ydir)))
    )
    (if (not lastPnts)
      (setq lastPnts (cons dynpt lastPnts))
      (setq lastPnts (list dynpt (car lastPnts)))
    )
    (xdrx_polyline_setpointat en 1 p2)
    (xdrx_polyline_setpointat en 2 dynpt)
    (xdrx_polyline_setpointat en 3 p4)
    dynpt
  )        
  (defun myerr(msg)
     (princ (strcat "\n" msg))
     (setq *error* myerr)
     (xdrx_end)
     (XD::Doc:Command (list ".undo" 1))
  )
  (setq olderr *error*)
  (setq *error* myerr)
  (xdrx_begin)                               
  (setq p1 (car pts)
        p2 (cadr pts)
        flag 0
  )                                       ; the center of five-star
  (setq p1 (trans p1 1 0))
  (if p2
    (setq p2 (trans p2 1 0))
  )
  (setq xdir(getvar "ucsxdir")
        ydir (getvar "ucsydir")
  )
  (setvar "lastPoint" (trans p1 0 1))
  (if (not p2)
    (progn
      (setq ll (list p1 p1 p1 p1))
    )
    (progn
      (setq flag 1)
      (setq ll (list p1 p2 p2 p1))
      (setq v0 (mapcar
                 '-
                 p2
                 p1
               )
      )
      (setq an (angle p1 p2)) ; |start to drag it
    )
  )
  (initget 0)
  (setq en (apply
             'xdrx_polyline_make
             (cons T ll)
           )
  )
  (xdrx_pointmonitor (if (= flag 1)
                             "RecCallback1"
                             "RecCallback2"
                           )
  )
  (setq p3 (getpoint info))
  (xdrx_pointmonitor)
  (cond
    ((= (type p3) 'STR)
      (entdel e)
    )
    ((= (type ret) 'LIST)
      (if (not (equal (car lastpnts) (last lastpnts) 30))
        (progn
          (if (cadr pts)
            (progn
              (setq dis (distance (car lastpnts) p1)
                    vec (xdrx_vector_product (xdrx_vector_normalize vec) dis)
                    p3 (mapcar '+ p2 vec)
                    p4 (mapcar '+ p1 vec)
              )
              (xdrx_polyline_setpointat en 2 p3)
              (xdrx_polyline_setpointat en 3 p4)
              (setq p3 (trans p3 0 1))
            )
          )
        )
      )
    )
  )
  (setq *error* olderr)
  (xdrx_end)
  p3
)

yoyoho

正需要，支持N版大人了！

yoyoho

N版 (点击图片可以放大) 看不到啊!

liuyj

newer 发表于 2016-11-10 14:44

我说呢，我搜到的源码还是lispboy的，函数名一样，结果没反应

newer

liuyj 发表于 2016-11-10 15:31

确保加载最新的通用LISP函数库就可以了。

yanchao316

确实是难得好帖啊，顶先

ck1569

不错，很实用的工具，谢谢楼主分享！

kqqt6236

这是那个行业的？