[其他]：SSGET在选择时会将锁定图层选择在内

eachy

[php]
;|

(ssget [sel-method] [pt1 [pt2]] [pt-list] [filter-list])

在使用 SSGET 的过程中发现在含有 Lock 的图层时，只有 CAD 命令可以过滤掉 Lock 图层实体，
Seclect 命令和 SSGET 是不能过滤 Lock 图层的，这样在程序中循环将浪费掉大量的时间，因此
写了这个函数简单情况下替代标准的 Ssget。

参数： Msg  ----  提示字串
       mode ----  同 ssget 的 method, 没有提供 pt 选项，够用就行
       filter --- 过滤表


|;
(defun ea:ssget        (Msg mode filter / ea:getlocklyr locklyr)
  (defun ea:getlocklyr (/ d r);检索锁定图层
    (setq r "")
    (while (setq d (tblnext "layer" (null d)))
      (if (= (cdr (assoc 70 d)) 4)
        (setq r (strcat (cdr (assoc 2 d)) "," r))
      )
    )
    (if        (/= r "")
      (vl-string-trim "," r);还是 2000+ 以上版本方便
      nil
    )
  )
  (setq locklyr (ea:getlocklyr));锁定图层字串
  (if locklyr
    (if        filter
      (setq
        filter (append
                 filter
                 (list '(-4 . "<not") (cons 8 locklyr) '(-4 . "not>"))
               )
      )
      (setq
        filter (list '(-4 . "<not") (cons 8 locklyr) '(-4 . "not>"))
      )
    )
  );构造图层过滤表，ssget 中即使前面有锁定的图层 not 仍旧会起作用
  (if msg
    (princ msg)
  );提示串
  (cond
    ((and mode filter)
     (ssget mode filter);有 mode
    )
    (filter
     (ssget filter);含有过滤表
    )
    (t (ssget));其它情况用标准 ssget
  )
)[/php]

nuance

2000+可以（ssget ":L")

eachy

最初由 nuance 发布
[B]2000+可以（ssget ":L") [/B]

谢谢，上面的白写了

陌生人

我觉得2贴也应该加分：）

lsjjm

最初由 eachy 发布
SSGET在选择时会将冻结图层选择在内... [/B]

题目是否有误, "冻结"?

eachy

最初由 lsjjm 发布
[B]

题目是否有误, "冻结"? [/B]

写错了，是锁定：）

陌生人

就程序本身,增加的filter还可以这样写，注意 str 为"" 或"a,b,"在加了逻辑not之后不影响效果，因此可以省去一些步骤。
[php]
(setq str "" )
(vlax-for obj (vla-get-layers (vla-get-activeDocument (vlax-get-acad-object)))
  ;;此处也可如ea斑竹一样用table
  (if (= (vla-get-lock obj) :vlax-TRUE) (setq str (strcat str (vla-get-name obj) ",")))
)
(setq filter2 (list '(-4 . "< NOT")(cons 8 str)'(-4 . "NOT >"))))
[/php]

LUCAS

eachy兄:
把以前的貼子給忘了!
http://www.xdcad.net/forum/showt ... d=380504#post380504

eachy

最初由 LUCAS 发布
[B]eachy兄:
把以前的貼子給忘了!
http://www.xdcad.net/forum/showt ... d=380504#post380504 [/B]

唉，前几天出差在外，不能上网才临时写的

陌生人

哈哈，我也常常会重复写已经写过的程序：）

aeo

龙龙仔贴了半年都不止了!

aeo

最初由 aeo 发布
[B]龙龙仔贴了半年都不止了! [/B]

总结一下:
[php]
A All
B Box
C Crossing
CP Crossing Polygon
:D Duplicates OK
:E Everything in aperture
F Fence
G Groups
I Implied
L Last
:L Rejects locked layers
M Multiple
:N Nested
P Previous
:P Rejects Viewport
:S Force single object selection only
W Window
WP Window Polygon
X Extended search (search whole database)
[/php]

从来没谁给我加分:)