[LISP函数]：十六进制与十进制相互转化

tengteb

;十进制数转化为十六字符串
(defun TBC:DEC2HEX (dec / tmp x y n hex)
  (if dec
    (if        (= 0 dec)
      (setq hex "0")
      (progn (setq hex ""
                   x   dec
                   n   16

             )
             (while (< 0 x)
               (setq y         (rem x n)
                     x         (/ x n)
                     tmp (if (> y 9)
                           (chr (+ y 55))
                           (chr (+ y 48))
                         )
                     hex (strcat tmp hex)
               )
             )
      )
    )
  )
  hex
)

  ;十六进制字符串转化为十进制数
(defun TBC:HEX2DEC (hex / tmp i n dec)
  (if hex
    (progn (setq hex (strcase hex)
                 n   (strlen hex)
                 i   1
                 dec 0
           )
           (while (<= i n)
             (setq tmp (ascii (substr hex i 1))
                   i   (1+ i)
                   tmp (if (>= tmp 65)
                         (- tmp 55)
                         (- tmp 48)
                       )
                   dec (+ tmp (* 16 dec))
             )
           )
    )
  )
  dec
)

lixiangdfeng

各类进制转换
http://www.xdcad.net/forum/showthread.php?s=&threadid=653871
说明：包括10进制 2进制 8进制 16进制及ASCII码的转换

tengteb

改进后的函数（使用递归）

;十进制数转化为十六字符串
(defun TBC:DEC2HEX (dec / Func DEC2HEX n hex)
  (defun Func (x / ch)
    (if        (< x 10)
      (setq ch 48)
      (setq ch 55)
    )
    (list (+ x ch))
  ) ;defun
  (defun DEC2HEX (x)
    (if        (< x n)
      (Func x)
      (append (DEC2HEX (/ x n)) (Func (rem x n)))
    )
  ) ;defun
  (and
    dec
    (setq n   16
          hex (vl-list->string (DEC2HEX dec))
    )
    (> 2 (strlen hex))
    (setq hex (strcat "0" hex))
  ) ;and
  hex
)

  ;更新日期：2009.12.30
  ;十六进制字符串转化为十进制数
(defun TBC:HEX2DEC (hex / Func n dec)
  (defun Func (x / ch)
    (if        (< x 65)
      (setq ch 48)
      (setq ch 55)
    )
    (setq dec (+ (- x ch) (* 16 dec)))
  ) ;defun
  (if hex
    (progn
      (setq n        16
            dec        0
            hex        (vl-string->list (strcase hex))
      )
      (mapcar 'Func hex)
    )
  ) ;if  dec
)

/db_自贡黄明儒_

如果直接利用excel,可以利用定义好的函数进行二进制、十六进制、十进制、八进制相互转换。
http://bbs.xdcad.net/thread-706608-1-1.html