在grread状态下实现捕捉功能并显示标记符号

fools · 发表于 2007-3-3 14:00:15

马上注册，结交更多好友，享用更多功能，让你轻松玩转社区。

您需要登录才可以下载或查看，没有账号？立即注册

×

TheSwamp.org上的联接:
http://www.theswamp.org/index.php?topic=12797.0

调用grread获取原始点,然后通过osnap函数捕捉准确点,并调用grvecs画出自动捕捉记号
我为了能发表在TheSwamp.org,所以很多说明是用英文写的,请大家见谅.
CAB的原代码只写了grread+osnap,判断及加入绘制捕捉记号的部分是我添加上的

(DEFUN c:tmp (/ AUTOSNAPMARKERCOLOR AUTOSNAPMARKERSIZE DRAG GHOSTPT LST_OSMODE STR_OSMODE TIME DistPerPixel Bold Draftobj
get_osmode YPY_StrParse YPY_GetGrvecs YPY_DrawVecs
) ; CAB 10/5/2006
; Fools change a little about "," (3/3/2007)
;
; Function to return the current osmode setting in the form of a string
; If (getvar "osmode") = 175
; (get_osmode) returns "_end,_mid,_cen,_nod,_int,_per"
(DEFUN get_osmode (/ cur_mode mode$)
(SETQ mode$ "")
(IF (< 0 (SETQ cur_mode (GETVAR "osmode"))
16383
)
(MAPCAR
(FUNCTION (LAMBDA (x)
(IF (NOT (ZEROP (LOGAND cur_mode (CAR x))))
(IF (ZEROP (STRLEN mode$))
(SETQ mode$ (CADR x))
(SETQ mode$ (STRCAT mode$ "," (CADR x)))
)
)
)
)
'((1 "_end") (2 "_mid")
(4 "_cen")
(8 "_nod")
(16 "_qua")
(32 "_int")
(64 "_ins")
(128 "_per")
(256 "_tan")
(512 "_nea")
(1024 "_qui")
(2048 "_app")
(4096 "_ext")
(8192 "_par")
)
)
)
mode$
) ; My functions
(DEFUN YPY_StrParse (str delim / ptr lst)
(WHILE (SETQ ptr (VL-STRING-SEARCH delim str))
(SETQ lst (CONS (SUBSTR str 1 ptr) lst))
(SETQ str (SUBSTR str (+ ptr 2)))
)
(REVERSE (CONS str lst))
)
(DEFUN YPY_GetGrvecs (pt dragpt lst / KEY)
(SETQ key T)
(WHILE (AND
key
lst
)
(IF (EQUAL (OSNAP dragpt (CAR lst)) pt 1E-6)
(SETQ key nil)
(SETQ lst (CDR lst))
)
)
(CDR (ASSOC (CAR lst) '(("_end" ((-1 1) (-1 -1))
((-1 -1) (1 -1))
((1 -1) (1 1))
((1 1) (-1 1))
) ; square
("_mid" ((0 1.414) (-1.225 -0.707))
((-1.225 -0.707) (1.225 -0.707))
((1.225 -0.707) (0 1.414))
) ; triangle
("_cen" ((0 1) (-0.707 0.707))
((-0.707 0.707) (-1 0))
((-1 0) (-0.707 -0.707))
((-0.707 -0.707) (0 -1))
((0 -1) (0.707 -0.707))
((0.707 -0.707) (1 0))
((1 0) (0.707 0.707))
((0.707 0.707) (0 1))
) ; circle
("_nod" ((0 1) (-0.707 0.707))
((-0.707 0.707) (-1 0))
((-1 0) (-0.707 -0.707))
((-0.707 -0.707) (0 -1))
((0 -1) (0.707 -0.707))
((0.707 -0.707) (1 0))
((1 0) (0.707 0.707))
((0.707 0.707) (0 1))
((-1 1) (1 -1))
((-1 -1) (1 1))
) ; circle+cross
("_qua" ((0 1.414) (-1.414 0))
((-1.414 0) (0 -1.414))
((0 -1.414) (1.414 0))
((1.414 0) (0 1.414))
) ; square rotate 45
("_int" ((-1 1) (1 -1))
((-1 -1) (1 1))
((1 0.859) (-0.859 -1))
((-1 0.859) (0.859 -1))
((0.859 1) (-1 -0.859))
((-0.859 1) (1 -0.859))
) ; cross
("_ins" ((-1 1) (-1 -0.1))
((-1 -0.1) (0 -0.1))
((0 -0.1) (0 -1.0))
((0 -1.0) (1 -1))
((1 -1) (1 0.1))
((1 0.1) (0 0.1))
((0 0.1) (0 1.0))
((0 1.0) (-1 1))
) ; two squares
("_per" ((-1 1) (-1 -1))
((-1 -1) (1 -1))
((0 -1) (0 0))
((0 0) (-1 0))
) ; half square
("_tan" ((0 1) (-0.707 0.707))
((-0.707 0.707) (-1 0))
((-1 0) (-0.707 -0.707))
((-0.707 -0.707) (0 -1))
((0 -1) (0.707 -0.707))
((0.707 -0.707) (1 0))
((1 0) (0.707 0.707))
((0.707 0.707) (0 1))
((1 1) (-1 1))
) ; circle+line
("_nea" ((-1 1) (1 -1))
((1 -1) (-1 -1))
((-1 -1) (1 1))
((1 1) (-1 1))
) ; two triangle
("_qui") ; ???
("_app" ((-1 1) (-1 -1))
((-1 -1) (1 -1))
((1 -1) (1 1))
((1 1) (-1 1))
((-1 1) (1 -1))
((-1 -1) (1 1))
) ; square+cross
("_ext" ((0.1 0) (0.13 0))
((0.2 0) (0.23 0))
((0.3 0) (0.33 0))
) ; three points
("_par" ((0 1) (-1 -1))
((1 1) (0 -1))
) ; two lines
)
)
)
) ; Use GRVECS
(DEFUN YPY_DrawVecs (Pt Vecs Size Color / lst matrix) ; no Z axis
(SETQ matrix (LIST (LIST Size 0.0 0.0 (CAR pt)) (LIST 0.0 Size 0.0 (CADR pt)) (LIST 0.0 0.0 1.0 0.0) (LIST 0.0 0.0
0.0 1.0
)
)
)
(SETQ lst (MAPCAR
'CONS
(MAPCAR
(FUNCTION (LAMBDA (x)
Color
)
)
Vecs
)
Vecs
)
)
(GRVECS (APPLY
'APPEND
lst
) matrix
)
) ; ****************************
; Main Routine starts here
; ****************************
(VL-LOAD-COM)
(SETQ time T)
(SETQ str_osmode (get_osmode))
(SETQ lst_osmode (YPY_StrParse str_osmode ","))
(SETQ Draftobj (VLA-GET-DRAFTING (VLA-GET-PREFERENCES (VLAX-GET-ACAD-OBJECT))))
(SETQ AutoSnapMarkerSize (VLA-GET-AUTOSNAPMARKERSIZE Draftobj))
(SETQ AutoSnapMarkerColor (VLA-GET-AUTOSNAPMARKERCOLOR Draftobj))
(WHILE time
(grread (SETQ drag (GRREAD T 1 1))) ; Can change like (grread T 15 2)
(COND
((= (CAR drag) 5)
(REDRAW)
(SETQ drag (CADR drag))
(IF (or
(zerop (strlen str_osmode))
(NULL (SETQ ghostpt (OSNAP drag str_osmode)))
)
(SETQ ghostpt drag) ; Beacuse of mouse middle button scroll , calculate "DistPerPixel" every time
(PROGN
(SETQ DistPerPixel (/ (GETVAR "VIEWSIZE") (CADR (GETVAR "SCREENSIZE")))) ; Bold
(SETQ Bold (MAPCAR
'*
(LIST DistPerPixel DistPerPixel DistPerPixel)
(LIST (+ AutoSnapMarkerSize 0.5) AutoSnapMarkerSize (- AutoSnapMarkerSize 0.5))
)
)
(FOREACH item Bold
(YPY_DrawVecs ghostpt (YPY_GetGrvecs ghostpt drag lst_osmode) item AutoSnapMarkerColor)
)
)
)
)
((= (CAR drag) 3)
(IF (NULL (SETQ ghostpt (OSNAP (CADR drag) (get_osmode))))
(SETQ ghostpt (CADR drag))
)
(REDRAW)
(SETQ time nil)
)
)
)
(PRINC) ; can return ghostpt if want
)

