[LISP函数-字串]：将具有分隔符的字符串解析为列表

eachy · 发表于 2005-9-7 18:08:41

马上注册，结交更多好友，享用更多功能，让你轻松玩转社区。

您需要登录才可以下载或查看，没有账号？立即注册

×

;;;==================================================================
;;; (xd-string_parse str delimiter)
;;; 将具有分隔符的字符串解析为列表
;;;------------------------------------------------------------------
;;; 参数:
;;; str 要解析的字符串
;;; delimiter 要搜索的分隔符
;;;------------------------------------------------------------------
;;; 返回:
;;; 一个字符串列表。
;;; 示例:
;;; (setq a "harp,guiness,black and tan")
;;; (xd-string_parse a ",")
;;; 返回:
;;; ("harp" "guiness" "black and tan")
;;;------------------------------------------------------------------
(defun xd-string_parse (str delimiter / post strlst)
(if str
(progn
(setq strlst '())
(while (vl-string-search delimiter str)
(setq post (vl-string-search delimiter str))
(setq strlst (append strlst (list (substr str 1 post))))
(setq str (substr str (+ post 2)))
)
(vl-remove "" (append strlst (list str)))
)
)
)

;;;================================================================== 
;;; (xd-string_parse str delimiter) 
;;;             将具有分隔符的字符串解析为列表 
;;;------------------------------------------------------------------ 
;;; 参数: 
;;;             str                     要解析的字符串 
;;;             delimiter               要搜索的分隔符 
;;;------------------------------------------------------------------ 
;;;     返回: 
;;;             一个字符串列表。 
;;;             示例: 
;;;             (setq a "harp,guiness,black and tan") 
;;;             (xd-string_parse a ",") 
;;;             返回: 
;;;             ("harp" "guiness" "black and tan") 
;;;------------------------------------------------------------------ 
(defun xd-string_parse (str delimiter / post strlst) 
  (if str 
    (progn 
      (setq strlst '()) 
      (while (vl-string-search delimiter str) 
        (setq post (vl-string-search delimiter str)) 
        (setq strlst (append strlst (list (substr str 1 post)))) 
        (setq str (substr str (+ post 2))) 
      ) 
      (vl-remove "" (append strlst (list str))) 
    ) 
  ) 
)

它山之石 · 发表于 2005-9-8 09:19:47

改进版，允许分隔符为多个字符串。

(defun GLisp_StrParse
(Str Delimiter / SearchStr
StringLen return n char
DelimiterLen
)
(setq SearchStr Str)
(setq StringLen (strlen SearchStr))
(setq DelimiterLen (strlen Delimiter))
(setq return '())
(while (> StringLen 0)
(setq n 1)
(setq char (substr SearchStr 1 DelimiterLen))
(while (and (/= char Delimiter) (/= char ""))
(setq n (1+ n))
(setq char (substr SearchStr n DelimiterLen))
) ;_ 结束while
(setq return (cons (substr SearchStr 1 (1- n)) return))
(setq SearchStr (substr SearchStr (+ DelimiterLen n) StringLen))
(setq StringLen (strlen SearchStr))
) ;_ 结束while
(reverse return)
) ;_ 结束defun

aeo · 发表于 2005-9-14 23:07:37

;;;========================================================================================
;;;按字符拆分字符串,可以多个字符
;;;保留拆分字符
;;;(XD-STRING_PARSE1 "df,34:4sf ere 45" " ,:")->("df" "," "34" ":" "4sf" " " "ere" " " "45")
;;;----------------------------------------------
(defun xd-string_parse1 (str chars / a new return)
(setq str(vl-string->list str)
chars(vl-string->list chars)
)
(while str
(setq a (car str) str(cdr str))
(if(member a chars)
(setq return(cons(list a)
(cons(reverse new)return)
)
new nil
)
(setq new(cons a new))
)
)
(if new(setq return(cons(reverse new)return)))
(mapcar ' vl-list->string (vl-remove 'nil(reverse return)))
)

狂刀 · 发表于 2005-9-18 08:36:38

(setq str "￥*df,E34:4sf ere #45" ch " ,:")
(defun c:tt ()(mapcar '(lambda(x)((eval x) str ch)) '(xd-string_parse GLisp_StrParse xd-string_parse1)))
(c:tt)
->(("￥*df,E34:4sf ere #45")
("￥*df,E34:4sf ere #45")
("￥*df" "," "E34" ":" "4sf" " " "ere" " " "#45"))
(setq str "￥*df",[E34:4sf" ere #45}"" ch " ,:")
(c:tt)
-> (("￥*df",[E34:4sf" ere #45}"")
("￥*df",[E34:4sf" ere #45}"")
("￥*df"" "," "[E34" ":" "4sf"" " " "ere" " " "#45}""))

第一，二个函数没有把字符分开。aeo的正常

顺便发一个以前写的。

;|==============================================;;
;;;字符串分隔成字符串表-------------------------狂刀.2003.12
;;; 函数: (x_str2lst 字符串分割符串)
;;; 实例:
;;;(setq str "￥*df,E34:4sf ere #45" ch " ,:")
;;;(x_str2lst str ch)
;;;-> ("￥*df" "E34" "4sf" "ere" "#45")
;;;(setq str "￥*df",[E34:4sf" ere #45}"" ch " ,:")
;;;(x_str2lst str ch)
;;;->("￥*df"" "[E34" "4sf"" "ere" "#45}"")
;;===============================================;;
|;
(defun x_str2lst (str divs / stri strn strlst)
(setq strn nil strlst nil)
(while (and str (/= "" str))
(setq stri (substr str 1 1))
(if (vl-string-search stri divs)
(if strn (setq strlst (cons strn strlst) strn nil))
(setq strn (if strn (strcat strn stri) stri))
)
(setq str (substr str 2))
)
(if strn (setq strlst (cons strn strlst) strn nil))
(if strlst (reverse strlst) nil)
)

;|==============================================;; 
;;;字符串分隔成字符串表-------------------------狂刀.2003.12 
;;; 函数: (x_str2lst 字符串 分割符串) 
;;; 实例: 
;;;(setq str "￥*df,E34:4sf ere #45" ch " ,:") 
;;;(x_str2lst str ch) 
;;;-> ("￥*df" "E34" "4sf" "ere" "#45") 
;;;(setq str "￥*df",[E34:4sf" ere #45}"" ch " ,:") 
;;;(x_str2lst str ch) 
;;;->("￥*df"" "[E34" "4sf"" "ere" "#45}"") 
;;===============================================;; 
|; 
(defun x_str2lst (str divs / stri strn strlst) 
  (setq strn nil strlst nil) 
  (while (and str (/= "" str)) 
    (setq stri (substr str 1 1))          
    (if (vl-string-search stri divs)      
        (if strn (setq strlst (cons strn strlst) strn nil))    
        (setq strn (if strn (strcat strn stri) stri)) 
        ) 
    (setq str (substr str 2))   
  ) 
 (if strn (setq strlst (cons strn strlst) strn nil)) 
 (if strlst (reverse strlst) nil) 
)

它山之石 · 发表于 2005-9-20 10:46:23

呵呵，俺的那个是支持连续字符串，与aeo的不同
俺当时的目的是将钢筋的根数与直径分开

(setq str "3%%1308@100" ch "%%130")
(defun c:tt ()(mapcar '(lambda(x)((eval x) str ch)) '(xd-string_parse GLisp_StrParse xd-string_parse1)))
(c:tt)
(("3" "%1308@100")
("3" "8@100")
("3" "%" "%" "1" "3" "0" "8@" "1" "0" "0"))

eachy · 发表于 2005-9-24 18:57:15

(defun xd-string_parse (str delimiter / post strlst len)
(if str
(progn
(setq strlst '() len (strlen delimiter))
(while (vl-string-search delimiter str)
(setq post (vl-string-search delimiter str))
(setq strlst (append strlst (list (substr str 1 post))))
(setq str (substr str (+ 1 post len)))
)
(vl-remove "" (append strlst (list str)))
)
)
)

fsxm · 发表于 2006-7-2 10:47:34

狂晕！~！一个字符分隔与多个字符分隔有太大的分别吗？
因为平时我们都是用一个字符分隔的啦！
没有必要将函扩展到多个字符这样会降低处理速度
比如用, or ; or \s or \t分隔只要在调用程序前处理一下就行了
还用的了那么多程序代码去解这种事吗？

(setq x ","
xlst '(";" "\s" "\t")
)
(foreach x2 (cdr xlst)
(while (vl-string-search x2 str)
(setq str (vl-string-subst x x2 str))
)
)

如果一定要来个功能多一点的就用这个好了~

(defun str->lst (str xlst / x xlen n lst)
(if (listp xlst)
(progn
(setq x (car xlst))
(foreach x2 (cdr xlst)
(while (vl-string-search x2 str)
(setq str (vl-string-subst x x2 str))
)
)
)
(setq x xlst)
)
(setq xlen (strlen x))
(while (setq n (vl-string-search x str))
(setq lst (cons (substr str 1 n) lst))
(setq str (substr str (+ 1 xlen n)))
)
(reverse (cons str lst))
)

fengjianwei · 发表于 2006-11-14 10:17:27

怎么显示出选择各个文件的文件名呢

jyzas · 发表于 2013-8-11 08:33:38

支持楼上的:)

lianghui2018 · 发表于 2014-3-23 22:20:19

学习，珍藏，谢谢各位老师的共享

账号		自动登录	找回密码
密码			立即注册

[LISP函数-字串]：将具有分隔符的字符串解析为列表

马上注册，结交更多好友，享用更多功能，让你轻松玩转社区。

相关帖子