[讨论]：[0215]三点求逆时针角度

xyz518mm

[讨论]：[0215]三点求逆时针角度

写了一个三点求逆时针方向角度
想请讨论一下是否有更方便的计算方法

附上图片及程序

(DEFUN CCW_ANG ( p1 p2 p3 / A B )
(setq A (RTOD (ANGLE P2 P1)))
(setq B (RTOD (ANGLE P2 P3)))
(COND
((AND (> A 180)
      (> A B)
      (< B 180))
(SETQ ANG (+ B (- 360 A) ))
)

((AND (< A 180)
      (< A B)
      (> B 180))
(SETQ ANG (+ (- B 180) (- 180 A) ))
)
((AND (> A 180)
      (> A B)
      (> B 180))
(SETQ ANG (+ B (- 360 A) ))
)
((AND (< A 180)
      (< A B)
      (< B 180))
(SETQ ANG (- B A))
)   
((AND (< A 180)
      (> A B)
      (< B 180))
(SETQ ANG (- A B))
)
((AND (> A 180)
      (< A B)
      (> B 180))
(SETQ ANG (- B A))
)

(T NIL)
)
ANG
)

测试:
(setq p1 (getpoint "\n起点:"))
(setq p2 (getpoint "\n中点:"))
(setq p3 (getpoint "\n终点:"))
(PRINT (CCW_ANG p1 p2 p3))

如:
由点 B R C 则返回 角度100
由点 C R B 则返回 角度260

                               
登录/注册后可看大图

zml84

RTOD 这个函数是楼主自创的吧？
<br><br>
根据楼主的要求，请试一试下面这个：
[PHP]
;;;=====================================================
;;函数定义
(defun ccw_ang (pt1 pt2 pt3 / a b ang)
    (setq a (angle Pt2 Pt1)
          b (angle Pt2 Pt3)
    )
    (if        (< b a)
        (setq ang (- (+ b pi pi) a))
        (setq ang (- b a))
    )
)


;;;=====================================================
;;测试
(defun c:tt ()
    (if        (setq pt1 (getpoint "\n第一点:"))
        (if (setq pt2 (getpoint pt1 "\n第二点:"))
            (if        (setq pt3 (getpoint pt2 "\n第三点:"))
                (progn
                    (setq j (angtos (ccw_ang pt1 pt2 pt3) 0 4))
                    (princ j)
                )
            )
        )
    )
    (princ)
)
;;;=====================================================
[/PHP]