(DEFUN c:tmp (/ AUTOSNAPMARKERCOLOR AUTOSNAPMARKERSIZE DRAG GHOSTPT LST_OSMODE STR_OSMODE TIME DistPerPixel Bold Draftobj 
                get_osmode YPY_StrParse YPY_GetGrvecs YPY_DrawVecs 
             )                               ;  CAB  10/5/2006 
                                       ;  Fools change a little about ","  (3/3/2007) 
                                       ; 
                                       ;  Function to return the current osmode setting in the form of a string 
                                       ;  If (getvar "osmode") = 175 
                                       ;  (get_osmode)  returns   "_end,_mid,_cen,_nod,_int,_per" 
  (DEFUN get_osmode (/ cur_mode mode$) 
    (SETQ mode$ "") 
    (IF (< 0 (SETQ cur_mode (GETVAR "osmode")) 
           16383 
        ) 
      (MAPCAR 
        (FUNCTION (LAMBDA (x) 
                    (IF (NOT (ZEROP (LOGAND cur_mode (CAR x)))) 
                      (IF (ZEROP (STRLEN mode$)) 
                        (SETQ mode$ (CADR x)) 
                        (SETQ mode$ (STRCAT mode$ "," (CADR x))) 
                      ) 
                    ) 
                  ) 
        ) 
        '((1 "_end") (2 "_mid") 
         (4 "_cen") 
         (8 "_nod") 
         (16 "_qua") 
         (32 "_int") 
         (64 "_ins") 
         (128 "_per") 
         (256 "_tan") 
         (512 "_nea") 
         (1024 "_qui") 
         (2048 "_app") 
         (4096 "_ext") 
         (8192 "_par") 
        ) 
      ) 
    ) 
    mode$ 
  )                                       ; My functions 
  (DEFUN YPY_StrParse (str delim / ptr lst) 
    (WHILE (SETQ ptr (VL-STRING-SEARCH delim str)) 
      (SETQ lst (CONS (SUBSTR str 1 ptr) lst)) 
      (SETQ str (SUBSTR str (+ ptr 2))) 
    ) 
    (REVERSE (CONS str lst)) 
  ) 
  (DEFUN YPY_GetGrvecs (pt dragpt lst / KEY) 
    (SETQ key T) 
    (WHILE (AND 
             key 
             lst 
           ) 
      (IF (EQUAL (OSNAP dragpt (CAR lst)) pt 1E-6) 
        (SETQ key nil) 
        (SETQ lst (CDR lst)) 
      ) 
    ) 
    (CDR (ASSOC (CAR lst) '(("_end" ((-1 1) (-1 -1)) 
                  ((-1 -1) (1 -1)) 
                  ((1 -1) (1 1)) 
                  ((1 1) (-1 1)) 
                 )                       ; square 
                 ("_mid" ((0 1.414) (-1.225 -0.707)) 
                  ((-1.225 -0.707) (1.225 -0.707)) 
                  ((1.225 -0.707) (0 1.414)) 
                 )                       ; triangle 
                 ("_cen" ((0 1) (-0.707 0.707)) 
                  ((-0.707 0.707) (-1 0)) 
                  ((-1 0) (-0.707 -0.707)) 
                  ((-0.707 -0.707) (0 -1)) 
                  ((0 -1) (0.707 -0.707)) 
                  ((0.707 -0.707) (1 0)) 
                  ((1 0) (0.707 0.707)) 
                  ((0.707 0.707) (0 1)) 
                 )                       ; circle 
                 ("_nod" ((0 1) (-0.707 0.707)) 
                  ((-0.707 0.707) (-1 0)) 
                  ((-1 0) (-0.707 -0.707)) 
                  ((-0.707 -0.707) (0 -1)) 
                  ((0 -1) (0.707 -0.707)) 
                  ((0.707 -0.707) (1 0)) 
                  ((1 0) (0.707 0.707)) 
                  ((0.707 0.707) (0 1)) 
                  ((-1 1) (1 -1)) 
                  ((-1 -1) (1 1)) 
                 )                       ; circle+cross 
                 ("_qua" ((0 1.414) (-1.414 0)) 
                  ((-1.414 0) (0 -1.414)) 
                  ((0 -1.414) (1.414 0)) 
                  ((1.414 0) (0 1.414)) 
                 )                       ; square rotate 45 
                 ("_int" ((-1 1) (1 -1)) 
                  ((-1 -1) (1 1)) 
                  ((1 0.859) (-0.859 -1)) 
                  ((-1 0.859) (0.859 -1)) 
                  ((0.859 1) (-1 -0.859)) 
                  ((-0.859 1) (1 -0.859)) 
                 )                       ; cross 
                 ("_ins" ((-1 1) (-1 -0.1)) 
                  ((-1 -0.1) (0 -0.1)) 
                  ((0 -0.1) (0 -1.0)) 
                  ((0 -1.0) (1 -1)) 
                  ((1 -1) (1 0.1)) 
                  ((1 0.1) (0 0.1)) 
                  ((0 0.1) (0 1.0)) 
                  ((0 1.0) (-1 1)) 
                 )                       ; two squares 
                 ("_per" ((-1 1) (-1 -1)) 
                  ((-1 -1) (1 -1)) 
                  ((0 -1) (0 0)) 
                  ((0 0) (-1 0)) 
                 )                       ; half square 
                 ("_tan" ((0 1) (-0.707 0.707)) 
                  ((-0.707 0.707) (-1 0)) 
                  ((-1 0) (-0.707 -0.707)) 
                  ((-0.707 -0.707) (0 -1)) 
                  ((0 -1) (0.707 -0.707)) 
                  ((0.707 -0.707) (1 0)) 
                  ((1 0) (0.707 0.707)) 
                  ((0.707 0.707) (0 1)) 
                  ((1 1) (-1 1)) 
                 )                       ; circle+line 
                 ("_nea" ((-1 1) (1 -1)) 
                  ((1 -1) (-1 -1)) 
                  ((-1 -1) (1 1)) 
                  ((1 1) (-1 1)) 
                 )                       ; two triangle 
                 ("_qui")               ; ??? 
                 ("_app" ((-1 1) (-1 -1)) 
                  ((-1 -1) (1 -1)) 
                  ((1 -1) (1 1)) 
                  ((1 1) (-1 1)) 
                  ((-1 1) (1 -1)) 
                  ((-1 -1) (1 1)) 
                 )                       ; square+cross 
                 ("_ext" ((0.1 0) (0.13 0)) 
                  ((0.2 0) (0.23 0)) 
                  ((0.3 0) (0.33 0)) 
                 )                       ; three points 
                 ("_par" ((0 1) (-1 -1)) 
                  ((1 1) (0 -1)) 
                 )                       ; two lines 
                ) 
         ) 
    ) 
  )                                       ; Use GRVECS 
  (DEFUN YPY_DrawVecs (Pt Vecs Size Color / lst matrix)        ; no Z axis 
    (SETQ matrix (LIST (LIST Size 0.0 0.0 (CAR pt)) (LIST 0.0 Size 0.0 (CADR pt)) (LIST 0.0 0.0 1.0 0.0) (LIST 0.0 0.0 
                                                                                                               0.0 1.0 
                                                                                                         ) 
                 ) 
    ) 
    (SETQ lst (MAPCAR 
                'CONS 
                (MAPCAR 
                  (FUNCTION (LAMBDA (x) 
                              Color 
                            ) 
                  ) 
                  Vecs 
                ) 
                Vecs 
              ) 
    ) 
    (GRVECS (APPLY 
              'APPEND 
              lst 
            ) matrix 
    ) 
  )                                       ; **************************** 
                                       ;  Main Routine starts here 
                                       ; **************************** 
  (VL-LOAD-COM) 
  (SETQ time T) 
  (SETQ str_osmode (get_osmode)) 
  (SETQ lst_osmode (YPY_StrParse str_osmode ",")) 
  (SETQ Draftobj (VLA-GET-DRAFTING (VLA-GET-PREFERENCES (VLAX-GET-ACAD-OBJECT)))) 
  (SETQ AutoSnapMarkerSize (VLA-GET-AUTOSNAPMARKERSIZE Draftobj)) 
  (SETQ AutoSnapMarkerColor (VLA-GET-AUTOSNAPMARKERCOLOR Draftobj)) 
  (WHILE time 
    (grread (SETQ drag (GRREAD T 1 1)))        ; Can change like (grread T 15 2) 
    (COND 
      ((= (CAR drag) 5) 
        (REDRAW) 
        (SETQ drag (CADR drag)) 
        (IF (or 
              (zerop (strlen str_osmode)) 
              (NULL (SETQ ghostpt (OSNAP drag str_osmode))) 
            ) 
          (SETQ ghostpt drag)               ; Beacuse of mouse middle button scroll , calculate "DistPerPixel" every time 
          (PROGN 
            (SETQ DistPerPixel (/ (GETVAR "VIEWSIZE") (CADR (GETVAR "SCREENSIZE")))) ; Bold 
            (SETQ Bold (MAPCAR 
                         '* 
                         (LIST DistPerPixel DistPerPixel DistPerPixel) 
                         (LIST (+ AutoSnapMarkerSize 0.5) AutoSnapMarkerSize (- AutoSnapMarkerSize 0.5)) 
                       ) 
            ) 
            (FOREACH item Bold 
              (YPY_DrawVecs ghostpt (YPY_GetGrvecs ghostpt drag lst_osmode) item AutoSnapMarkerColor) 
            ) 
          ) 
        ) 
      ) 
      ((= (CAR drag) 3) 
        (IF (NULL (SETQ ghostpt (OSNAP (CADR drag) (get_osmode)))) 
          (SETQ ghostpt (CADR drag)) 
        ) 
        (REDRAW) 
        (SETQ time nil) 
      ) 
    ) 
  ) 
  (PRINC)                               ; can return ghostpt if want 
)

