[求助]：新手学习lisp遇到问题

qiyu0588 · 发表于 2007-11-6 16:08:12

马上注册，结交更多好友，享用更多功能，让你轻松玩转社区。

您需要登录才可以下载或查看，没有账号？立即注册

×

正在学习lisp中...
下面程序是选取直线，在直线中点画圆的程序：
在cad04中没有问题，可在07中就出现问题
04是在中点画圆，而在07就变成了在起点画圆了，不知道什么原因？
程序：
(defun c:tt( / en endate pt1_lst pt2_lst pt1 pt2
ang dis inter inter_r )
(setvar "cmdecho" 0)

(setq en (entsel))
(setq endate (entget (car en)))
(setq pt1_lst (assoc 10 endate))
(setq pt2_lst (assoc 11 endate))
(setq pt1 (cdr pt1_lst))
(setq pt2 (cdr pt2_lst))

(setq ang (angle pt1 pt2))
(setq dis (distance pt1 pt2))

(setq inter (polar pt1 ang (/ dis 2)))

(setq inter_r (getdist inter "\n半径:"))

(command "circle" inter inter_r)
(prin1)
)
附图：04中

qiyu0588 · 发表于 2007-11-6 16:08:58

下面是07的：

cy956 · 发表于 2007-11-6 16:19:34

捕捉问题。建议你用entmake，具体的你在坛内搜索entmake

enixing · 发表于 2007-11-6 16:27:07

或者用
;;;关闭捕捉
(defun ooe0 ()
  (setq ooe (Getvar "Osmode"))
  (setvar "Osmode" 0)
)
(defun ooe1 ()
  (setvar "Osmode" ooe)
)
关闭捕捉试试

qiyu0588 · 发表于 2007-11-6 16:27:47

哦谢谢
(setvar "osmode" 0)
我加了关闭捕捉问题解决了，时不时lisp运行前最好关掉对象捕捉呢？
我再学习下entmake

zml84 · 发表于 2007-11-7 09:27:38

[php]
(defun C:TT (/ EN ENDATE PT1 PT2 ANG DIS PT R)
(setvar "cmdecho" 0)
(if (and (setq EN (entsel "\n点取直线: "))
      ;;获取组码表
      (setq ENDATE (entget (car EN)))
      ;;判断所选对象是否是直线
      (= (cdr (assoc 0 ENDATE)) "LINE")
      ;;获取直线起终点坐标
      (setq PT1 (cdr (assoc 10 ENDATE))
   PT2 (cdr (assoc 11 ENDATE))
      )
      ;;计算直线方位角和长度
      (setq ANG (angle PT1 PT2)
   DIS (distance PT1 PT2)
      )
      ;;计算直线中点（下面这种方法是有缺陷的，因为忽略了Z值）
      (setq PT (polar PT1 ANG (/ DIS 2)))
      ;;向用户询问半径
      (setq R (getdist PT "\n半径:"))
      ;;判断半径是否有效
      (> R 0)
)
;;绘制圆
(command "_.circle" "non" PT R)
) ;_结束if
(princ)
) ;_结束defun
[/php]

账号		自动登录	找回密码
密码			立即注册

[求助] [求助]：新手学习lisp遇到问题

马上注册，结交更多好友，享用更多功能，让你轻松玩转社区。

相关帖子