[求助]：大侠高手们帮我看看这个程序

lvsuccess

我是一个学习AUTOLISP的新手，有一个程序（关于反应器的），说能根据直线的变化来调整两个圆的直径使之和永远等于直线的长度。
可是我试了一下觉得不对，只有一个圆会动。
大家帮我看看！！
先谢过了！！
附件里的是ＬＩＳＰ程序。

(VL-Load-Com)
(defun c:special-l( )
(setq pt1 (GetPoint " \ n 直线起点:")
   pt2 (GetPoint pt1 " \ n 直线末点:")
)
;;绘制直线及圆并获取圆的实体名
(Command "line" pt1 pt2 "")
(setq len (Entlast))
(Command "circle" pt2 (/ (Distance pt1 pt2) 2))
(setq chl ( Cdr (Assoc 5 (EntGet (Entlast)))))
(Command "circle" pt1 ( / (Distance pt1 pt2) 2))
(setq chl
(list chl
    (Cdr (Assoc 5 (EntGet (EntLast))))
    ));;                      将两圆的实体名组成一个表
(setq rlt (Cons;;    将直线的图元名转换成VLA图表对象表
      (VLAX-EName->VLA-Object len)'( ))
)
(setq vrl
      (VLR-Pers(VLR-Object-Reactor rlt chl'((:vlr-modified . Line-Circle))))
)
(PrinC)
)
(defun Line-Circle (notifier-object reactor-object parameter-list)
;;获取两个圆的图元句柄
(setq cen1 (HandEnt (Car (VLR-Data reactor-object)))
   cen2 (HandEnt (Cadr (VLR-Data reactor-object)))
)
;;获取直线的两个端点坐标
(setq len (VLAX-VLA-Object->EName notifier-Object)
   lel (EntGet len)
      pt1 (Cdr (Assoc 10 lel))  
      pt2 (Cdr (Assoc 11 lel))
)
;;修改末端点处圆的圆心坐标及半径
(setq cel1 (EntGet cen1)
          cell (Subst (Vl-List* 10 pt2) (Assoc 10 cel1) cel1)
          cell (Subst (Vl-List* 40(/( Distance pt1 pt2) 2))
              (Assoc 40 cel1) cel1)
)
(EntMod cel1)         ;;使修改生效
  ;;修改起始端点处圆的圆心坐标及半径
(setq cel2 (EntGet cen2)
      cel2(Subst(VL-List* 10 pt1) (Assoc 10 cel2) cel2)
      cel2 (Subst (VL-List* 40(/( Distance pt1 pt2) 2))
      (Assoc 40 cel2) cel2)
)
     (EntMod cel2);;使修改生效
)

ljpnb

[php]

(VL-Load-Com)
(defun c:special-l ()
  (setq        pt1 (GetPoint " \ n 直线起点:")
        pt2 (GetPoint pt1 " \ n 直线末点:")
  )
  ;;绘制直线及圆并获取圆的实体名
  (Command "line" pt1 pt2 "")
  (setq len (Entlast))
  (Command "circle" pt2 (/ (Distance pt1 pt2) 2))
  (setq chl (Cdr (Assoc 5 (EntGet (Entlast)))))
  (Command "circle" pt1 (/ (Distance pt1 pt2) 2))
  (setq        chl
         (list chl
               (Cdr (Assoc 5 (EntGet (EntLast))))
         )
  )
  ;; 将两圆的实体名组成一个表
  (setq        rlt (Cons ;; 将直线的图元名转换成VLA图表对象表
                  (VLAX-EName->VLA-Object len)
                  '()
            )
  )
  (setq        vrl
         (VLR-Pers (VLR-Object-Reactor
                     rlt
                     chl
                     '((:vlr-modified . Line-Circle))
                   )
         )
  )
  (PrinC)
)



(defun Line-Circle (notifier-object reactor-object parameter-list)
  ;;获取两个圆的图元句柄
  (setq        cen1 (HandEnt (Car (VLR-Data reactor-object)))
        cen2 (HandEnt (Cadr (VLR-Data reactor-object)))
  )
  ;;获取直线的两个端点坐标
  (setq        len (VLAX-VLA-Object->EName notifier-Object)
        lel (EntGet len)
        pt1 (Cdr (Assoc 10 lel))
        pt2 (Cdr (Assoc 11 lel))
  )
  ;;修改末端点处圆的圆心坐标及半径
  (setq        cel1 (EntGet cen1)
        cel1 (Subst (Vl-List* 10 pt2) (Assoc 10 cel1) cel1);_这句变量cel1笔误
        cel1 (Subst (Vl-List* 40 (/ (Distance pt1 pt2) 2));_这句变量cel1笔误
                    (Assoc 40 cel1)
                    cel1
             )
  )
  (EntMod cel1)
  ;;使修改生效
  ;;修改起始端点处圆的圆心坐标及半径
  (setq        cel2 (EntGet cen2)
        cel2 (Subst (VL-List* 10 pt1) (Assoc 10 cel2) cel2)
        cel2 (Subst (VL-List* 40 (/ (Distance pt1 pt2) 2))
                    (Assoc 40 cel2)
                    cel2
             )
  )
  (EntMod cel2)
  ;;使修改生效
)[/php]

lvsuccess

有什么区别吗？
您用红色标出的区域仅仅是格式的问题？
我看了半天……

ljpnb

那你有没有试过呢，试过有问题再问，当中我不是注明了cel1笔误。。。。。

ma1508

向人请教还要收爱心币 穷疯了？！

lvsuccess

cel1笔误？？
我用过了，没有问题。
我想问的是：我哪里错了？
另外cel1笔误没有在楼主的帖子里找到。
还有，我没有收爱心币，只是一个LISP的文件。


谢谢，问题解决CEL1笔误！！