zml84 · 发表于 2007-3-3 16:28:54

楼主：测试时发现，当关闭捕捉时运行会出错。
增加一个条件选择即可解决问题。修改部分如下所示：
[PHP]
(WHILE time
(GRREAD (SETQ drag (GRREAD T 1 1)))
(COND
      ((= (CAR drag) 5)
      (REDRAW)
      (SETQ drag (CADR drag))
      (IF (OR (= 0 (GETVAR "osmode"))
      (> (GETVAR "osmode") 15359)
   )
   (SETQ ghostpt drag)
   (IF (NULL (SETQ ghostpt (OSNAP drag str_osmode)))
      (SETQ ghostpt drag)
      (FOREACH item Bold
   (YPY_DrawVecs
      ghostpt
      (YPY_GetGrvecs ghostpt drag lst_osmode)
      item
      AutoSnapMarkerColor
   )
      )
   )
      )
      )
      ((= (CAR drag) 3)
      (IF (NULL (SETQ ghostpt (OSNAP (CADR drag) (get_osmode))))
   (SETQ ghostpt (CADR drag))
      )
      (REDRAW)
      (SETQ time nil)
      )
)
)
[/PHP]
另："AutoSnap Marker Size"和"AutoSnap marker color"可以通过(vlax-get-acad-object)函数得到模型树，并进一步分析之得到。

fools · 发表于 2007-3-3 19:34:50

多谢zml84!
有关的"AutoSnap Marker Size"和"AutoSnap marker color"获取,首贴已经更新!
另外更新了DistPerPixel获取,主要是避免中键缩放的影响.
你提到的取消捕捉发生错误,是因为我以为(osnap pt "")将返回nil,结果不是,而是一个点,加入判断str_osmode是否为""即可,首贴已更新.
[php]
(IF (or (zerop (strlen str_osmode)) (NULL (SETQ ghostpt (OSNAP drag str_osmode))))
(SETQ ghostpt drag)
(PROGN ... )
)
[/php]
如果觉得捕捉时显示十字光标不好看可以改变grread的参数,以实现
不显示十字光标或显示为对象选择光标,甚至可以另画一个光标,:)
例如将(grread (SETQ drag (GRREAD T 1 1)))改为(GRREAD T 15 2)

程序还有许多不足之处,请大家多提宝贵意见.

小菜 · 发表于 2007-3-4 13:55:45

有创意，要是能实现极轴追踪就更牛了

aeo · 发表于 2007-3-4 15:53:00

费这么大劲，还不如arx,我反正是arx了。
其实arx里捕捉显示的原理也是这样的.

考虑东西还有很多
比如极轴对象追踪磁吸中间打入另一个捕捉输入距离透明命令等等

而且要把函数包装起来，不然每次要用，都要拷贝这么多的代码，不是很好.

fools · 发表于 2007-3-4 22:18:11

获取AutoSnapMarker 颜色和尺寸,也可以用下面这种方法
(getenv "AutoSnapColor")
(getenv "AutoSnapSize")

aeo · 发表于 2007-3-8 22:29:27

自动捕捉磁吸问题

;;;点p在自动捕捉点posmode磁吸范围内?
;;;((= (CAR drag) 5)时, NIL用p进行计算 ,T用posmode
(defun In_AutoSnapBox(p posmode)
(and (= 4(logand(getvar "autosnap")4))
(> (* (atoi(getenv "AutoSnapSize")) 1.414
(/ (GETVAR "VIEWSIZE") (CADR (GETVAR "SCREENSIZE"))))
(distance p posmode)
)
)
)

还是lisp简约!

aeo · 发表于 2007-3-9 00:40:17

极轴写好了，
大家努力:)

极轴的信息在
HKEY_CURRENT_USER\Software\Autodesk\AutoCAD\R17.0\ACAD-5001:804\FixedProfile\Editor Configuration

Dream.Fei · 发表于 2007-4-18 00:20:00

在CAD2007中无法运行.
提示信息:
命令: tmp ; 用户警告: 给保护符号赋值: drag <- (5 (124.565 116.191 0.0))
; 从中断循环重置

jx2008 · 发表于 2007-5-10 18:00:31

终于高出这个东西来了，等待了很久！多谢楼上各位

账号		自动登录	找回密码
密码			立即注册

[每日一码] 在grread状态下实现捕捉功能并显示标记符号

马上注册，结交更多好友，享用更多功能，让你轻松玩转社区。

本帖被以下淘专辑推荐:

相关帖子